This is the file that create me problems with the column created with
lathe. No binary file, this time...


// Persistence of Vision Ray Tracer Scene Description File
// File: col.pov
// Vers: 3.5
// Desc: Esempi di colonne
// Date: inizio 02/02/2003
// Auth: Daniele Lupo alias Jepessen
//                                  


/*
	column_1: a simple column
	column_2: a simple rastremated column
	...
	
*/


#version 3.5;

#include "colors.inc"

global_settings {
  assumed_gamma 1.5
}

// ----------------------------------------

camera {
  location  <0.0, 20, 5>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0.0,0.0,5>
  //angle 10
}

light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 30, 30>
}

// ----------------------------------------




//creation to a shape necessary to create column_4

#declare temp = 1;
#declare to_subtract_1 = sphere_sweep {
	linear_spline
	2,
	<0,0,1>,.1
	<0,0,9>,.1
	
	translate 0.7*x
}

#while (temp < 20)
	#declare to_subtract_1 = union {
		object {to_subtract_1}
		sphere_sweep {
			linear_spline
			2,
			<0,0,1>,.1
			<0,0,9>,.1
			translate 0.7*x
			rotate <0,0,18>*temp
		}
	}
	#declare temp = temp + 1;
#end

//creation of a shape necessary to create column_5

#declare temp = 1;
#declare to_subtract_2 = sphere_sweep {
	linear_spline
	2,
	<0,0,1>,.095
	<-0.25,0,9>,.06
	
	translate 0.8*x
}

#while (temp < 20)
	#declare to_subtract_2 = union {
		object {to_subtract_2}
		sphere_sweep {
			linear_spline
			2,
			<0,0,1>,.095
			<-0.25,0,9>,.06
	
			translate 0.8*x
			rotate <0,0,18>*temp
		}
	}

	#declare temp = temp + 1;
#end

//end of creation of the shape


#declare column_1 = union {
	box {
		<-1,-1,0>
		<1,1,0.5>
	}
	box {
		<-1,-1,9.5>
		<1,1,10>
	}
	cylinder {
		<0,0,0.5>
		<0,0,9.5>
		0.7
	}
	
}

//Simple rastremated column

#declare column_2 = union {
	box {
		<-1,-1,0>
		<1,1,0.5>
	}
	box {
		<-1,-1,9.5>
		<1,1,10>
	}
	
	cone {
		<0,0,0.5>,0.8
		<0,0,9.5>,0.55
	}
		
}


#declare column_3 = union {
	box {
		<-1,-1,0>
		<1,1,0.5>
	}
	box {
		<-1,-1,9.5>
		<1,1,10>
	}
	lathe {
		quadratic_spline
		3,
		<.3,-5>
		<.8,.5>
		<.6,9.5>
		
		rotate <90,0,0>
		
	}
	

	
}

#declare column_4 = difference {
	object {column_1}
	object {to_subtract_1}
}

#declare column_5 = difference {
	object {column_2}
	object {to_subtract_2}
}

//--------------------------

//visualization of columns
  
object {column_1
	pigment{
		color White
	}
		translate <5,0,0> 
	

}

object {
	column_2
	pigment {
		color White
	}
	translate 2.5*x
}

object {
	column_3
	pigment {
		color White
	}
}

object {
	column_4
	pigment {
		color White
	}
	translate -2.5*x
}

object {
	column_5
	pigment {
		color White
	}
	translate -5.0*x
}

Post a reply to this message

Please keep in mind it helps others if you can locate and post the actual
part of a script you think has a problem instead of an entire scene file.
But also including a camera and light source. Don't worry about it, just
telling you what is easiest to get help with.

In this case the answer is surprisingly simple. Add the keyword 'sturm' to
your lathe in column_3, just before the 'rotate' line and after the last
vector. The reason is explained in the documentation, it has to do with
inaccuracies of the math involved.

Bob

Post a reply to this message

Thanks for the help. Bob.

And exsuse me for problems about scene posting...
I'll remember this for other postings... Sorry for this problem.


Daniele

On Sat, 8 Feb 2003 09:31:37 -0600, "hughes, b."
<omn### [at] charternet> wrote:

>Please keep in mind it helps others if you can locate and post the actual
>part of a script you think has a problem instead of an entire scene file.
>But also including a camera and light source. Don't worry about it, just
>telling you what is easiest to get help with.
>
>In this case the answer is surprisingly simple. Add the keyword 'sturm' to
>your lathe in column_3, just before the 'rotate' line and after the last
>vector. The reason is explained in the documentation, it has to do with
>inaccuracies of the math involved.
>
>Bob
>

Post a reply to this message