Hello There,

I am trying to render a scene, whrere a laser beam is refracted by some objects,
but it just does not work. I found a similar question here

web.487989b0797036a91a8107a20@news.povray.org

and the scene mentioned there actually works. Mine still won't, so what is wrong
with it? Thank you in advance for your help!

#include "colors.inc"
#include "textures.inc"

global_settings {
 assumed_gamma 1.0
 max_trace_level 10
 photons {
  count 100000
  autostop 0
  media 1000
  max_trace_level 10
 }
}

camera {
  location  <0,20,-20>
  look_at   <0,0,0>
}

// scatterbox
box {
 <-10,0,-40>, <10,5,40>
 hollow
 pigment {
  color transmit 1
 }
 interior {
  media {
   scattering {
    1, 1 extinction 0
   }
  samples 30,100
  }
 }
}

// interacting box
box {
 <2,4,-10>, 0
 translate <0,0,4>
 rotate <0, 45, 0>
 hollow
 pigment {
  color transmit 0.9
 }
 interior {
  media {
   scattering {
    1, 1 extinction 0
   }
   samples 30,100
  }
 ior 1.5
 }
 photons {
  target
  refraction on
  reflection on
 }
}

// laser
light_source {
 <0,1,-50>
 color red 1.0
 cylinder
 point_at <0,1,10>
 radius 0.2
 falloff 0.2
 tightness 0.1
 photons {
   refraction on
   reflection on
 }
}

// ambient light
light_source {
 <100,100,150>
 color rgb 1.3
 media_interaction off
 photons {
   refraction off
   reflection off
 }
}

// floor
plane {
 y, 0
 pigment {
  checker color White color Black
 }
}

Post a reply to this message

"Nurwodah" <nomail@nomail> wrote in message 
news:web.4a1bc48ea9dd582089e1bd650@news.povray.org...
>
> I am trying to render a scene, whrere a laser beam is refracted by some 
> objects,

Didn't look at the other but try this in your global_settings instead:

 photons {
  //count 100000
  spacing 0.02
  autostop 0
  media 50,5
//  max_trace_level 10
 }

I think spacing helps in this case where the photons are in a narrow beam.
And... this is the important part... use a photons block in your scattering 
box:

 photons {
  target
  refraction on
  reflection on
  collect off
  pass_through
 }

Now, I should say, I haven't done this particular kind of render in recent 
times so don't take it as perfection (or even the right way) but I did get a 
good laser beam by doing that. Also to make it faster than what you were 
doing I put the media samples down to only 10,30. I even added some 
reflection (in finish{}) to the refracting glass and it was still fairly 
quick.

Bob

Post a reply to this message

Hello Bob,

thank you for your help! Indeed, the missing photon block in the scattering box
was the problem. I did not expect this to be necessary if the refracting glass
block contained a photon block, but obviously I was wrong.

But:

If I use the following source for rendering, I get a rather strange image:
After passing the glass block and being refracted/reflected/absorbed correctly,
the laser beam changes into a dotted line, that looks very much like some
interference pattern. As far as I understand (I mean, almost 99.99% sure!)
POV-ray is of course not capable of calculating phase interactions of light, so
any idea what could have happened here?

#include "colors.inc"
#include "textures.inc"

global_settings {
 assumed_gamma 1.0
 max_trace_level 10
 photons {
  spacing 0.02
  autostop 0
  media 50,5
 }
}

camera {
  location  <0,20,0>
  look_at   <0,0,0>
}

// scatterbox

box {
 <-10,0,-40>, <10,5,40>
 hollow
 pigment {
  color transmit 1
 }
 interior {
  media {
   scattering {
    1, 1 extinction 0
   }
  samples 10,30
  }
 }
 photons {
  target on
  refraction on
  reflection on
  collect off
  pass_through
 }
}

// interacting box

box {
 <2,4,-10>, 0
 translate <0,0,4>
 rotate <0, 45, 0>
 hollow
 pigment {
  color transmit 0.9
 }
 interior {
 ior 1.5
 }
 finish {
  diffuse 0.3
 }
 photons {
  target
  refraction on
  reflection on
 }
}

// laser

light_source {
 <0,1,-50>
 color red 1.0
 cylinder
 point_at <0,1,100>
 radius 0.2
 falloff 0.2
 tightness 0.1
 photons {
   refraction on
   reflection on
 }
}

// ambient light

