Recommended settings: -w640 -h480 +a0.1
  Comments?

camera { location <-2,5,-10> look_at 0 angle 35 }
light_source { <100,100,-200> 1 }
#declare Curves = union
{ difference { torus { 1/3,.13 } torus { 1/3,.1 } translate -z }
  difference { torus { 2/3,.13 } torus { 2/3,.1 } translate x+z }
  difference { torus { 2/3,.13 } torus { 2/3,.1 } translate -x+z }
  difference
  { cylinder{ -x*1.1-z/3,x*1.1-z/3,.13 } cylinder{ -x*1.1-z/3,x*1.1-z/3,.1 } }
  clipped_by { box { -1,1 } }
}
union
{ #declare R=seed(0); #declare Ix=-11; #while(Ix<=11)
    #declare Iz=-11; #while(Iz<=11)
      object { Curves rotate y*90*int(rand(R)*4) translate <Ix,0,Iz> }
      #declare Iz=Iz+2; #end
    #declare Ix=Ix+2; #end
  pigment { rgbf <1,0,.5,.8> } finish { specular .5 } interior { ior 1.5 }
}
union
{ #declare Ix=-11; #while(Ix<=11)
    #declare Iz=-11; #while(Iz<=11)
      object { Curves rotate y*90*int(rand(R)*4) translate <Ix,-1,Iz> }
      #declare Iz=Iz+2; #end
    #declare Ix=Ix+2; #end
  pigment { rgbf <.5,0,1,.8> } finish { specular .5 } interior { ior 1.5 }
}


-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message