Hello,

I created a simple scene with sphere inside a room and rendered this with

1) POV-Ray
2) Mental Ray

These are the results:

1) http://www.theoinf.de/pp/test_pov.png
2) http://www.theoinf.de/pp/test_mr.png

I used radiosity with default settings for POV-Ray and photon mapping for Mental
Ray (10000 photons). Light attenuation follows an inverse-square-rule in both
settings (POV-Ray: fade_power 2, Mental Ray: photometric light, 700 cd). All
material is 50% grey and 100% diffuse.

The image generated by POV-Ray looks less realistic than the one made by
Mental-Ray. I was not able to improve realism by tweaking radiosity settings.

In theory, radiosity should work as well as photon mapping in this scene. Is
there a way to get better results with POV-Ray?

My POV-Ray code is below.

-Boris

---------------------------------------------------------------------------

#include "colors.inc"

global_settings {
  radiosity {}
}

camera {
  location <0, 1, -4>
  look_at  <0, 1,  0>
  angle 75
}

light_source {
  <1, 4, 0>
  color 0.5*White
  fade_distance 30
  fade_power 2
}


// Scene

sphere {
  <0, 1, 0>, 1
  texture {pigment {color rgb<0.5, 0.5, 0.5>}}
  finish {diffuse 1 ambient 0}
}

box {
  <-5, 0, -5>, < 5, 5,  5>
  texture {pigment {color rgb<0.5, 0.5, 0.5>}}
  finish {diffuse 1 ambient 0}
  inverse
}

Post a reply to this message

"borix" <nomail@nomail> wrote:
> Is
> there a way to get better results with POV-Ray?

yes, you could learn to use radiosity and its parameters instead of using the
default settings.  Like:

global_settings { ambient_light .01
  radiosity {
    brightness 1.5
    count 80
    error_bound .6
    pretrace_start .02
    pretrace_end .008
  }
}

already gives a far better result, using just 80 samples...

Post a reply to this message

Use rad_def.inc if you're lazy. Gives some more decent parameters to 
base on than the actual 'defaults'.

Post a reply to this message

> Hello,
>
> I created a simple scene with sphere inside a room and rendered this with
>
> 1) POV-Ray
> 2) Mental Ray
>
> These are the results:
>
> 1) http://www.theoinf.de/pp/test_pov.png
> 2) http://www.theoinf.de/pp/test_mr.png
>
> I used radiosity with default settings for POV-Ray and photon mapping for 
> Mental
> Ray (10000 photons). Light attenuation follows an inverse-square-rule in 
> both
> settings (POV-Ray: fade_power 2, Mental Ray: photometric light, 700 cd). 
> All
> material is 50% grey and 100% diffuse.
>
> The image generated by POV-Ray looks less realistic than the one made by
> Mental-Ray. I was not able to improve realism by tweaking radiosity 
> settings.
>
> In theory, radiosity should work as well as photon mapping in this scene. 
> Is
> there a way to get better results with POV-Ray?

1) The default settings for radiosity in POV are intentionally low-quality,
the reasoning for this is so that they can be used to quickly preview
object placement in test renders.

2) Diffuse values in POV control the contribution of simulated
diffuse light in the normal lighting model. In situations where
standard light sources are used in conjuction with radiosity it doesn't
make sense to set diffuse to 100%, the contribution from the light
source is not 0%, the image will saturate.

3) It is common to use high ambient objects for light sources instead
of normal light sources in POV radiosity scenes. Also the standard
light sources can be used for soft shadows in POV, with or without
radiosity.

4) This is a common question, essentially comparing some typical
feature, with typical settings in some other renderer to a similar
scene in POV with atypical "noob" settings.  POV has a very good
manual, try section 2.3.7 if you really are interested in radiosity.

http://s201.photobucket.com/albums/aa280/Zakardis/?action=view&current=pov_rad_test.png

#include "colors.inc"

global_settings {
   assumed_gamma 2.2
   radiosity {
      brightness 3
      count 100
      error_bound 0.15
      gray_threshold 0.0
      low_error_factor 0.2
      minimum_reuse 0.015
      nearest_count 10
      recursion_limit 5
      adc_bailout 0.01
      max_sample 0.5
      media off
      normal off
      always_sample 1
      pretrace_start 0.08
      pretrace_end 0.01
   }
}

camera {
   location <0, 1, -4>
   look_at  <0, 1,  0>
   angle 75
}

light_source {
   <1, 4, 0>
   color 0.5*White
   fade_distance 30
   fade_power 2
   area_light <0.5, 0, 0>, <0, 0, 0.5>, 5, 5
   adaptive 1
   jitter
}

// Scene
sphere {
   <0, 1, 0>, 1
   texture {
      pigment {
         color rgb <0.5, 0.5, 0.5>
      }
      finish {
         ambient 0
         diffuse 0.6 // default diffuse setting
      }
   }
}

box {
   <-5, 0, -5>, < 5, 5,  5>
   texture {
      pigment {
         color rgb<0.5, 0.5, 0.5>
      }
      finish {
         ambient 0
         diffuse 0.6 // default diffuse setting
      }
   }
   inverse
}

Post a reply to this message

Here's a great radiosity tutorial...

http://www.imagico.de/pov/radiosity01.html

Post a reply to this message

Hello,

thank you for your replies. I've done some more experiments with different
parameter settings and obtained much better results. brightness and *count
contribute to the most visible differences. Still, I feel that ceiling and
sphere are too dark compared to the other walls (they're all 50% grey). Does
this have to do with the lamp? How do you simulate a 700 cd point light in a 5
m x 5 m room?


Merry Xmas everyone!

Post a reply to this message

borix napsal(a):
> Hello,
> 
> thank you for your replies. I've done some more experiments with different
> parameter settings and obtained much better results. brightness and *count
> contribute to the most visible differences. Still, I feel that ceiling and
> sphere are too dark compared to the other walls (they're all 50% grey). Does
> this have to do with the lamp? How do you simulate a 700 cd point light in a 5
> m x 5 m room?
> 
> 
> Merry Xmas everyone!
> 
> 
do you use assumed_gamma 1?

Post a reply to this message

Jan Dvorak <jan### [at] centrumcz> wrote:

> do you use assumed_gamma 1?

no, I haven't changed any gamma-settings. I work with a laptop LCD.

Post a reply to this message

borix napsal(a):
> Jan Dvorak <jan### [at] centrumcz> wrote:
> 
>> do you use assumed_gamma 1?
> 
> no, I haven't changed any gamma-settings. I work with a laptop LCD.
> 
> 
> 
http://www.povray.org/documentation/view/3.6.1/260/

Post a reply to this message

"borix" <nomail@nomail> wrote:
> Still, I feel that ceiling and
> sphere are too dark compared to the other walls (they're all 50% grey). Does
> this have to do with the lamp? How do you simulate a 700 cd point light in a 5
> m x 5 m room?

I felt your original fade_distance of 30 for the light_source unnaceptable.  I
changed it to about 4 and increased the radiosity brightness to about 3 and the
result came out a lot smoother.  VanSickle's tip on diffuse values is also worth
it.

I should also point out that the Mental Ray test render came out with a lot of
blotchiness in the walls...

Post a reply to this message