Hi all, especially Houston!

I've got a problem.

I want to set up an underwater station with spotlights pointing in +/- all
directions. The scene I made produced some strange artefacts (not shown
here).

So I set up a test scene containing 11 spots, media and cam only. I could
see black circles produced at the end of the spots pointing towards -z.

What can I do to get rid of these?

The athmospheric media (medium...) is Rayleigh or Henyey-Greenstein
scattering. System is Windows XP.

The scene (below) should render in ~20 s at medium image size.

Hope you could give me some hints!

Yours,
Bu.




////////////////////////////////////
// Persistence of Vision Ray Tracer Scene Description File
// File: ?.pov
// Vers: 3.6
// Desc: Basic Scene Example
// Date: mm/dd/yy
// Auth: Burki
//

// #version 3.6;


global_settings {
  assumed_gamma 1.0
  max_trace_level 15  //         <--- Max Trace quite high
  ambient_light 0
}

// ---------------------- CAM ------------------

camera {
  location  <0.0, 4.5, -12.0>
  direction 1.2*z
  right     x*image_width/image_height
  look_at   <0.0, 0.0,  0.0>
}


// -------- Athmospheric Media ---------

media {
  scattering {
     4,                      // 4=Rayleigh; 5=Henyey-Greenstein
     rgb <0.4, 1, 0> * 0.02  // color / 'density'
  }
  method 3               // adaptive sampling
}



#declare spot =
light_source {
  0
  color rgb 100                 //  LIGHT COLOR 100 !!!
  spotlight
  translate <1, 0.0, 0>         // 1 unit right
  point_at  <2, 0.1, 0>         // slightly upward
  radius 5
  tightness 50
  falloff 8
  fade_distance 1               // fades fast
  fade_power 2
}



// number_of_spots Spots in a circle (e.g. eleven)
#declare spot_count = 0;
#declare number_of_spots = 11;
#while (spot_count < number_of_spots)
        object {
                spot
                rotate spot_count * 360/number_of_spots *y
        }
#declare spot_count = spot_count + 1;
#end


// no objects, just light, media and cam.

///////////////////////////////////// END

Post a reply to this message

"Burki" <nomail@nomail> wrote:
> spotlights pointing in +/- all directions. The scene I made produced some
> strange artefacts
> What can I do to get rid of these?

Hi Burki!
You're trying to cast spotlights towards infinity... and, quoting
3.3.2.1  Atmospheric Media :
"Note: POV-Ray cannot sample media along an infinitely long ray. The ray
must be finite in order to be possible to sample. This means that sampling
media is only possible for rays that hit an object. "
The black circles are not in the z-negative direction but rather in the
z-positive. They show up when Pov stops sampling after some length of the
cone of light. Add a plane {z, 2000 inverse pigment {rgb .5}} to your
scene, you'll discover that pov stops sampling around +2000 in the z
direction. Hence a possible workaround: arrange your scene so that theres
something for the spotlight to hit before +2000*z, or tweak the camera so
that these artifacts are out of view.

Hoping this helps!

JYR
-----------------------------------------------------
Windows XP HomeEdition//AMD Athlon XP 2800+1 MB RAM

Post a reply to this message

On second thought... You have a short fade distance, thus a short visible
light cone . Try adding a transparent plane not too far in the z-positive
direction :
plane {z, 200 inverse pigment {rgbt 1}}
just to limit the sampling distance. Then, of course, i don't know what your
whole scene should look like, maybe this is not an option...

JYR
-----------------------------------------------------
Windows XP HomeEdition//AMD Athlon XP 2800+//1 MB RAM

Post a reply to this message

