Hi!
Im so thankful for all the help you guys keep giving me!
Maybe one day I can make it up by also contributing to this comunity.
*looks proudly towards a far horison*

Anyways. Take a look at the poles on this barbed wire fence.

http://img223.imageshack.us/img223/9836/taggtrad9rh.jpg

They look, well, kinda smooth... Any ideas how to make them look a little
more like actual wooden poles? Tried to use the wood normal, but, I didnt
really get what I expected...

This is the only setting for texture I use for the poles right now:
texture {T_Wood22 scale 1.5 }

I would very much appreciate any suggestions on the subject,
cuz I know it can be done... I've seen it...

Humbly
/RH

Post a reply to this message

Try Christoph Hormanns excellent ISO Wood include file at:

http://www.imagico.de/pov/tools.html

I think it will do the job for you.

Tim

Post a reply to this message

RusHHouR <gee### [at] mailnu> wrote:
> I would very much appreciate any suggestions on the subject,
> cuz I know it can be done... I've seen it...

  Here are some tips for creating decent-looking wood textures:

1. The 'wood' pattern consists simply of concentric circles ramp wave
   around the z axis. All by itself it's a bit boring for a "wood" pigment.
   However, it has a great turbulence implementation which makes it look
   superb. Try with different turbulence amounts.

2. Scale the 'wood' pigment unevenly so that it's elongated along the
   z axis (or whatever axis the circles are around if you have rotated
   the pattern). This matches real-life wood a lot more closely.

3. While some woods have smooth color transitions, most of them have
   quite sharp transitions between layers of colors. Take this into
   account in your color map.

4. If you want rough non-polished wood, use a normal pattern which is
   also elongated along the same axis as the pigment. This normal can
   exactly match the pigment (by applying the exact same transformations
   and turbulence), but it doesn't have to.

  This small scene tries to demonstrate these principles:

#declare UseNormal = no;

camera { location -z*10 look_at 0 angle 35 }
light_source { <10, 5, -20>, 1 }

cylinder
{ -y*2, y*2, 1

  pigment
  { wood color_map
    { [0 rgb <1, .8,.5>]
      [.4 rgb <.95, .7, .4>]
      [.6 rgb <.75, .5, .2>]
      [1 rgb <.7, .4, .15>]
    }
    turbulence .5
    rotate x*90
    scale <1, 20, 1>*.25
  }

  #if(UseNormal)
    normal
    { wood -.25
      slope_map { [0 <0,0>][.5 <.5,1>][1 <1,0>] }
      turbulence .5
      rotate x*90
      scale <1, 20, 1>*.25
    }
  #end

  finish { specular .25 }
}


-- 
                                                          - Warp

Post a reply to this message

Take a look at the Isowood include of Christoph
Hormann(http://www.imagico.de/iso_wood.html).
Gena Obukhov's bent trunks are useful too
(http://propro.ru/go/Wshop/objects/objects.html).

Happy rendering!

Norbert Kern

Post a reply to this message

"RusHHouR" <gee### [at] mailnu> wrote:
> They look, well, kinda smooth...

lacking some normal, turbulence and a little contrast in the colors in the
wood colormap...

> Tried to use the wood normal, but, I didnt
> really get what I expected...

thing is:  the normal has to match the pigment settings so as to make it
believeable.

like this:


camera { location -2*z look_at 0 }

light_source {<1,.6,-.5>*10 1 }
light_source {<.3,.3,-1>*10 .4 }

#declare cm_wood =
color_map {
 [0 rgb .8*<.8,.76,.4>]
 [.4 rgb <.6,.46,.4>]
 [1 rgb .6*<.6,.46,.4>]
}

#declare t_wood =
texture {
 pigment { wood color_map { cm_wood } turbulence .10 }
 normal { wood .8 turbulence .10 }
 finish { ambient .3 diffuse .36 phong .4 phong_size 46 brilliance .6 }
}

cylinder { -1*y, 1*y, .3
 texture { t_wood rotate 80*x scale .022 scale y*1.2 translate .6 }
}


playing around with the last scale setting (.22), the color_map and the wood
bump_size (.8) can bring some surprisingly nice results.

Post a reply to this message

That is great! Will try these out.

Thanks everyone.

Post a reply to this message