Hello

Every time when I tried to render the scene I've got different results. The
difference was in the lighting of the scene. In the scene there is only one HDR
sky_sphere.

I am using official 3.7 build on Windows and unofficial MacOS build 3.7.1.

Is there something I've missed?

Here are two examples of the resulting image: https://ibb.co/gR9VkQ

Here is complete test scene:

#version 3.7;

#include "colors.inc"
#include "finish.inc"

#default{
  finish{
    ambient 0
    diffuse 1
  }
}

global_settings {
  radiosity {
    pretrace_start 0.08
    pretrace_end   0.04
    count 35

    nearest_count 5
    error_bound 1.8
    recursion_limit 3

    low_error_factor .5
    gray_threshold 0.0
    minimum_reuse 0.015
    brightness 1

    adc_bailout 0.01/2
  }
}

sky_sphere{
  pigment{
    image_map {
      hdr "..\kitchen_probe.hdr"
      map_type 1
      interpolate 4
    }
  } // end of pigment
} //end of skysphere -----

// perspective (default) camera
camera {
  location  <0.0, 1.2, -2.0>
  look_at   <0.0, 0.5,  0.0>
  right     x*image_width/image_height
}


// scene
sphere{ <0,0,0>, 0.5
  texture{
    pigment{ DimGray }
    finish{ Dull }
  } // end of texture
  translate <0, 0.5, 0>
}

plane{
  <0,1,0>, 0  hollow // normal vector, distance to zero ----
  texture{
    pigment{ Gray }
    finish{ Dull }
  } // end of texture
}

Post a reply to this message

Le 28/07/2017 à 11:44, gregors a écrit :
> Hello
> 
> Every time when I tried to render the scene I've got different results. The
> difference was in the lighting of the scene. In the scene there is only one HDR
> sky_sphere.
> 
> I am using official 3.7 build on Windows and unofficial MacOS build 3.7.1.
> 
> Is there something I've missed?
> 
> Here are two examples of the resulting image: https://ibb.co/gR9VkQ
> 
> Here is complete test scene:

Nearly complete, missing kitchen_probe.hdr
(I found one at
http://www.cgadvertising.com/pages/free-materials/hdr-maps.php

)

It can be reproduced simply adding +KFI0 +KFF10 (here on linux, so not
platform specific)

Yet, have you read http://wiki.povray.org/content/HowTo:Use_radiosity ?

Radiosity is not reproducible (there is a lot of randomness in it), you
need to save & reload radiosity data if you want always the same result
(such as in animation).

Post a reply to this message

Le_Forgeron <jgr### [at] freefr> wrote:
> Le 28/07/2017 à 11:44, gregors a écrit :
> > Hello
> >
> > Every time when I tried to render the scene I've got different results. The
> > difference was in the lighting of the scene. In the scene there is only one HDR
> > sky_sphere.
> >
> > I am using official 3.7 build on Windows and unofficial MacOS build 3.7.1.
>
> It can be reproduced simply adding +KFI0 +KFF10 (here on linux, so not
> platform specific)
>
> Yet, have you read http://wiki.povray.org/content/HowTo:Use_radiosity ?
>
> Radiosity is not reproducible (there is a lot of randomness in it), you
> need to save & reload radiosity data if you want always the same result
> (such as in animation).

Since you said that I had to check to be sure, I know there's always some
resampling going on even when always_sample off is being used. Or so I believe,
and the doc seems to say same.
Having tried the animation using command line +rf"hdr_rad" for one frame and
adding +rfi for the other frames, animated it still flickers from changes to the
radiosity.

Before doing that I was trying higher count and some other settings. I had also
used a different hdr file in place of the kitchen.

I was able to render successive frames without visible deviations by using count
>1600 called the Halston method in the docs.

Maybe the other settings contribute to the smoothness too.

I'm still not very good with radiosity settings, I tend to find what looks best
for particular scenes while trying for fast renders too.

Here's that global_settings from the test scene.

global_settings {
 assumed_gamma 1

  radiosity {
    pretrace_start 0.08
    pretrace_end   0.02
    count 1601 // >1600 is Halston method

 always_sample off
 //max_sample 0.9

    nearest_count 12
    error_bound 1.2
    recursion_limit 2//3

    low_error_factor 0.4
    gray_threshold 0.0
    minimum_reuse 0.015
    brightness 1

    adc_bailout 0.01/2
  }
}

