FIRST OF ALL: I am french, so excuse me if my english is not perfect...
I have made a serie of include files to make planetary scenes.
The first and most important file is planet.inc: it declares
"object{planet}". It is a 1 pov-unit radius sphere scaled by the parameter
"planet_dimensions" (for example <6378.1,6356.8,6378.1> for the Earth,
where 6378.1 is the equatorial radius and 6356.8 is the polar one). The
texture is declared by "planet_texture".

FIRST PROBLEM:What shoud I put in the finish{} properties of
"planet_texture" to have a good-looking (is that the word) planet? The only
thing I am sure for now is that the ambient value must be 0.

SECOND PROBLEM:I have two maps, one representing the Earth land mass
topography above the sea (see http://www.space-graphics.com/e43_flat.htm)
and the other representing the Earth global ocean/landmass mask (see
http://www.space-graphics.com/e43_mask.htm). For the second map, the white
represents the oceans and rivers while the black represents the landmass.

I would like the landmass and the oceans to have different finish{}
properties so that only the ocean reflects well the sun.

For the moment I declare the earth texture like that:

#declare planet_texture=texture{
pigment{
image_map{
jpeg "Earth_map.jpg" map_type 1
}
}
finish{
ambient 0
//WHAT SHOULD I PUT HERE THEN???...
}
}

and in planet.inc I have:
#declare planet=sphere{
0
1
texture{
planet_texture
}
scale planet_dimensions
}


Erwan Le Gac

Post a reply to this message

"elegac" <e.l### [at] voilafr> wrote in message 
news:web.43b816026526bd51c89ad05e0@news.povray.org...
>
> FIRST PROBLEM:What shoud I put in the finish{} properties of
> "planet_texture" to have a good-looking (is that the word) planet?

A specular hilight would be something to add for the sunlight to be seen 
reflected. Mostly for the water, but also a little for land. Something maybe 
like:  specular 0.05 roughness 0.1
You might need to adjust the amount (size) showing for the distance your 
camera is planned to be located from the planet surface. There's an effect 
called heiligenschein, or holy light, like a halo created on dewey grass 
around the shadow of your head but I'm not sure if this is the same thing.

> SECOND PROBLEM:
> I would like the landmass and the oceans to have different finish{}
> properties so that only the ocean reflects well the sun.

The black and white landmass/water map can be used in a material_map, then 
applied as the uppermost layer of textures over the other image_map texture 
but using transparent pigments to still see the other map through it. 
Something like this:

#declare Planet_Land_Texture=
texture {
    pigment {
     image_map {
      jpeg "earthmap.jpg"
         map_type 1 // spherical
         interpolate 2 // pixel blending
     }
    }
    finish {
        ambient 0
        diffuse 0.5
        specular 0.05 roughness 0.1
    }
}

#declare Planet_Water_Texture=
texture {
    material_map {
        png "earthlandwatermap.png"
        map_type 1
        interpolate 2
        texture { // first color index (black)
            pigment {
                rgbt 1 // clear
            }
        }
        // add textures between, if any more index values exist
        texture { // next color index (white?)
            pigment {
                rgbt 1
            }
            normal { // makes water unsmooth
                wrinkles 0.1 scale 0.01
            }
            finish {
                ambient 0
                diffuse 0
                specular 0.4 roughness 0.02
            }
        }
    }
}

sphere {
 0,1
  texture {Planet_Land_Texture}
}
// cannot layer the material texture into 1st so 2nd sphere is needed
sphere {
 0,1.0001 // slightly larger to cover other sphere
  texture {Planet_Water_Texture}
}

camera {
 location -3*z
 look_at 0
}

light_source {
 -123*z, 1
 rotate <30,30,0>
}
// looks like this should work okay with the image files you told of (I 
renamed them).

You might also want to try adding a normal{bump_map{[image file here]}} to 
the land part by using an elevation-based map, unless you'll only see the 
planet from far away.

Good luck with it! Ask more questions if you need any help. Someone else 
might even have other ideas for you.

Bob

Post a reply to this message

"Bob Hughes" <omniverse@charter%net> wrote:
> "elegac" <e.l### [at] voilafr> wrote in message
> news:web.43b816026526bd51c89ad05e0@news.povray.org...
> >
> > FIRST PROBLEM:What shoud I put in the finish{} properties of
> > "planet_texture" to have a good-looking (is that the word) planet?
>
> A specular hilight would be something to add for the sunlight to be seen
> reflected. Mostly for the water, but also a little for land. Something maybe
> like:  specular 0.05 roughness 0.1
> You might need to adjust the amount (size) showing for the distance your
> camera is planned to be located from the planet surface. There's an effect
> called heiligenschein, or holy light, like a halo created on dewey grass
> around the shadow of your head but I'm not sure if this is the same thing.
>

FIRST PROBLEM: SOLVED!
It look good now, thanks! Look at
http://cjoint.com/data/bcoUFJE77o_Earth.jpg
(I've added an atmosphere with my "atmosphere.inc" include file)

Now let's see the second problem...

Erwan

Post a reply to this message

"elegac" <e.l### [at] voilafr> wrote:
> "Bob Hughes" <omniverse@charter%net> wrote:
> > "elegac" <e.l### [at] voilafr> wrote in message
> > news:web.43b816026526bd51c89ad05e0@news.povray.org...
> > >
> > > FIRST PROBLEM:What shoud I put in the finish{} properties of
> > > "planet_texture" to have a good-looking (is that the word) planet?
> >
> > A specular hilight would be something to add for the sunlight to be seen
> > reflected. Mostly for the water, but also a little for land. Something maybe
> > like:  specular 0.05 roughness 0.1
> > You might need to adjust the amount (size) showing for the distance your
> > camera is planned to be located from the planet surface. There's an effect
> > called heiligenschein, or holy light, like a halo created on dewey grass
> > around the shadow of your head but I'm not sure if this is the same thing.
> >
>
> FIRST PROBLEM: SOLVED!
> It look good now, thanks! Look at
> http://cjoint.com/data/bcoUFJE77o_Earth.jpg
> (I've added an atmosphere with my "atmosphere.inc" include file)
>
> Now let's see the second problem...
>
> Erwan

I have another solution to your problem: use your landmass/water map as a
mask for a texture map (ie pigment pattern)) as follows:

#declare Planet_Land_Texture =
texture {
    pigment {
     image_map {
      jpeg "earthmap.jpg"
         map_type 1 // spherical
         interpolate 2 // pixel blending
     }
    }
    finish {
        // WHATEVER, but, according to me,  land should be kept as it is in
the image.
    }
}

#declare Planet_Water_Texture = texture
{
    // WHATEVER: blue pigment with reflection and/or specular or image map.
}

#declare Planet = sphere
{
    0, 1
    texture
    {
        pigment_pattern // Here is the trick
        {
            image_pattern
            {
                png "earthlandwatermap.png"
                map_type 1
            }
        }
        texture_map
        {
            // Entries may be inverted according to the way
"earthlandwatermap.png" encodes land and water. Here, zeros are for land
and ones for water (threshold set to 0.5).
            [0.5 Planet_Land_Texture]
            [0.5 Planet_Water_Texture]
        }
    }
}

object {Planet}

Regards

    Bruno

Post a reply to this message