|
 |
Oh-oh, just realized the textures are not part of POV includes. Adding
them in too.
//BEGIN
// TEXTURES
#declare DullGloss_F =
finish {
ambient 0.09
diffuse 0.58
specular 0.1
roughness 0.02
phong 0.23
phong_size 180
reflection 0.1
crand 0.012
}
#declare Luster_F =
finish {
ambient 0.23
diffuse 0.65
specular 0.96
roughness 0.006
phong 0.7 phong_size 120
reflection 0.14
}
#declare LayerPolish_F =
finish {
ambient 0.17
diffuse 0.67
specular 0.21
roughness 0.003
phong .15 phong_size 234
reflection 0.06
metallic .1
brilliance .3
}
#declare Metal_F =
finish {
ambient 0.4
diffuse 0.99
brilliance 7
specular 0.96
roughness 0.009
reflection 0.15
metallic
}
#declare Gold_M =
texture {
pigment { color rgb <1.0, 0.80, 0.45> }
finish {
specular 0.94
roughness 0.0008
ambient 0.24
diffuse 0.81
reflection 0.31
metallic
brilliance 3.1
}
}
#declare Steel_M =
texture {
pigment { color rgb <0.76, 0.79, 0.78> }
finish {
specular 0.62
roughness 0.025
ambient 0.18
diffuse 0.5
reflection 0.36
metallic
brilliance 3
}
}
// BOWLING ALLEY
#declare Board =
box {<-1,-1,-1>,<1,1,1> texture {Pine_W scale <1,1,.33> rotate <5,5,5>
finish {Luster_F}}
scale <.2499,.1,9.999> translate <0,-1.1,0>}
#declare Boards =
union {
object {Board translate <5,0,0>}
object {Board translate <4,0,0>}
object {Board translate <3,0,0>}
object {Board translate <2,0,0>}
object {Board translate <1,0,0>}
object {Board translate <0,0,0>}
object {Board translate <-1,0,0>}
object {Board translate <-2,0,0>}
object {Board translate <-3,0,0>}
object {Board translate <-4,0,0>}
object {Board translate <-5,0,0>}
}
#declare Lane =
union {
object {Boards translate <.5,0,10>}
object {Boards translate <0,0,0>}
object {Boards translate <.5,0,-10>}
object {Boards translate <0,0,-20>}
object {Boards translate <.5,0,-30>}
object {Boards translate <0,0,-40>}
}
#declare G =
union {
cylinder {-1*z,1*z,1 open scale <1.1,1.1,30> translate -1.5*x}
cylinder {-1*z,1*z,1 open scale <1.1,1.1,30> translate 1.5*x}
texture {Steel_M}
clipped_by {plane {y,0}}
}
#declare Gutters =
union {
object {G translate <0,-1.05,-12>}
cylinder {-1*z,1*z,.4 texture {Gold_M normal {granite .1 scale
<.5,.75,25>}}
scale <1.1,.8,30> translate <0,-1.05,-12>}
}
#declare Alley =
union {
object {Lane clipped_by {
box {<-5,-1.5,-40>,<5,1,5>}} scale <1,1,3> translate -4*z}
object {Gutters translate -7.6*x}
object {Gutters translate 7.6*x}
}
// BOWLING PIN
#declare BPinP_T =
texture {
pigment { rgb<1,1,1> }
finish {DullGloss_F} }
#declare BPinT_T =
texture {
pigment { radial turbulence .67 frequency 24
color_map {
[ 0.0, 0.06 color rgbt<.5,.3,.1,.6> color rgbt<.5,.3,.1,.9>]
[ 0.06, 0.2 color rgbt<.5,.3,.1,1> color rgbt<.5,.3,.1,1>]
[ 0.2, 0.425 color rgbt<.5,.3,.1,.6> color rgbt<.5,.3,.1,.5>]
[ 0.425, 0.5 color rgbt<.5,.3,.1,.7> color rgbt<.5,.3,.1,.9>]
[ 0.5, 0.85 color rgbt<.5,.3,.1,1> color rgbt<.5,.3,.1,1>]
[ 0.85, 0.9 color rgbt<.5,.3,.1,.8> color rgbt<.5,.3,.1,.7>]
[ 0.9, 0.95 color rgbt<.5,.3,.1,.6> color rgbt<.5,.3,.1,.8>]
[ 0.95, 1.01 color rgbt<.5,.3,.1,1> color rgbt<.5,.3,.1,.8>]
} scale <1,.3,1>
}
normal { radial .07 turbulence .67 frequency 20 scale <1,.3,1>}
finish {LayerPolish_F}
}
#declare BPinS_T =
texture {
pigment { gradient y
color_map {
[ 0.04, 0.08 color rgbf<1,1,1,.2> color rgbf<1,1,1,.05>]
[ 0.08, 0.3 color rgbf<1,1,1,.05> color rgbf<1,1,1,.25>]
[ 0.3, 0.475 color rgbf<1,1,1,.25> color rgbf<1,1,1,.1>]
[ 0.475, 0.5 color rgbf<1,1,1,.1> color rgbf<1,1,1,.05>]
[ 0.5, 0.53 color rgbf<1,1,1,.05> color rgbf<1,1,1,0>]
[ 0.53, 0.59 color rgbf<.8,.1,.06,0> color rgbf<.8,.1,.06,0>]
[ 0.59, 0.68 color rgbf<1,1,1,0> color rgbf<1,1,1,.05>]
[ 0.68, 0.79 color rgbf<.9,.05,.03,.05> color rgbf<.9,.05,.03,.075>]
[ 0.79, 0.86 color rgbf<1,1,1,.075> color rgbf<1,1,1,.125>]
[ 0.86, 0.95 color rgbf<1,1,1,.125> color rgbf<1,1,1,.15>]
[ 0.95, 1.01 color rgbf<1,1,1,.15> color rgbf<1,1,1,.2>]
}
}
finish {DullGloss_F}
}
#declare BPin_S =
sor {
13,
<0.0, 0.0>
<0.42, 0.01>
<0.64, 0.26>
<0.61, 0.41>
<0.42, 0.56>
<0.34, 0.61>
<0.28, 0.67>
<0.33, 0.84>
<0.35, 0.89>
<0.27, 0.95>
<0.12, 0.98>
<0.04, 0.9875>
<0.0, 1.001>
sturm
}
#declare BPin =
object {BPin_S texture {BPinP_T} texture {BPinT_T} texture {BPinS_T}
scale <.9,3.33,.9> translate <0,-1,0>}
#declare BowlingPins =
union {
object {BPin translate <0,0,0>}
object {BPin translate <-1,0,1>}
object {BPin translate <1,0,1>}
object {BPin translate <-2,0,2>}
object {BPin translate <0,0,2>}
object {BPin translate <2,0,2>}
object {BPin translate <-3,0,3.5>}
object {BPin translate <-1,0,3.5>}
object {BPin translate <1,0,3.5>}
object {BPin translate <3,0,3.5>}
}
//END
--
omniVERSE: beyond the universe
http://members.aol.com/inversez/POVring.htm
=Bob
Post a reply to this message
|
|
