Having been around POV-Ray for some time, I'm sure I should know how
to do this, but somehow the proper effect continues to elude me...

I have some text in my scene I'd like to draw special attention to.
It would be rather nice to have some sort of 'highlight' effect where
the particular word I'd like to emphasize flashes as if a bright light
were crossing a shiny metal surface.  Try as I might, I cannot seem to
reproduce this effect to my satisfaction.

Eventually, I'll animate the effect to show a diagonal flash of light
passing over the word, sort-of like you might see in some 1970's
Marvel Comics type film.

Any ideas?

- How

Post a reply to this message

"How Camp" <kro### [at] hotmailcom> wrote in message
news:vhl360dkcd3b2l630nvvo05b1s0714s1p3@4ax.com...
>
> I have some text in my scene I'd like to draw special attention to.
> It would be rather nice to have some sort of 'highlight' effect where
> the particular word I'd like to emphasize flashes as if a bright light
> were crossing a shiny metal surface.  Try as I might, I cannot seem to
> reproduce this effect to my satisfaction.
>
> Eventually, I'll animate the effect to show a diagonal flash of light
> passing over the word, sort-of like you might see in some 1970's
> Marvel Comics type film.


Something like the super- (ha ha! little pun about comics) simple script
below?

You could probably reflect the light's box in the overlying plane too for a
lens flare effect, but what's really needed there is a true lens flare.

camera {
 location <0,0,-3>
 look_at <0,0,0>
}

#declare LightBox=box {-1,1 pigment {rgb 1} finish {ambient 1} scale
<0.25,5,0.1> rotate -45*z}

light_source {
 -10*z,1
 looks_like {LightBox}
 rotate <0,(45-90*clock),0>
}

//background {color rgb 1}

plane {
 z,-0.25
 pigment {
  rgbt 0.99
 }
 normal {
  bumps 0.1 scale 0.001
 }
 finish {
  ambient 0 diffuse 1
  specular 0.05 roughness 0.005
 }
}

text {
 ttf "times.ttf"
 "Flashy Text", 0.25, 0
 pigment {
  color rgb <1,0.9,0.3>
 }
 finish {
  ambient 0.1 diffuse 0.2
  specular 0.5 roughness 0.001
  metallic brilliance 2
  reflection {
   <1,0.9,0.3>,0.5
   metallic
  }
 }
 scale 0.5 translate <-1.25,-0.125,-0.125>
}


-- 
Bob H.
http://www.3digitaleyes.com

Post a reply to this message

On Wed, 24 Mar 2004 14:45:46 -0600, "Hughes, B."
<omn### [at] charternet> wrote:

>Something like the super- (ha ha! little pun about comics) simple script
>below?

Thanks, Bob, this is exactly the sort of effect I'm looking for.  I've
tried this approach before, just as you did, with varying success.
However, I had not thought to use "looks_like" in my light_source to
limit it's effects.  Is there a way to make a particular light only
interact with a single object?

- How

Post a reply to this message

"How Camp" <kro### [at] hotmailcom> wrote in message
news:r3t360pqf1patsd6kfftqaeveiobov4ukk@4ax.com...
>
> Thanks, Bob, this is exactly the sort of effect I'm looking for.

Very welcome.

> Is there a way to make a particular light only
> interact with a single object?

If you use version 3.5 (also beta 3.6), there is. Let's see... the 3.5 docs
tell more about it in section 6.5.8 if you want to check into that more. My
example would be like:

light_group {
    light_source {...} // Only this light affects the object included.
    text {...} // Included object.
    global_lights off // No other lights allowed to affect this.
}

light_source {...} // This one doesn't affect the above, unless
global_lights is 'on'.

Post a reply to this message

On Wed, 24 Mar 2004 16:24:27 -0600, "Hughes, B."
<omn### [at] charternet> wrote:

>
>If you use version 3.5 (also beta 3.6), there is. Let's see... the 3.5 docs
>tell more about it in section 6.5.8 if you want to check into that more. My
>example would be like:
>
>light_group {
>    light_source {...} // Only this light affects the object included.
>    text {...} // Included object.
>    global_lights off // No other lights allowed to affect this.
>}
>
>light_source {...} // This one doesn't affect the above, unless
>global_lights is 'on'.
>

