The code below creates the image I posted to p.b.i , showing the effects
of changing values of (f)ilter and (t)ransmit in an rgbft color
specifier.

Andy

-----------------------


//POV file TRANSMIT.pov
//Demonstrate filter and transmittance in object color
//File by Andy Woodfin
//April 23, 1999

#include "colors.inc"

camera {
        location <-1,-2,-55>
        look_at <-1,-2,-1>
        angle 30
        }


//light_source { <-15,80,-50> color White }
//light_source { <-2,2,-80> color 1.2*White shadowless }
light_source { <-3,8,-80> color 1.2*White shadowless  }

plane {z, 1
        pigment {checker color rgb<1.0,0.0,0.0>, color rgb<0.0,1.0,0.0>
                scale 0.3
                }
                hollow
        }


#declare ROW=0;
#declare COL=0;
#declare EL=11;

/* Ignore this guy, just used for reference */
/*
sphere { <0,0,0>, 1
        pigment {color Blue}
        }
*/

#while(ROW<EL)
        #while(COL<EL)
                sphere { <1.6*(COL-EL/2),1.6*(ROW-EL/2),-0.65>, 0.6
                        pigment {color rgbft<1.0,0.0,0.0,ROW/10,COL/10>}

                        }
                #if(COL=0)
                text{ ttf "times.ttf" str(ROW/10,0,1) , 0.5, 0
                         texture {
                                pigment {Blue}
                                finish {
                                        ambient 0.5
                                        diffuse 0.6
                                }
                         }
                        scale 1.2
                        translate
<1.6*(-2-EL/2),1.6*(ROW-EL/2)-0.1,-0.2>
                    }
                #end
                #if(ROW=0)
                text{ ttf "times.ttf" str(COL/10,0,1) , 0.5, 0
                         texture {
                                pigment {Blue}
                                finish {
                                        ambient 0.8
                                        diffuse 0.6
                                }
                         }
                        scale 0.8
                        translate
<1.6*(COL-EL/2)-0.6,1.6*(-1.2-EL/2),-0.2>
                    }
                #end
                #declare COL=COL+1;
        #end
        #declare COL=0;
        #declare ROW=ROW+1;
#end

text{ ttf "times.ttf" "F" , 0.5, 0
        texture {
                pigment {Black}
                        finish {
                                ambient 0.8
                                diffuse 0.6
                         }
                 }
                scale 1.5
                translate <1.6*(-3-EL/2)-0.6,0,-0.2>
     }


text{ ttf "times.ttf" "T" , 0.5, 0
        texture {
                pigment {Black}
                        finish {
                                ambient 0.8
                                diffuse 0.6
                         }
                 }
                scale 1.5
                translate <-2,1.6*(-2.2-EL/2),-0.2>
     }


--

--------------------
"There are three men in a boat with four cigarettes but no matches.
How do they smoke??"
  -The Riddler

Andrew Woodfin
UNC Charlotte Center for Precision Metrology
adw### [at] unccedu | http://www.coe.uncc.edu/~adwoodfi
--------------------

Post a reply to this message