Sorry to anyone who looked at this in the few hours before I cancelled
my first post of this. I should have checked the file out before
posting. Now it's alright (supposedly) -- custom color include before.
The following is a test on several primitives to show scaling effects.
Sorry I couldn't find the name of the person who brought this up at AOL
or c.g.r.r. a year or more ago. This is basically the same script, I
changed the numbers and such. Add on semi-colons for 3.1 if you
want. I have checked this out in 3.1, 3.02 (Win) and 2.2 (DOS) versions
but it isn't 2.2 compatible so I had to change syntax (script not here,
ask [subject: scale test] if you want it).
The 2.2 (DOS) version of POV-Ray does much better than 3.* (Win) in
keeping things together correctly. When SCALE0 is used nothing remains
of any objects as rendered with 3.*, but only the spheres and box
disappear with 2.2 and no distortions noticed.

//BEGIN

// Show effects on some primitives when scaled.

#include "colors.inc"

//#declare SCALE = 1
 // at 1 normal.

#declare SCALE0 = 0.000000001
 // at .000000001 the cone remains normal! (gone in version 3.*?)
#declare SCALE1 = 0.00000666
 // at .0000066 the torii are chopped! no spheres or blobs.
#declare SCALE2 = 0.0031624
 // at .0031623 the spheres shrink out of sight (640x480)!
#declare SCALE3 = 44444
 // above 36000 the box distorts!
#declare SCALE4 = 666666
 // at 666666 the torii are cut in (opposite) half! blobs need sturm. no
box.
#declare SCALE5 = 999999999
 // at 999999999 the cone is indestructable (not in 3.*?)! spheres gone
again. no box, blobs or torii.

#declare SCALES = SCALE0  // replace # with 0-5

#declare OBJ = union{
cylinder {-y,y,1 rotate <30,45,30> pigment {Red}}
sphere {0,1 translate <0,-2.5,0> pigment {Green}}
sphere {0,1 translate <0,2.5,0> pigment {Yellow}}
cone {-y,1,y,0 rotate <30,30,30> translate <-3,0,0> pigment {Red}}
torus {1,.25 rotate <45,15,30> translate <3,-2.5,0> pigment {White}}
torus {1,.25 rotate <-45,-15,-30> translate <3,2.5,0> pigment {Black}}
box {<-.8,-.8,-.8>,<.8,.8,.8> rotate <45,45,45> translate <3,0,0>
 pigment {Red}}
blob {threshold .5
 sphere	{-x,1.25,.75 pigment {Green}}
 sphere	{x,1.25,.75 pigment {Yellow}}
 cylinder {-y,y,1.25,.75 pigment {DarkPurple}}
  rotate <-40,-30,-20> translate <-3,-2.5,0> sturm}
blob {threshold .5
 sphere	{-x,1.25,.75 pigment {Blue}}
 sphere	{x,1.25,.75 pigment {Orange}}
 cylinder {-y,y,1.25,.75 pigment {Pink}}
  rotate <40,30,20> translate <-3,2.5,0> sturm}
}
camera		{ location <0,0,-15> look_at <0,0,0> angle 40 scale SCALES }
light_source{ <+100,+100,-1000> color rgb<1.5,1.5,1.5> scale SCALES }
background	{ color Gray}
object		{ OBJ scale SCALES }

-- 
 omniVERSE: beyond the universe
  http://members.aol.com/inversez/POVring.htm
=Bob

Post a reply to this message