I created a static scene in POV-Ray and successfully suppressed shadows with
no_shadow.  However when I modified the file for animation I found that the
shadows appeared in the rendered frames despite the no_shadow keyword.  In
the animated version, the no_shadow object gradually appears by displaying
an intersection of the object with a box that grows larger with the value of
clock.  (I even made the box no_shadow as well, but I still see a shadow.)
When I don't do the intersection, the shadow goes away.

I'm using POV-Ray version 3.6.1a.icl8.win32 under Windows XP Pro, SP2.

Have I made some typical newbie error, or am I missing something subtle
about rendering animation?

Below is a simplified version of the code that displays the problem.
You can set the "Animate" constant true to see the shadow appear, or
false to see the object not casting a shadow (as desired).

Thanks for any advice you can offer.
WhiteRyder


  #include "colors.inc"
  #include "finish.inc"

  background { color MidnightBlue }
  plane      { < 0, 1, 0 >, 0   pigment { color VLightGray }  }

  camera {
    location <0, 2, -6>
    look_at  <0, 3,  0>
  }

  light_source { <-2, 5, -7> color 2*White }

  #declare Animate=true;      // Set "true" to render animation

  // Generate the cone rising from the base
  #declare ConeHeight = 2;

  #declare RayCone=

#if (Animate)                 // for animation, show intersection with box
  intersection  {
#end                          // for static scene, show whole cone
    cone {
      < 0,      0,     0 >, 1.0
      < 0, ConeHeight, 0 >, 0.05
      no_shadow
      pigment { White  transmit 0.7 }
    }

#if (Animate)                 // Box grows to reveal more in each frame
    box  {
      <-1,        -1,                 -1 >,
      < 1,  clock*ConeHeight - 0.001,  1 >   // subtract 0.001 to avoid
clock==0 artifacts
      no_shadow
      pigment { White  transmit 0.7 }
    }
  }
#end

  // Display appropriate portion of cone
  union
  {
    object { RayCone }
    translate y*1
  }

Post a reply to this message

Wasn't it White Ryder who wrote:
>I created a static scene in POV-Ray and successfully suppressed shadows with
>no_shadow.  However when I modified the file for animation I found that the
>shadows appeared in the rendered frames despite the no_shadow keyword.  In
>the animated version, the no_shadow object gradually appears by displaying
>an intersection of the object with a box that grows larger with the value of
>clock.  (I even made the box no_shadow as well, but I still see a shadow.)
>When I don't do the intersection, the shadow goes away.

You need to apply "no_shadow" to the whole intersection, not to the
component parts.

The simplest thing to do is to do it when you invoke the object, so you
don't have to handle the animate and non-animate differently.

    object { RayCone no_shadow}


-- 
Mike Williams
Gentleman of Leisure

Post a reply to this message

Mike Williams <nos### [at] econymdemoncouk> wrote:
>
> You need to apply "no_shadow" to the whole intersection, not to the
> component parts.
>


Yes, that was exactly it, thanks.

I had assumed that the "no_shadow" would propagate to the intersection,
but apparently not.  :P

Thank you for your quick answer!

White Ryder

Post a reply to this message