A candle flame example produced using multiplying densities.

***Sorry about the indented code. I will try not to do it agian.***

#local DebugFlag = 0;
#declare Candle =
union{
  cylinder {
    <0, 0, 0>,
    <0, 1, 0>,
    1
    texture{
      pigment{rgbt 1}
    }
    interior{
      media{
        emission 1
        scattering{1,.01}
        intervals 20
        samples 1, 1
        confidence 0.999
        variance 1/100
        density {
          spherical
          cubic_wave
          turbulence 0.4
          lambda 1
          scale <0.8, 1, 0.8>
          color_map{
            [ 0 rgb 0]
            [ 1 rgb <5.0,3.0,0.0>]
          }
        }
        density {
          gradient y
          translate y
          cubic_wave
          color_map{
            [ 0 rgb 0]
            [ 1 rgb 1]
          }
        }
        density {
          gradient y
          poly_wave 0.5
          color_map{
            [ 0 rgb 0]
            [ 1 rgb 1]
          }
        }
      }
    } 
    hollow
    scale <1, 5, 1>
    translate y*1.25
  }

  intersection{
    cone{y*-8,.75,y*1,.5 pigment{rgb<1,1,.97>}finish{ambient .5 diffuse .23}}
    sphere{<.05,1,0>,.5 inverse pigment{rgb 1}finish{ambient .5 diffuse .23}}
  }

  cylinder{y*.8,y*1.5,.1 pigment{rgb 0}}
}

object{
  Candle
}

camera{
  location <0,1,-6>
  look_at 2.5 * y
}

light_source{
  <75,45,-500>
  color rgb 1
}




-- 
Ken Tyler

mailto://tylereng@pacbell.net

Post a reply to this message

ROFL, the best comment yet, very droll!

Ken wrote:
> 
>   A candle flame example produced using multiplying densities.
> 
> ***Sorry about the indented code. I will try not to do it agian.***
> 
> #local DebugFlag = 0;
> #declare Candle =
> union{
>   cylinder {
>     <0, 0, 0>,
>     <0, 1, 0>,
>     1
>     texture{
>       pigment{rgbt 1}
>     }
>     interior{
>       media{
>         emission 1
>         scattering{1,.01}
>         intervals 20
>         samples 1, 1
>         confidence 0.999
>         variance 1/100
>         density {
>           spherical
>           cubic_wave
>           turbulence 0.4
>           lambda 1
>           scale <0.8, 1, 0.8>
>           color_map{
>             [ 0 rgb 0]
>             [ 1 rgb <5.0,3.0,0.0>]
>           }
>         }
>         density {
>           gradient y
>           translate y
>           cubic_wave
>           color_map{
>             [ 0 rgb 0]
>             [ 1 rgb 1]
>           }
>         }
>         density {
>           gradient y
>           poly_wave 0.5
>           color_map{
>             [ 0 rgb 0]
>             [ 1 rgb 1]
>           }
>         }
>       }
>     }
>     hollow
>     scale <1, 5, 1>
>     translate y*1.25
>   }
> 
>   intersection{
>     cone{y*-8,.75,y*1,.5 pigment{rgb<1,1,.97>}finish{ambient .5 diffuse .23}}
>     sphere{<.05,1,0>,.5 inverse pigment{rgb 1}finish{ambient .5 diffuse .23}}
>   }
> 
>   cylinder{y*.8,y*1.5,.1 pigment{rgb 0}}
> }
> 
> object{
>   Candle
> }
> 
> camera{
>   location <0,1,-6>
>   look_at 2.5 * y
> }
> 
> light_source{
>   <75,45,-500>
>   color rgb 1
> }
> 
> --
> Ken Tyler
> 
> mailto://tylereng@pacbell.net

-- 

Politicians - It seems to me that the worst of them could convince me
that horse shit tastes like honey-cake; the best of them would leave
me believing that I alone in all the world had failed
to enjoy its flavour.

The individual is more important then the state!

Post a reply to this message