Post a reply to this message

Thank you for the answers. They helped a lot.

Post a reply to this message

Le 17-07-28 à 05:44, gregors a écrit :
> Hello
> 
> Every time when I tried to render the scene I've got different results. The
> difference was in the lighting of the scene. In the scene there is only one HDR
> sky_sphere.
> 
> I am using official 3.7 build on Windows and unofficial MacOS build 3.7.1.
> 
> Is there something I've missed?
> 
> Here are two examples of the resulting image: https://ibb.co/gR9VkQ
> 
> Here is complete test scene:
> 
> #version 3.7;
> 
> #include "colors.inc"
> #include "finish.inc"
> 
> #default{
>    finish{
>      ambient 0
>      diffuse 1
Not a good idea. A value around 0.6 to 0.8 will give more realist 
results.> to    }
> }
> 
> global_settings {
>    radiosity {
>      pretrace_start 0.08
>      pretrace_end   0.04
Should be smaller, like 0.01 or even 0.005
>      count 35
MUCH to small for a pure radiosity scene. Ok in a scene using regular 
light_source.
Use at least 75, probably more.
Also, you should try the 2 parameters variation. The second value set a 
pool of samples directions. It help reduce artefacts.
try this :
count 160, 5555
> 
>      nearest_count 5
Maybe a little small.
Take advantage of the adaptive version :
nearest_count 5, 20
>      error_bound 1.8
Maybe a little smaller, like 0.9
This is OK when NOT using pure radiosity, but illuminating your scene 
with light_source.
>      recursion_limit 3
> 
>      low_error_factor .5
OK, but you may want to try something smaller here also. Good values 
range between 0.1 and 0.5
>      gray_threshold 0.0 // OK
>      minimum_reuse 0.015 // OK
>      brightness 1 // OK
> 
>      adc_bailout 0.01/2 // Probably OK
>    }
> }
> 
> sky_sphere{
>    pigment{
>      image_map {
>        hdr "..\kitchen_probe.hdr"
Take note that it's a single direction probe. It have a blind spot and 
you can see the camera.
>        map_type 1
>        interpolate 4
>      }
>    } // end of pigment
> } //end of skysphere -----
> 
> // perspective (default) camera
> camera {
>    location  <0.0, 1.2, -2.0>
>    look_at   <0.0, 0.5,  0.0>
>    right     x*image_width/image_height
> }
> 
> 
> // scene
> sphere{ <0,0,0>, 0.5
>    texture{
>      pigment{ DimGray }
>      finish{ Dull }
>    } // end of texture
>    translate <0, 0.5, 0>
> }
> 
> plane{
>    <0,1,0>, 0  hollow // normal vector, distance to zero ----
Why add «hollow»? It have absolutely no effect in this scene.
>    texture{
>      pigment{ Gray }
>      finish{ Dull }
>    } // end of texture
> }
> 
> 

Alain

Post a reply to this message

Le_Forgeron <jgr### [at] freefr> wrote:

>
> Yet, have you read http://wiki.povray.org/content/HowTo:Use_radiosity ?
>
> Radiosity is not reproducible (there is a lot of randomness in it), you
> need to save & reload radiosity data if you want always the same result
> (such as in animation).

I recently discovered this random light-patch-brightness as well (while
animating my 'city buildings.') I thought it was because I had used the rather
crude default values for radiosity. Saving and reloading the data sounds like a
good idea.

I need to read the up-to-date documentation; haven't done so in a long while.
I don't think I've ever tried using radiosity in an animation, until now.

Thanks for clarifying.

Post a reply to this message

"omniverse" <omn### [at] charternet> wrote:
>
>   radiosity {
>     pretrace_start 0.08
>     pretrace_end   0.02
>     count 1601 // >1600 is Hal(-s)ton method
>
>  always_sample off
>  //max_sample 0.9
>
>     nearest_count 12
>     error_bound 1.2
>     recursion_limit 2//3
>
>     low_error_factor 0.4
>     gray_threshold 0.0
>     minimum_reuse 0.015
>     brightness 1
>
>     adc_bailout 0.01/2
>   }

Apologies for the spelling mistake. Halton not Halston. A pseudo-randomization,
distributed more evenly.

Post a reply to this message