In the following scene I expect the white sphere to show a hint of red or green
across its surface, thrown up by the nearby objects. Can anyone tell me what
I've misunderstood about diffuse? Is there something that needs to be added to
the sphere's texture?

#version 3.7;
global_settings{ assumed_gamma 1.0 }

#include "colors.inc"
camera {/*ultra_wide_angle*/ angle 75      // front view
                            location  <0.2 , 1.7 ,-3.2>
                            right     x*image_width/image_height
                            look_at   <0.3 , 1.0 , 0.0>}
light_source{<-1500,2500,-2500> color White}
light_source{ <-1000, 800, 3000>
              color White
            }

plane { <0,1,0>, 0
        texture { pigment{ color Green} finish { diffuse 1 }
                }
      }

light_source { <-11,103,0>, White}

cylinder{
        <-1,0,0>,
        <-1,0,5>,
        1
        texture {
                pigment { Red }
                finish  {
                        diffuse 1
                        brilliance .2
                        reflection 0.1
                        }
                }
        }

sphere  {
        <1,1,1.2>,1
        texture {
                pigment { White }
                finish { ambient 0 diffuse 1}

                }
        }

Post a reply to this message

Le 02/03/2014 11:08, FNH nous fit lire :
> In the following scene I expect the white sphere to show a hint of red or green
> across its surface, thrown up by the nearby objects. Can anyone tell me what
> I've misunderstood about diffuse? Is there something that needs to be added to
> the sphere's texture?

Study the scene radiosity/cornell.pov

(from the delivered scenes with povray)

Post a reply to this message

On 02/03/14 10:18, Le_Forgeron wrote:
> Le 02/03/2014 11:08, FNH nous fit lire :
>> In the following scene I expect the white sphere to show a hint of red or green
>> across its surface, thrown up by the nearby objects. Can anyone tell me what
>> I've misunderstood about diffuse? Is there something that needs to be added to
>> the sphere's texture?
> 
> Study the scene radiosity/cornell.pov
> 
> (from the delivered scenes with povray)
> 

As Le Forgeron hinted, it's not additions to texture you need, but
radiosity. Add the following into your global_settings:

radiosity{
    pretrace_start 0.04
    pretrace_end 0.01
    count 200
    recursion_limit 3
    nearest_count 10
    error_bound 0.5
}

John
-- 
Protect the Earth
It was not given to you by your parents
You hold it in trust for your children

Post a reply to this message

> As Le Forgeron hinted, it's not additions to texture you need, but
> radiosity. Add the following into your global_settings:
>
> radiosity{
>     pretrace_start 0.04
>     pretrace_end 0.01
>     count 200
>     recursion_limit 3
>     nearest_count 10
>     error_bound 0.5
> }
>
> John
> --
> Protect the Earth
> It was not given to you by your parents
> You hold it in trust for your children

Thank you! Totally missed that!

Post a reply to this message

On 02/03/14 12:08, FNH wrote:
> 
> Thank you! Totally missed that!
> 
> 

As I've said before to others, you're welcome. We learn by making mistakes.

John
-- 
Protect the Earth
It was not given to you by your parents
You hold it in trust for your children

Post a reply to this message

Le 14-03-02 06:04, Doctor John a écrit :
> On 02/03/14 10:18, Le_Forgeron wrote:
>> Le 02/03/2014 11:08, FNH nous fit lire :
>>> In the following scene I expect the white sphere to show a hint of red or green
>>> across its surface, thrown up by the nearby objects. Can anyone tell me what
>>> I've misunderstood about diffuse? Is there something that needs to be added to
>>> the sphere's texture?
>>
>> Study the scene radiosity/cornell.pov
>>
>> (from the delivered scenes with povray)
>>
>
> As Le Forgeron hinted, it's not additions to texture you need, but
> radiosity. Add the following into your global_settings:
>
> radiosity{
>      pretrace_start 0.04
>      pretrace_end 0.01
>      count 200
>      recursion_limit 3
>      nearest_count 10
>      error_bound 0.5
> }
>
> John
>

That's a rather high quality radiosity setting.

You can get descent results using only radiosity{} to enable radiosity 
using the default parameters.
For a test render, it's often enough.
The radiosity defaults are:
radiosity{
pretrace_start 0.08
pretrace_end 0.04
count 35
nearest_count 5
error_bound 1.8
low_error_factor 0.5
minimum_reuse 0.015
recursion_limit 2
normals off
media off
}



Alain

Post a reply to this message