So, here's the situation: I'm working in POV-Ray, and I get an idea like
this: "Hey, maybe I could light up this whole column of objects and have
them all glow due to a light-emitting object at the bottom!"(I'm using
radiosity). Is there any way to use an interior to get an effect similar to
what happens when you feed light into a fiber optic line, where the entire
wire seems to glow with a quiet red light? I don't want to fake it by using
ambience, I want this to be an authentic glow. Has anyone achieved this, or
knows how?

Post a reply to this message

"FractalMBrown" <fractalmbrown_AT_QX_DOT_NET> wrote in message 
news:web.42ec3a5f65a378c192a4d1390@news.povray.org...
> So, here's the situation: I'm working in POV-Ray, and I get an idea like
> this: "Hey, maybe I could light up this whole column of objects and have
> them all glow due to a light-emitting object at the bottom!"(I'm using
> radiosity). Is there any way to use an interior to get an effect similar 
> to
> what happens when you feed light into a fiber optic line, where the entire
> wire seems to glow with a quiet red light? I don't want to fake it by 
> using
> ambience, I want this to be an authentic glow. Has anyone achieved this, 
> or
> knows how?

Hmmmm, thinking media-filled objects could be the answer. Radiosity will 
affect that when you use 'media on' in the radiosity statement. That plus 
photons and reflective/refractive objects might work all together if you use 
actual light source(s) in conjunction with radiosity. Not real sure it would 
do exactly as you want though.

I can't think of an example of such a thing. I did a fiber-optic cable long 
ago but it was only to get light out the other end (was not entirely 
successful).

Bob Hughes

Post a reply to this message

> Hmmmm, thinking media-filled objects could be the answer. Radiosity will
> affect that when you use 'media on' in the radiosity statement. That plus
> photons and reflective/refractive objects might work all together if you use
> actual light source(s) in conjunction with radiosity. Not real sure it would
> do exactly as you want though.
>
> I can't think of an example of such a thing. I did a fiber-optic cable long
> ago but it was only to get light out the other end (was not entirely
> successful).
>
> Bob Hughes

Thanks, I'll have to learn how to use media (I'm still learning all the
features), but I'll keep your advice in mind.

Post a reply to this message

When I said radiosity affects media, well, that was a misnomer. I was 
checking about this just tonight as I finally thought on this some more and 
tried a test scene to be sure it could work okay.

Seems that media affects radiosity instead of the other way around. For 
example, a very diffuse white block below a clear tube filled with red media 
(emission <1,0,0>) will glow red, but the media won't be brightened by the 
block FAIK. Without light sources there's no way to scatter the light into 
the media so the block will remain dark unless ambient and even so the media 
remains unaffected..

Sorry that I led you astray. So for doing that I'll try and make up for it 
by giving an example of something like what you asked about, even if it 
might not be exactly the same thing I thought you might have been asking. 
The following script is a quick hack, so please keep that in mind. Photons 
optional.

Bob

/* tube glowing red from light below it */

global_settings {
 assumed_gamma 1.0
 ambient_light 0//1
 radiosity {
  count 123
  brightness 1
  media on
 }
 photons {
  count 5000 // increase...?
  media 100, 2
 }
}

sphere {
 0,100
 pigment {color rgb 0.5}
 inverse
}

camera {
 location <1,2,-6>
 angle 50
 look_at -y
}

box {
 -1,1
 pigment {
  color rgb 1
 }
 finish {
  ambient 1
  diffuse 1
 }
 scale <2,0.5,1>
 translate -2.01*y
 photons {
  target 0
  collect off
 }
}

light_source { // between cylinder and box
 -1.125*y,1
 photons {
  refraction on
  reflection off
 }
}

cylinder {
 -y,+y,0.5
 pigment {
  color rgbt 1
 }
 interior {
  ior 1.48
  fade_distance 0.25
  media {
   samples 15
   emission <1,0,0>//10 // divide by 10 if using photons
   absorption <0.1,0.1,0.1>
   scattering {
    2,<0.5,0,0>//10 // divide by 10 if using photons
   }
   density {
    function {abs(y)}
    density_map {
     [0 rgb 0] // use rgb 1 for even distribution
     [1 rgb 1]
    }
    scale 2
    translate y
   }
  }
 }
 hollow
 photons {
  target 0 // 1 for photons effect
  refraction on
  reflection off
  collect off
 }
}

Post a reply to this message

"Bob Hughes" <omniverse@charter%net> wrote:
> When I said radiosity affects media, well, that was a misnomer. I was
> checking about this just tonight as I finally thought on this some more and
> tried a test scene to be sure it could work okay.
>
> Seems that media affects radiosity instead of the other way around. For
> example, a very diffuse white block below a clear tube filled with red media
> (emission <1,0,0>) will glow red, but the media won't be brightened by the
> block FAIK. Without light sources there's no way to scatter the light into
> the media so the block will remain dark unless ambient and even so the media
> remains unaffected..
>
> Sorry that I led you astray. So for doing that I'll try and make up for it
> by giving an example of something like what you asked about, even if it
> might not be exactly the same thing I thought you might have been asking.
> The following script is a quick hack, so please keep that in mind. Photons
> optional.
>
> Bob
>
> /* tube glowing red from light below it */
   (Clipped)

Thanks, I'll try it out as soon as I can! (I can't try it right now
considering how I'm doing a 12000x8000 render and it's going to take about
30 hours at this rate)

Post a reply to this message