Burki nous apporta ses lumieres en ce 2005-06-20 06:52:
> Hi all, especially Houston!
> 
> I've got a problem.
> 
> I want to set up an underwater station with spotlights pointing in +/- all
> directions. The scene I made produced some strange artefacts (not shown
> here).
> 
> So I set up a test scene containing 11 spots, media and cam only. I could
> see black circles produced at the end of the spots pointing towards -z.
> 
> What can I do to get rid of these?
> 
> The athmospheric media (medium...) is Rayleigh or Henyey-Greenstein
> scattering. System is Windows XP.
> 
> The scene (below) should render in ~20 s at medium image size.
> 
> Hope you could give me some hints!
> 
> Yours,
> Bu.
> 
> 
> 
> 
> ////////////////////////////////////
> // Persistence of Vision Ray Tracer Scene Description File
> // File: ?.pov
> // Vers: 3.6
> // Desc: Basic Scene Example
> // Date: mm/dd/yy
> // Auth: Burki
> //
> 
> // #version 3.6;
> 
> 
> global_settings {
>   assumed_gamma 1.0
>   max_trace_level 15  //         <--- Max Trace quite high
>   ambient_light 0
> }
> 
> // ---------------------- CAM ------------------
> 
> camera {
>   location  <0.0, 4.5, -12.0>
>   direction 1.2*z
>   right     x*image_width/image_height
>   look_at   <0.0, 0.0,  0.0>
> }
> 
> 
> // -------- Athmospheric Media ---------
> 
> media {
>   scattering {
>      4,                      // 4=Rayleigh; 5=Henyey-Greenstein
>      rgb <0.4, 1, 0> * 0.02  // color / 'density'
>   }
>   method 3               // adaptive sampling
> }
> 
> 
> 
> #declare spot =
> light_source {
>   0
>   color rgb 100                 //  LIGHT COLOR 100 !!!
>   spotlight
>   translate <1, 0.0, 0>         // 1 unit right
>   point_at  <2, 0.1, 0>         // slightly upward
>   radius 5
>   tightness 50
>   falloff 8
>   fade_distance 1               // fades fast
>   fade_power 2
> }
> 
> 
> 
> // number_of_spots Spots in a circle (e.g. eleven)
> #declare spot_count = 0;
> #declare number_of_spots = 11;
> #while (spot_count < number_of_spots)
>         object {
>                 spot
>                 rotate spot_count * 360/number_of_spots *y
>         }
> #declare spot_count = spot_count + 1;
> #end
> 
> 
> // no objects, just light, media and cam.
> 
> ///////////////////////////////////// END
> 
> 
> 
> 
> 
There are to few samples for your situation,
Put your media in a large hollow box as follow:
box{50,-50 pigment{rgbt 1}
	interior{
		media {
		  scattering {
		     4,                      // 4=Rayleigh; 5=Henyey-Greenstein
		     rgb <0.4, 1, 0.0> * 0.02  // color / 'density'
		  }
		  method 3   // adaptive sampling. default, don't need to specify
		  samples 15 // increase as needed, weak effect on render time
		}
	}
	hollow
}
This will limit the rays to a finite distance. I increased the number of samples, it
was also a 
cause of your artefacts.

Alain

Post a reply to this message

JYR <jyr### [at] hotmailcom> wrote:

> Note: POV-Ray cannot sample media along an infinitely long ray.

I'd simply forgotton this not so unimportant fact ...



Alain <ele### [at] netscapenet> wrote:

> There are to few samples for your situation.

Yes ! Now it begins to work. I also increased the intervals in the test
scene. In the original scene the beams looked a bit like a string of beads.
Increasing the intervals from 10 to 30 helped to produce a more constant
beam. But this also demands a greater rendering time.

Originally I wanted that a spot should shine out of every window. As I made
7x49 windows in total I think I'm going to drop this idea ...

You helped me a lot, especially in encouraging me to read more in the help
files   :)

Thanks,
Bu.

Post a reply to this message

Burki nous apporta ses lumieres en ce 2005-06-21 17:06:
> JYR <jyr### [at] hotmailcom> wrote:
> 
> 
>>Note: POV-Ray cannot sample media along an infinitely long ray.
> 
> 
> I'd simply forgotton this not so unimportant fact ...
> 
> 
> 
> Alain <ele### [at] netscapenet> wrote:
> 
> 
>>There are to few samples for your situation.
> 
> 
> Yes ! Now it begins to work. I also increased the intervals in the test
> scene. In the original scene the beams looked a bit like a string of beads.
> Increasing the intervals from 10 to 30 helped to produce a more constant
> beam. But this also demands a greater rendering time.
> 
> Originally I wanted that a spot should shine out of every window. As I made
> 7x49 windows in total I think I'm going to drop this idea ...
Have a parallel light_source some distence away. Using a single light can help reduce
your render 
time. Be sure that it's far enough so that anything suposed to cast a shadow is closer
than the 
location of your light.
> 
> You helped me a lot, especially in encouraging me to read more in the help
> files   :)
> 
> Thanks,
> Bu.
> 
> 
Using method 3, it's beter to increase samples than intervels. Less chance to get
artefacts and 
normaly faster.
My tests using your sample scene: (render times)
intervals 25 in 14' 31"
samples 25 in 2' 46" still some artefacts
samples 50 in 5' 04" no notable artefact, smooth, at least as good as 25 intervals
samples 75 in 6' 59" very, very smooth, probably overkill
samples 100 in 8' 57" no notable improvement, overkill

Alain

Post a reply to this message

Alain <ele### [at] netscapenet> wrote:

> Using method 3, it's beter to increase samples than intervels. Less chance to get
> artefacts and normaly faster.

Thanks, Alain!

I repeated your experiments and came to the same results. Not exact the same
time of course. I put everything in a 'sphere {0,50 hollow}'.
This was really very helpful.

Yours,
Bu.

Post a reply to this message