I'm trying to recreate this awesome scene:

http://darkaan.deviantart.com/art/Light-Balls-v-2-1680x1050-67946500

Any ideas on how to reproduce the blurred light relections / (phongs?) without
taking years to render would be appreciated.

I've modelled with a light source within each ball, but this is highly
processor-intensive, prob due to the large number of light sources.  Is there
any other way to acheive the effect?

Thanks,

Robin

Post a reply to this message

"robinmckenzie" <nomail@nomail> wrote:
> I'm trying to recreate this awesome scene:
>
> http://darkaan.deviantart.com/art/Light-Balls-v-2-1680x1050-67946500
>
> Any ideas on how to reproduce the blurred light relections / (phongs?) without
> taking years to render would be appreciated.
>
> I've modelled with a light source within each ball, but this is highly
> processor-intensive, prob due to the large number of light sources.  Is there
> any other way to acheive the effect?

From what I see, this is actually not a reflection, but a radiosity effect (or
similar, but radiosity should do the job). So use a texture map to equip your
spheres with those alternating bands of reflecting and white texture; for the
white bands, use a white pigment (what else :)) and set its ambient to 1 and
diffuse to 0. Be sure to set all other textures' ambient to 0 so they don't
emit light. Set the plane's diffuse to something > 0. Make sure you have an
ambient_lighting of 1, insert a radiosity block in your global settings, press
"Run", and and voila - happy rendering!

You won't need any conventional light sources at all.

Post a reply to this message

"robinmckenzie" <nomail@nomail> wrote:
> I'm trying to recreate this awesome scene:
>
> http://darkaan.deviantart.com/art/Light-Balls-v-2-1680x1050-67946500
>
> Any ideas on how to reproduce the blurred light relections / (phongs?) without
> taking years to render would be appreciated.

As already said, it's radiosity.  In the case of this scene, radiosity is not
really the main CPU cruncher -- it calculates just fine and in a few minutes,
even in a modest machine as mine.  It's the reflections and focal blur that
really bring it to a crawl.  I wonder which software did the guy use and how
much time it took to render at that size with that quality... it's certainly
raytraced spheres...

Very nice scene.  It inspired me to try to reproduce it, though not quite there
yet -- I should probably better adjust the aperture and blur_samples as well as
trying perhaps some fresnel reflection and a better sphere distribution scheme.
If anyone is feeling courageous to try to match the scene, here's a start,
though I suggest you turn FOCAL_BLUR off first -- took 13 minutes a subpar
640x480 rendering on a P4 2.66:

http://img116.imageshack.us/img116/5341/blackspheresel2.png


code:


#local GI = on;
#local FOCAL_BLUR = on;
#local REFLECTIONS = on;

union {
plane { y, -1 pigment { rgb <.8,.8,1>/3 } finish { diffuse .56 ambient 0 } }

#local sph =
sphere { 0 1
 texture {
  pigment { rgb <.8,.8,1> }
  finish { diffuse 0 ambient 3 }
 } texture {
  pigment { marble rotate z*90
   color_map { [0 rgb z/2][.7 rgb z/2][.75 rgbt 1][1 rgbt 1]} }
  finish { diffuse .6 ambient 0
   #if (REFLECTIONS) reflection .9 metallic .2 #end
  }
 }
}

//object { sph }
#local much = 17;
#local i = much; #while (i>-much)
object { sph rotate <30*i*i,40*i> translate 3*x*i+15*z*cos(30+i*30) }
#declare i = i-1; #end

 rotate -y*65
 rotate -x*3.5
 //translate z*12-x*2
 translate z*28-x*0
}

#if (!GI)
light_source { -z*5 1 }
#end

global_settings {
 #if (GI)
 radiosity {
  brightness 2
  count 180
  gray_threshold .5
  error_bound .28
  pretrace_end .006
 }
 #end
}

camera { angle 30
#if (FOCAL_BLUR)
 focal_point z*8.5-y*1+x aperture .06 blur_samples 50*5 confidence .98
#end
}

Post a reply to this message

robinmckenzie nous illumina en ce 2008-12-04 16:22 -->
> I'm trying to recreate this awesome scene:
> 
> http://darkaan.deviantart.com/art/Light-Balls-v-2-1680x1050-67946500
> 
> Any ideas on how to reproduce the blurred light relections / (phongs?) without
> taking years to render would be appreciated.
> 
> I've modelled with a light source within each ball, but this is highly
> processor-intensive, prob due to the large number of light sources.  Is there
> any other way to acheive the effect?
> 
> Thanks,
> 
> Robin
> 
> 
When you create a scene that use several objects with blured reflection that can 
reflect each other, you must be carefull.
You don't want to reflect a blured reflection from another blured reflection.
What to do?
Have each objects in double. One with only normal reflection and no_image, the 
other with the blured reflection and no_reflection.

Whenever you directly see an object, you will see the one with the blured 
reflection. Whenever you see the object in a reflection, you'll see the one with 
the normal reflection.

But, the image you linked to, don't use blured reflection. It's a radiosity 
scene. The bright parts glow by themselve using high ambient with a slightly 
bluish pigment. The floor is a plain white plane. There are NO regular light_source.

-- 
Alain
-------------------------------------------------
   My wife's such a bad cook, the dog begs for Alka-Seltzer.
   	Rodney Dangerfield

Post a reply to this message