light_source {
 <100,100,150>
 color rgb 1.3
 media_interaction off
 photons {
   refraction off
   reflection off
 }
}

// floor

plane {
 y, 0
 pigment {
  checker color White color White
 }
}

Post a reply to this message

"Nurwodah" <Nur### [at] webde> wrote in message 
news:web.4a1d416d84c0b6cb7e13cce0@news.povray.org...
>
> If I use the following source for rendering, I get a rather strange image:
> After passing the glass block and being refracted/reflected/absorbed 
> correctly,
> the laser beam changes into a dotted line, that looks very much like some
> interference pattern.

Just got a look at this before going out the door.

I see, yeah, try something like media 200,10 for the global photons and 
maybe that will be okay.
You might also need to make 'spacing' a fraction smaller, the exit beam is 
fuzzy.
Checking that, I had to use media 300,10 with spacing 0.005 or else the 
fragmenting occurs again.

Funny thing, I hadn't realized the two medias (both boxes) wouldn't be 
needed-- unless you were going to have different ones, of course.

Bob

Post a reply to this message

> I see, yeah, try something like media 200,10 for the global photons and
> maybe that will be okay.
> You might also need to make 'spacing' a fraction smaller, the exit beam is
> fuzzy.
> Checking that, I had to use media 300,10 with spacing 0.005 or else the
> fragmenting occurs again.

ok, so this is about trial & error.

> Funny thing, I hadn't realized the two medias (both boxes) wouldn't be
> needed-- unless you were going to have different ones, of course.

Yeah, I figured out that when I realized the beam inside the glass thing
appearing about twice as bright as in the surrounding area, the scattering
values probably just sum.

thanks again

Nurwodah

Post a reply to this message

"Nurwodah" <Nur### [at] webde> wrote in message 
news:web.4a1d58a384c0b6cb7e13cce0@news.povray.org...
>> I see, yeah, try something like media 200,10 for the global photons and
>> maybe that will be okay.
>> You might also need to make 'spacing' a fraction smaller, the exit beam 
>> is
>> fuzzy.
>> Checking that, I had to use media 300,10 with spacing 0.005 or else the
>> fragmenting occurs again.
>
> ok, so this is about trial & error.

Usually is for me. Moreso with photons. I have enough trouble getting media 
alone to look the way I want.
;)
>> Funny thing, I hadn't realized the two medias (both boxes) wouldn't be
>> needed-- unless you were going to have different ones, of course.
>
> Yeah, I figured out that when I realized the beam inside the glass thing
> appearing about twice as bright as in the surrounding area, the scattering
> values probably just sum.

Mixing media containers can be a real challenge. I thought maybe you were 
wanting a different kind of substance eventually for the refractive object. 
I just ignored the fact it didn't need to have anything but the one 
room-filling media until you posted that second time without it. Otherwise I 
might have suggested removing that, and possibly thought wrong by doing so.
:)
> thanks again

Glad I could help!

Post a reply to this message

Maybe you've had better luck than me, I went back to this trying for a good 
render because I'm using the new version 3.6.2.

There's some kind of artifact (or artefact) making a line parallel to the 
beam of light, divides the part inside the glass.

Changed the light falloff to 0.25 thinking it was radius=falloff causing it, 
and adding 'parallel' to the light made no difference.
I didn't try every possibility but increasing media samples some and upping 
the global photons media to 1000,10 sure didn't fix that. Removed the 
fragmenting you had seen when I used higher numbers anyway (I was doing 
small quick renders before).

Just thought I'd mention the strange line in the glass. Maybe it just needs 
extreme tweaking on the numbers...?

Post a reply to this message

"BobH" <omniverse*charter!net> wrote:
> There's some kind of artifact (or artefact) making a line parallel to the
> beam of light, divides the part inside the glass.

Got a shot for us to see?

Maybe it's just a reflection of the beam in the glass?

Post a reply to this message

"clipka" <nomail@nomail> wrote in message 
news:web.4a1ebcd284c0b6cf708085d0@news.povray.org...
> "BobH" <omniverse*charter!net> wrote:
>> There's some kind of artifact (or artefact) making a line parallel to the
>> beam of light, divides the part inside the glass.
>
> Got a shot for us to see?
>
> Maybe it's just a reflection of the beam in the glass?

No reflection used. Posting a cropped image to p.b.i. subject light beam 
artifact.

Bob

Post a reply to this message