POV-Ray : Newsgroups : povray.newusers : 1 vanishing point perspective : Re: 1 vanishing point perspective Server Time
30 Nov 2021 22:07:11 EST (-0500)
  Re: 1 vanishing point perspective  
From: Kenneth
Date: 4 Jan 2020 12:15:00
Message: <web.5e10c74642dc78e1d98418910@news.povray.org>
[I've been away from the newsgroups for a long time; this is my first post in
quite awhile!]

I'm not a 'student' of perspective in drawing (although I like to sketch a lot),
but I would say that POV's regular perspective camera, in and of itself,
produces the kind of views you're looking for.

The 'perspective' camera doesn't introduce any curvilinear distortions, the way
a real camera lens would. (I think that's because it's essentially a 'pinhole
camera'.)

To my mind, the number of vanishing points in a scene seems to depend on the
camera's viewpoint (and maybe the particular subject matter in the scene?) Maybe
that's a VERY obvious statement, ha. If the camera is looking 'straight
ahead'--and all of the scene objects' surface planes are  parallel or
orthogonal(?) to the camera plane-- then it looks like "1-point perspective" to
me. (That's my naive analysis, anyway.)

Here's a really simple scene to experiment with. The appearence of the rotated
cube looks like... 2-point perspective?
-------

#version 3.7;
global_settings {assumed_gamma 1.0}
default{finish{ambient 1 diffuse 0}}

camera {
  perspective
  location  <1.7, 2.9, -4.2> // experiment with these settings
  look_at   <1.7, 2.9, 0>
  right     x*image_width/image_height
  angle 80 // a very wide-angle view, just to show the results
}

background{rgb .1}

plane{y,0
     no_shadow
         pigment{
                checker
                rgb <1,0,0>
                rgb 0
                scale 4
                }
         }

box{0,2
 pigment{checker scale .25}
 rotate 45*y
 translate 1.5*x
 }

difference{
box{0,5 translate <-2.5,0,-2.5>}
box{0,4.5 translate <-2.25,.25,-3.0>}
pigment{
   average
   pigment_map{
        [1 gradient z
            frequency 2
            color_map{
                  [.5 rgb .1]
                  [.5 rgb 1]
                     }
        ]
        [1 gradient y
            frequency 2
            color_map{
                  [.5 rgb .1]
                  [.5 rgb 1]
                     }
        ]
             }

             translate -.001
        }
        translate <1,0,3>
        }


Post a reply to this message

Copyright 2003-2021 Persistence of Vision Raytracer Pty. Ltd.