Please I want to create some ceramic tiles for a swimming pool.
I would like to create one with a bevelled edge and then I
think I can figure out how to repeat the pattern, Whats the
best method for creating a smooth bevelled edge.
thanks

Post a reply to this message

In article <web.4495063d838dec754278bffc0@news.povray.org>,
 "tommy thompson" <nomail@nomail> wrote:

>Please I want to create some ceramic tiles for a swimming pool.
>I would like to create one with a bevelled edge and then I
>think I can figure out how to repeat the pattern, Whats the
>best method for creating a smooth bevelled edge.
>thanks

I had positive Experience with the hyperellipsoid, e.g.:

#include "colors.inc"

camera
{
    location <-10,75,-100>
    look_at <0,0,0>
}

light_source
{
    <300,600,-100>
    color rgb <1,1,1>
}

plane
{
    y,-15
    pigment
    {
        Silver
    }
}

superellipsoid
{
    <0.1, 0.25>
    texture
    {
        pigment
        {
            color NeonPink
        }
    }
    rotate 90*x
    scale <20, 1, 20>
}


For the real thing, you have to adapt the scaling and - caertainly - the 
finish.



Best regards,

Post a reply to this message

"=?ISO-8859-1?Q?G=FCnther?= Dietrich" <gue### [at] despammedcom>
wrote:
> In article <web.4495063d838dec754278bffc0@news.povray.org>,
>  "tommy thompson" <nomail@nomail> wrote:
>
> >Please I want to create some ceramic tiles for a swimming pool.
> >I would like to create one with a bevelled edge and then I
> >think I can figure out how to repeat the pattern, Whats the
> >best method for creating a smooth bevelled edge.
> >thanks
>
> I had positive Experience with the hyperellipsoid, e.g.:
>
> #include "colors.inc"
>
> camera
> {
>     location <-10,75,-100>
>     look_at <0,0,0>
> }
>
> light_source
> {
>     <300,600,-100>
>     color rgb <1,1,1>
> }
>
> plane
> {
>     y,-15
>     pigment
>     {
>         Silver
>     }
> }
>
> superellipsoid
> {
>     <0.1, 0.25>
>     texture
>     {
>         pigment
>         {
>             color NeonPink
>         }
>     }
>     rotate 90*x
>     scale <20, 1, 20>
> }
>
>
> For the real thing, you have to adapt the scaling and - caertainly - the
> finish.
>
>
>
> Best regards,
>


 success ;-)
 It works well I can change the surface to look like glazed ceramic, I now
need to repeat the pattern.
Will go and read some more instuctions.

Post a reply to this message

"tommy thompson" <nomail@nomail> wrote:

> success ;-)

Thanks for the feedback.


> It works well I can change the surface to look like glazed ceramic, I now
>need to repeat the pattern.
>Will go and read some more instuctions.

You might try something like this:


// Floor with tiles
union
{
    // tiles
    #declare stepwidth = 0.15   // gives a tile grid of 0.15m x 0.15m
    #declare x_ = -1.2
    #while (x_ <= 1.2)
        #declare z_ = -2.55
        #while (z_ <= 2.55)
            superellipsoid
            {
                <0.1, 0.1>
                scale <0.073, 0.004, 0.073>
                pigment
                {
                    White_Marble
                    scale 0.12
                    // create a bit of 'randomness' for the tile patterns
                    translate <-x_, z_, 0>
                }
                finish
                {
                    phong 1
                    phong_size 50
                    reflection .35
                }
                translate <x_, 0, z_>
            }
            #declare z_ = z_ + stepwidth
        #end
        #declare x_ = x_ + stepwidth
    #end
    // Joint compound to fill the gaps between the tiles
    box
    {
        <-1.175, 0, -2.55>, <1.175, 0.0035, 2.55>
        pigment
        {
            Silver * 0.8
        } 
    }
}

Units are meters, the floor space is 2.35m x 5.10m (bathroom in a real 
existing old building).



Best regards,

Post a reply to this message

It reminds of a bathroom I used to know,
I'm going to try and add a texture using a .png
image.I,ve managed to get a picture onto the tile
I want to create the kind of textured tile
you find about swimming pools.

> Tommy T

Post a reply to this message