POV-Ray: Newsgroups: povray.newusers: using a helix_1 as a coil or helical spring, what is the Parameter P1

POV-Ray : Newsgroups : povray.newusers : using a helix_1 as a coil or helical spring, what is the Parameter P1		Server Time 2 Nov 2024 13:21:14 EDT (-0400)

From: rossy
Subject: using a helix_1 as a coil or helical spring, what is the Parameter P1
Date: 7 Jan 2004 12:20:02
Message: <web.3ffc3f09f3aad12ea840cd570@news.povray.org>

Hallo

it follows a cut out of the User Manual:
f_helix1(x,y,z, P0, P1, P2, P3, P4, P5, P6)

P0 : Number of helixes - e.g. 2 for a double helix
P1 : Period - is related to the number of turns per unit length
P2 : Minor radius (major radius > minor radius)
P3 : Major radius
P4 : Shape parameter. If this is greater than 1 then the tube becomes fatter
in the y direction
P5 : Cross section type
P6 : Cross section rotation angle (degrees)
What does "is related to the number of turns per unit length " exactly mean.


a movie of a moving coil spring.

coil spring but the same number of windings.
hopefully someone is able to help me, its very urgent!!
I want to use it for a presentation of my final career project
Thanks
Martin alias rossy

Post a reply to this message

From: Stephen McAvoy
Subject: Re: using a helix_1 as a coil or helical spring, what is the Parameter P1
Date: 7 Jan 2004 14:40:33
Message: <s4oovvkcpdt3hchg3u5c23vaobh10cjhlv@4ax.com>

On Wed,  7 Jan 2004 12:16:57 EST, "rossy" <nomail@nomail> wrote:

>hopefully someone is able to help me, its very urgent!!



look under Spring is sprung. Tue, 23 Sep 2003.

#declare SpringHeight = 6;
#declare SpringMajorRadius = 1;
#declare SpringMinorRadius = .1;
#declare SpringRevolutions = 10;
#declare SpringSegments = 1000;

union
{
  #declare Ind = 0;
  #while(Ind <= SpringSegments)
    #declare Pos2 =
      vrotate(<SpringMajorRadius, SpringHeight*Ind/SpringSegments, 0>,
              y*360*SpringRevolutions*Ind/SpringSegments);
    #if(Ind > 0)
      cylinder { Pos1, Pos2, SpringMinorRadius }
      sphere { Pos2, SpringMinorRadius }
    #end
    #declare Pos1 = Pos2;
    #declare Ind = Ind+1;
  #end

  pigment { rgb 1 } finish { specular .5 }
  translate -y*4
}



Regards
        Stephen

Post a reply to this message

From: Mike Williams
Subject: Re: using a helix_1 as a coil or helical spring, what is the Parameter P1
Date: 7 Jan 2004 15:57:52
Message: <kJ$ReKAAKH$$EwJo@econym.demon.co.uk>

Wasn't it rossy who wrote:
>Hallo
>
>it follows a cut out of the User Manual:
>f_helix1(x,y,z, P0, P1, P2, P3, P4, P5, P6)
>
>P0 : Number of helixes - e.g. 2 for a double helix
>P1 : Period - is related to the number of turns per unit length
>P2 : Minor radius (major radius > minor radius)
>P3 : Major radius
>P4 : Shape parameter. If this is greater than 1 then the tube becomes fatter
>in the y direction
>P5 : Cross section type
>P6 : Cross section rotation angle (degrees)
>What does "is related to the number of turns per unit length " exactly mean.
>

>a movie of a moving coil spring.

>coil spring but the same number of windings.
>hopefully someone is able to help me, its very urgent!!
>I want to use it for a presentation of my final career project

I was a bit vague when I wrote that bit of my Isosurface tutorial (that
then got incorporated into the 3.5 documentation).

Since then, I've come to the conclusion that it's the number of radians
through which each helix turns in a unit length. So, for example, this
helix turns through two complete turns between y=-1 and y=1. 
[2Pi = one revolution per unit length]

isosurface {
  function { f_helix1(x,y,z,1,2*pi,0.01,1,1,1,0) }
  max_gradient 3
  contained_by{box {-1,1}}
}


-- 
Mike Williams
Gentleman of Leisure

Post a reply to this message