Perfect!  Now, I just need to make the effect quite brilliant.  That
shouldn't be too difficult.  Thanks for the help!

- How

Post a reply to this message

On Wed, 24 Mar 2004 20:47:54 -0600, How Camp <kro### [at] hotmailcom>
wrote:

>Perfect!

I spoke too soon.  My understanding from reading the docs (6.5.8, as
Bob pointed out) is that a light_group can be formed with a
light_source and another object, and the indicated light_source will
only affect the object(s) in the light_group.

...So, what am I doing wrong in the following scene?  Somehow, my
light in the light_group is affecting the two text objects outside the
group.

Incidentally, this effect seems to disappear if I comment out the
'looks_like {LightBox}' line in the scene.



camera {
 location <0,0,-5>
 look_at <0,0,0>
}

#declare LightBox=
box {
   <-1,-5,-1>,<1,5,1> 
   texture {
      pigment {rgb 1} 
      finish {ambient 1} 
   }
   scale <0.25,5,0.1> 
   rotate -45*z
}

//light_source {<-10,5,-10>,1}

#declare MainTex = 
texture {
   pigment {
      color rgb <1,0.9,0.3>
   }
   finish {
      ambient 0.1 diffuse 0.2
      specular 0.5 roughness 0.001
      metallic brilliance 2
      reflection {
         <1,0.9,0.3>,0.5
         metallic
      }
   }
}

light_group {

   light_source {
      -10*z,<1,0,0>
      looks_like {LightBox}
      rotate <0,(45-90*0.5),0>
   }

   text {
      ttf "times.ttf"
      "Flashy Text", 0.25, 0
      texture {MainTex}
      scale 0.5 translate <-1.25,-0.125,-0.125>
   }
   global_lights
}

text {
   ttf "times.ttf"
   "Top Text Above", 0.25, 0
   texture {MainTex}
   scale 0.5 translate <-1.25,0.625,-0.125>
}

text {
   ttf "times.ttf"
   "Bottom Text Below", 0.25, 0
   texture {MainTex}
   scale 0.5 translate <-1.25,-0.725,-0.125>
}




- How

Post a reply to this message

On Wed, 24 Mar 2004 23:09:38 -0600, How Camp <kro### [at] hotmailcom> wrote:

> On Wed, 24 Mar 2004 20:47:54 -0600, How Camp <kro### [at] hotmailcom>
> wrote:
>
>> Perfect!
>
> I spoke too soon.  My understanding from reading the docs (6.5.8, as
> Bob pointed out) is that a light_group can be formed with a
> light_source and another object, and the indicated light_source will
> only affect the object(s) in the light_group.
>
> ...So, what am I doing wrong in the following scene?  Somehow, my
> light in the light_group is affecting the two text objects outside the
> group.
>
> Incidentally, this effect seems to disappear if I comment out the
> 'looks_like {LightBox}' line in the scene.

<snip code>

Remove the finish {ambient 1}  from the LightBox, light_group constrains 
the light_source but the box is producing it's own 'light' from the 
ambient which is not stopped and is being reflected in the text, keep the 
ambient and change the LightBox to pigment {rgb <0,1,1>}  and you should 
see what I mean.

HTH

--
Phil

-- 
All thoughts and comments are my own unless otherwise stated and I am 
happy to be proven wrong.

Post a reply to this message

"Phil Cook" <phi### [at] nospamdeckingdealscouk> wrote in message
news:opr5ezuie0p4ukzs@news.povray.org...
> On Wed, 24 Mar 2004 23:09:38 -0600, How Camp <kro### [at] hotmailcom>
wrote:
>
> > I spoke too soon.  My understanding from reading the docs (6.5.8, as
> > Bob pointed out) is that a light_group can be formed with a
> > light_source and another object, and the indicated light_source will
> > only affect the object(s) in the light_group.
>
> Remove the finish {ambient 1}  from the LightBox, light_group constrains
> the light_source but the box is producing it's own 'light' from the
> ambient which is not stopped and is being reflected in the text

