Hi,

Can anybody tell me whether there is a possibility to render wireframes in
POV-Ray.  I have always liked images where the final render is mixed/faded
with a wireframe.  I think it is possible in Lightwave, Cinema 4d etc...

Thanks.

Adrian

Post a reply to this message

the_ajj wrote:
> Hi,
> 
> Can anybody tell me whether there is a possibility to render wireframes in
> POV-Ray.  I have always liked images where the final render is mixed/faded
> with a wireframe.  I think it is possible in Lightwave, Cinema 4d etc...

http://tag.povray.org/povQandT/languageQandT.html#wireframes

Christoph

-- 
POV-Ray tutorials, include files, Landscape of the week:
http://www.imagico.de/ (Last updated 31 Oct. 2005)
MegaPOV with mechanics simulation: http://megapov.inetart.net/

Post a reply to this message

Christoph Hormann <chr### [at] gmxde> wrote:

> http://tag.povray.org/povQandT/languageQandT.html#wireframes
>

Bugger.

Post a reply to this message

"the_ajj" <nomail@nomail> wrote in message 
news:web.438c8e1a897dbb2fa43155f60@news.povray.org...
> Hi,
>
> Can anybody tell me whether there is a possibility to render wireframes in
> POV-Ray.  I have always liked images where the final render is mixed/faded
> with a wireframe.  I think it is possible in Lightwave, Cinema 4d etc...
>
> Thanks.
>
> Adrian
>
>

Technically the faq is of course totally correct.

But, you could fake it ...
A wire frame texture can be merged with a solid texture using a texture map 
as shown below (I'll post a rendered example of the one below in 
povray.binaries.images).
Alternatively, if your object is a mesh,  you could assign the coordinates 
into an array and have a macro draw a thin cylinder along each edge.

Regards,
Chris B.
--------


#include "ppf1face.inc" // Rounded object about 50 units wide and 100 high
#declare YourObject = union {object {ppFace} object {ppFace scale <-1,1,1>}}
#declare YourTexture = texture {pigment {color rgb <1,1,0>} finish{phong 1}}

#declare WireframeHorizontalTexture = texture {
  pigment {
    gradient y
    turbulence 0
    color_map {
      [0     rgbt <0,1,0,0>]
      [0.08  rgbt <0,1,0,0>]
      [0.08  rgbt <1,1,1,1>]
      [1     rgbt <1,1,1,1>]
    }
  scale 0.02
  }
}

#declare RadialLineTexture = texture {
  pigment {
    gradient x
    turbulence 0
    color_map {
      [0     rgbt <0,1,0,0>]
      [0.0008  rgbt <0,1,0,0>]
      [0.0008  rgbt <1,1,1,1>]
      [1     rgbt <1,1,1,1>]
    }
  }
  scale 2
}

#declare WireframeRadialTexture = texture {RadialLineTexture}

#local I = 0;
#while (I<180)
  #declare WireframeRadialTexture =
    texture {WireframeRadialTexture}
    texture {RadialLineTexture rotate y*I}
  #local I = I + 10;
#end

#declare WireframeTexture =
  texture {WireframeHorizontalTexture}
  texture {WireframeRadialTexture translate 0.5*x}


#declare MixedTexture =
  texture {YourTexture}
  texture {WireframeTexture}

#declare MergedTextures = texture {
  gradient x       //this is the PATTERN_TYPE
  texture_map {
    [0    WireframeTexture]
    [0.48 WireframeTexture]
    [0.52 MixedTexture    ]
    [0.54 MixedTexture    ]
    [0.56 YourTexture     ]
    [1    YourTexture     ]
  }
  translate -0.5*x
  scale 150
}

object {YourObject translate -z*20 texture {MergedTextures}}

camera {location <-20,100,-140> look_at <0,60,0>}
light_source { <100, 1000, -2000> color rgb 1}

Post a reply to this message

"Chris B" <c_b### [at] btconnectcomnospam> wrote:
> Technically the faq is of course totally correct.
>
> But, you could fake it ...

Redemption!  Excellent - thanks!

Adrian

Post a reply to this message