It seems clear how to duplicate the glass_old.inc textures, but how do I 
create an amethyst material?  Do I use all the amethyst colors or just 
one?  If more than one, how do I combine them?
Thanks,
John

Post a reply to this message

"John Dalbec" <jda### [at] cbosscom> wrote in message
news:40590668@news.povray.org...
> It seems clear how to duplicate the glass_old.inc textures, but how do I
> create an amethyst material?  Do I use all the amethyst colors or just
> one?  If more than one, how do I combine them?

Those colors are for attenuating the light through a transparent or
semitransparent object (clear-pigmented objects if not intending to change
the color). Just one is used, such as the following way:

#include "glass.inc"

sphere {
 0, 1
  material {
    texture {
      pigment {
       Col_Glass_Clear
      }
      finish {
       F_Glass9
      }
    }
    interior {
     I_Glass2
     fade_color Col_Amethyst_03 // example here
    }
  }
}

Although you could apply a color_map using them too:

#include "glass.inc"

sphere {
 0, 1
  material {
    texture {
      pigment {
       radial frequency 1 rotate 90*x
       color_map {
       [0.1 Col_Amethyst_01 filter 1]
       [0.1 Col_Amethyst_02 filter 1]
       [0.3 Col_Amethyst_02 filter 1]
       [0.3 Col_Amethyst_03 filter 1]
       [0.5 Col_Amethyst_03 filter 1]
       [0.5 Col_Amethyst_04 filter 0.5]
       [0.7 Col_Amethyst_04 filter 0.5]
       [0.7 Col_Amethyst_05 filter 0.5]
       [0.9 Col_Amethyst_05 filter 0.5]
       [0.9 Col_Amethyst_06 filter 0.5]
       }
      }
      finish {
       F_Glass9
      }
    }
    interior {
     I_Glass2
     fade_color rgb 1 // to see pigments above better
    }
  }
}

camera {
 location <0,0,-3>
 look_at <0,0,0>
}

light_source {
 -1000*z,1
 rotate <15,15,0>
}

background {color rgb 1}

All depends on what you're wanting to do, of course.

-- 
Bob H.
http://www.3digitaleyes.com

Post a reply to this message