Yep, unfortunately light groups are for lights and do not do anything else
to the objects in the scene except to shine for what's included in their
respective groups.

CSG is possble, so there's some chance of fixing it up using that. At least,
I've found that bounding the looks_like object to the text seems to be one
possibility. Only problem with it is the illumination is, of course, then
from that same text. You can face the camera the other way and see that
using the changed script below.

camera {
 location <0,0,-5> // +5 z to see light object
 look_at <0,0,0>
}

#declare MainTex =
texture {
   pigment {
      color rgb <1,0.9,0.3>
   }
   finish {
      ambient 0.1 diffuse 0.2
      specular 0.5 roughness 0.001
      metallic brilliance 2
      reflection {
         <1,0.9,0.3>,0.5
         metallic
      }
   }
}

#declare FlashyText=
   text {
      ttf "times.ttf"
      "Flashy Text", 0.25, 0
      scale 0.5 translate <-1.25,-0.125,-0.125>
   }

#declare LightBox=
box {
   <-1,-5,-1>,<1,5,1>
   texture {
      pigment {rgb 1}
      finish {ambient 1}
   }
   scale <0.25,5,0.1>
   rotate -45*z
   bounded_by {FlashyText scale <0.5,5,1>}
}

//light_source {<-10,5,-10>,1}

light_group {

   light_source {
      -10*z,<1,0,0>
      looks_like {LightBox}
      rotate <0,(30-60*clock),0>
   }
   object {FlashyText texture {MainTex}}
   global_lights
}

text {
   ttf "times.ttf"
   "Top Text Above", 0.25, 0
   texture {MainTex}
   scale 0.5 translate <-1.25,0.625,-0.125>
}

text {
   ttf "times.ttf"
   "Bottom Text Below", 0.25, 0
   texture {MainTex}
   scale 0.5 translate <-1.25,-0.725,-0.125>
}

Post a reply to this message

On Thu, 25 Mar 2004 09:59:28 -0600, "Hughes, B."
<omn### [at] charternet> wrote:

>"Phil Cook" <phi### [at] nospamdeckingdealscouk> wrote in message
>news:opr5ezuie0p4ukzs@news.povray.org...
>>
>> Remove the finish {ambient 1}  from the LightBox, light_group constrains
>> the light_source but the box is producing it's own 'light' from the
>> ambient which is not stopped and is being reflected in the text
>
>Yep, unfortunately light groups are for lights and do not do anything else
>to the objects in the scene except to shine for what's included in their
>respective groups.


Thank you both - this makes perfect sense.  I'll see what I can come
up with.

- How

Post a reply to this message

On Thu, 25 Mar 2004 09:59:28 -0600, Hughes, B. <omn### [at] charternet> 
wrote:

> "Phil Cook" <phi### [at] nospamdeckingdealscouk> wrote in message
> news:opr5ezuie0p4ukzs@news.povray.org...
>> On Wed, 24 Mar 2004 23:09:38 -0600, How Camp <kro### [at] hotmailcom>
> wrote:
>>
>> > I spoke too soon.  My understanding from reading the docs (6.5.8, as
>> > Bob pointed out) is that a light_group can be formed with a
>> > light_source and another object, and the indicated light_source will
>> > only affect the object(s) in the light_group.
>>
>> Remove the finish {ambient 1}  from the LightBox, light_group constrains
>> the light_source but the box is producing it's own 'light' from the
>> ambient which is not stopped and is being reflected in the text
>
> Yep, unfortunately light groups are for lights and do not do anything 
> else
> to the objects in the scene except to shine for what's included in their
> respective groups.
>
> CSG is possble, so there's some chance of fixing it up using that. At 
> least,
> I've found that bounding the looks_like object to the text seems to be 
> one
> possibility. Only problem with it is the illumination is, of course, then
> from that same text. You can face the camera the other way and see that
> using the changed script below.

<snip code>

Shame there's no such thing as an object_group equivalent though I suspect 
that would be computationally hideous. Quite funky though for effects like 
the sphere in "Sphere" reflects the room but not the people.

-
Phil

-- 
All thoughts and comments are my own unless otherwise stated and I am 
happy to be proven wrong.

Post a reply to this message