Hi,

I have 3 different *.pov files to render. I can render all of them successfully
in the way that I want so there is no problem with that. However, rendering them
individually obviously produces 3 different *.png files. I'd like to have a
single output file (doesn't necessarily have to be *png) with the rendered
images stacked on top of each other, perhaps with simple solid bars between
them. Is there a good way to to do this in POVRAY itself, or am I better off
taking the individual images into GIMP to produce the composite figure?

Thanks,
Brad

Post a reply to this message

Am 14.12.2012 17:40, schrieb Brad:
> Hi,
>
> I have 3 different *.pov files to render. I can render all of them successfully
> in the way that I want so there is no problem with that. However, rendering them
> individually obviously produces 3 different *.png files. I'd like to have a
> single output file (doesn't necessarily have to be *png) with the rendered
> images stacked on top of each other, perhaps with simple solid bars between
> them. Is there a good way to to do this in POVRAY itself, or am I better off
> taking the individual images into GIMP to produce the composite figure?

You could use a fourth POV-Ray scene, using an orthographic camera, and 
applying the other image files as textures.

Post a reply to this message

clipka <ano### [at] anonymousorg> wrote:
> You could use a fourth POV-Ray scene, using an orthographic camera, and
> applying the other image files as textures.

This is how I usually do it.  (N.B. This is much easier in POV-Ray 3.7 than in
previous versions, due to 3.7's image map gamma handling.)

However, sometimes I whip up an HTML document to display the images, then take a
screen capture.

Post a reply to this message

clipka <ano### [at] anonymousorg> wrote:
>
> You could use a fourth POV-Ray scene, using an orthographic camera, and
> applying the other image files as textures.

Thanks to both of you for your response. This sounds like it might work. Do you
know of any simple examples online for me to see how this is done exactly?

Thanks,
Brad

Post a reply to this message

On 16/12/2012 1:19 PM, Brad wrote:
> clipka <ano### [at] anonymousorg> wrote:
>>
>> You could use a fourth POV-Ray scene, using an orthographic camera, and
>> applying the other image files as textures.
>
> Thanks to both of you for your response. This sounds like it might work. Do you
> know of any simple examples online for me to see how this is done exactly?
>

There is a scene called Mydesk.pov in the directory 
POV-Ray\v3.7\scenes\advanced
That will show you how it is done. It is not exactly what you want but 
the principle is similar. This scene creates an image of a desk then 
puts that image back into the scene as a photograph. If you run the 
animation a couple of times the the photograph gets recursive with the 
photograph showing an image of the room with the photograph showing an 
image of the image of the image...


-- 
Regards
     Stephen

Post a reply to this message

On 16/12/2012 2:40 PM, Stephen wrote:
>>
>
> There is a scene called Mydesk.pov

Ooops! It is called desk.pov & desk.ini.

The Mydesk was me experimenting. :-)


-- 
Regards
     Stephen

Post a reply to this message

"Brad" <bra### [at] gmailcom> wrote:
> clipka <ano### [at] anonymousorg> wrote:
> >
> > You could use a fourth POV-Ray scene, using an orthographic camera, and
> > applying the other image files as textures.
>
> Thanks to both of you for your response. This sounds like it might work. Do you
> know of any simple examples online for me to see how this is done exactly?

Play with these scene files.  First render brad_source.pov with the given
command line arguments to generate the individual images, then render
brad_montage.pov to compile them.
______________________________________________________________________

//brad_source.pov

//+a +w200 +h150 +kff3 +fn
#include "shapes.inc"
global_settings { assumed_gamma 1 }

camera { location <0.3, 0.3, -7> look_at 0 angle 30 }

light_source { <-1, 1, -1> * 1000, rgb 1 parallel point_at 0 }

sky_sphere
{ pigment
  { gradient y color_map
    { [0 rgb <0.6, 0.7, 0.9>]
      [1 rgb <0.2, 0.3, 0.6>]
    }
  }
}

plane
{ y, -1
  pigment { checker rgb <0, 0.4, 0.1> rgb <1, 0.75, 0> }
}

object
{ #switch (frame_number)
    #case (3) Round_Cone_Union (-y, 1, y, 0.15, 0.15) #break
    #case (2) Round_Cylinder_Union (-y, y, 1, 0.2) #break
    #else sphere { 0, 1 }
  #end
  pigment { rgb <0.61, 0.61, 0.64> }
  finish
  { reflection { 0.9 metallic }
    diffuse 0.06
    ambient rgb 0.01
    brilliance 3
    specular 1000 metallic
    roughness 0.0001
  }
}
______________________________________________________________________

//brad_montage.pov

//+w220 +h490 -a
global_settings { assumed_gamma 1 }

camera
{ orthographic
  location <100, 235, -1>
  right 220 * x
  up 490 * y
}

background { rgb <0.2, 0.02, 0> }

#default
{ finish
  { diffuse 0
    #if (version < 3.7)
      ambient 1
    #else
      ambient 0
      emission 1
    #end
  }
}

box
{ 0, 1
  pigment { image_map { png "brad_source1" } }
  scale <200, 150, 1>
  translate 320 * y
}
box
{ 0, 1
  pigment { image_map { png "brad_source2" } }
  scale <200, 150, 1>
  translate 160 * y
}
box
{ 0, 1
  pigment { image_map { png "brad_source3" } }
  scale <200, 150, 1>
}
______________________________________________________________________

Post a reply to this message

Very cool, this worked for me. Thanks so much for the simple example. I'll play
around with it to see if I can get the final look I'm going for.

Also, Stephen, thanks for the desk example. I'll check that out as well -- it
sounds pretty neat.

Best,
Brad


"Cousin Ricky" <rickysttATyahooDOTcom> wrote:
> "Brad" <bra### [at] gmailcom> wrote:
> > clipka <ano### [at] anonymousorg> wrote:
> > >
> > > You could use a fourth POV-Ray scene, using an orthographic camera, and
> > > applying the other image files as textures.
> >
> > Thanks to both of you for your response. This sounds like it might work. Do you
> > know of any simple examples online for me to see how this is done exactly?
>
> Play with these scene files.  First render brad_source.pov with the given
> command line arguments to generate the individual images, then render
> brad_montage.pov to compile them.
> ______________________________________________________________________
>
> //brad_source.pov
>
> //+a +w200 +h150 +kff3 +fn
> #include "shapes.inc"
> global_settings { assumed_gamma 1 }
>
> camera { location <0.3, 0.3, -7> look_at 0 angle 30 }
>
> light_source { <-1, 1, -1> * 1000, rgb 1 parallel point_at 0 }
>
> sky_sphere
> { pigment
>   { gradient y color_map
>     { [0 rgb <0.6, 0.7, 0.9>]
>       [1 rgb <0.2, 0.3, 0.6>]
>     }
>   }
> }
>
> plane
> { y, -1
>   pigment { checker rgb <0, 0.4, 0.1> rgb <1, 0.75, 0> }
> }
>
> object
> { #switch (frame_number)
>     #case (3) Round_Cone_Union (-y, 1, y, 0.15, 0.15) #break
>     #case (2) Round_Cylinder_Union (-y, y, 1, 0.2) #break
>     #else sphere { 0, 1 }
>   #end
>   pigment { rgb <0.61, 0.61, 0.64> }
>   finish
>   { reflection { 0.9 metallic }
>     diffuse 0.06
>     ambient rgb 0.01
>     brilliance 3
>     specular 1000 metallic
>     roughness 0.0001
>   }
> }
> ______________________________________________________________________
>
> //brad_montage.pov
>
> //+w220 +h490 -a
> global_settings { assumed_gamma 1 }
>
> camera
> { orthographic
>   location <100, 235, -1>
>   right 220 * x
>   up 490 * y
> }
>
> background { rgb <0.2, 0.02, 0> }
>
> #default
> { finish
>   { diffuse 0
>     #if (version < 3.7)
>       ambient 1
>     #else
>       ambient 0
>       emission 1
>     #end
>   }
> }
>
> box
> { 0, 1
>   pigment { image_map { png "brad_source1" } }
>   scale <200, 150, 1>
>   translate 320 * y
> }
> box
> { 0, 1
>   pigment { image_map { png "brad_source2" } }
>   scale <200, 150, 1>
>   translate 160 * y
> }
> box
> { 0, 1
>   pigment { image_map { png "brad_source3" } }
>   scale <200, 150, 1>
> }
> ______________________________________________________________________

Post a reply to this message