It seems that my floor is floating.  why is it floating when y is 0?  Here's
my code:

#include "colors.inc"
#include "woods.inc"


background {color White}

light_source{
 0*x
 color White*1.1
 area_light
 <8,0,0> <0,0,8>
 8, 8
 adaptive 0
 jitter
 translate <40,180,40>
}

camera {
 location <0, 0, 11>
 look_at 0
 angle 40
}

// Right Wall

box{
 <1,1,1>,<-1,-1,-1>
 texture{
  pigment{
   color 1-(1-Khaki)*.490
  }
  normal{
   wrinkles 0.25
   scale 0.005
  }
  finish{
   ambient 0.266167
   diffuse 0.884867
  }
 }
 scale <0.1, 1.5, 3.5>
 translate <-2.938508, 0, .140896>
}

// Left Wall

box{
 <1,1,1>,<-1,-1,-1>
 texture{
  pigment{
   color 1-(1-Khaki)*.490
  }
  normal{
   wrinkles 0.25
   scale 0.005
  }
  finish{
   ambient 0.266167
   diffuse 0.884867
  }
 }
 scale <0.1, 1.5, 3.5>
 translate <2.938508, 0, .140896>
}

// back wall

box{
 <1,1,1>,<-1,-1,-1>
 texture{
  pigment{
   color 1-(1-Khaki)*.490
  }
  normal{
   wrinkles 0.25
   scale 0.005
  }
  finish{
   ambient 0.266167
   diffuse 0.884867
  }
 }
 scale <3.5, 1.86, 0.1>
 translate <0,0,-6.838508>
}


// The floor

#declare light_wood= pigment {P_WoodGrain7A  color_map {M_Wood7A} }
#declare  dark_wood= pigment {P_WoodGrain14A color_map {M_Wood14A} }

#declare board_length= 1.5;
#declare board_width= 0.25;

box{
 <2.938508,0,6.838508>,<-2.938508,0,-6.838508>
 pigment{
  gradient y triangle_wave
  pigment_map {
   [0.0 light_wood ]
   [1.0 dark_wood ]
  }
  warp{
   repeat board_length*z offset 0.37*y
  }
  warp{
   repeat board_width*x offset board_length*5/2*z
  }
 }
 normal {
  boxed
  slope_map {
   [0.5 <1,0>]
   [1.0 <0,0>]
  }
  bump_size 0.1
  scale <board_width,1,board_length>
  warp{
   repeat board_length*z
  }
  warp{
   repeat board_width*x offset board_length/2*z
  }
 }
}

Post a reply to this message

"Wade" <Zav### [at] aolcom> wrote in message
news:3b9857e0$1@news.povray.org...
> It seems that my floor is floating.  why is it floating when y is 0?
Here's
> my code:
>

<snip code>

All of your walls go from y=-1 to y=1, so the floor (at y=0) is floating in
the middle.
Either translate all your walls <0,1,0> or translate the floor <0,-1,0>

Gail
*************************************************************************
* gsh### [at] monotixcoza                *   Step into the abyss,           *
* http://www.rucus.ru.ac.za/~gail/   *   and let go.          Babylon 5 *
*************************************************************************
* Just think of me as the storm before the calm     Magic: The Gathering*
*************************************************************************

Post a reply to this message