Hello,

I have a problem with an isosurface: one part of it does not show up.

My software:

Persistence of Vision(tm) Ray Tracer Version 3.6.1 (g++ 3.4.1 @
 i686-pc-linux-gnu)

My code:
=====
isosurface {
  function{y-x*z}
  max_gradient 6
  contained_by {sphere {0 6}}
  clipped_by {box {<-2,-1,-4> <2,2,4> rotate -45*y}}
  pigment {color rgbt .8}
}
//box {<-2,-1,-4> <2,2,4> rotate -45*y pigment {color rgbt .8}}
light_source {<2,5,1> color rgb 1}
camera {
  orthographic
  location <2,2,-8> look_at <0,.3,0>
  up 10*y right 10*4/3*x
}
background {<1,1,1>}
=====

  When I take off the comment // before the box, the isosurface shows up
correctly. With the comment, a part of the isosurface is missing.

  Thanks for your help,

Post a reply to this message

>Hello,
>
>I have a problem with an isosurface: one part of it does not show up.

"clipped_by" Is a CSG operation and requires a suitable max_trace
setting (or "all_intersections") just as you would if you had used
"difference" or "intersection".

isosurface {
  function{y-x*z}
  max_gradient 6
  max_trace 2                   // Added this line
  contained_by {sphere {0 6}}
  clipped_by {box {<-2,-1,-4> <2,2,4> rotate -45*y}}
  pigment {color rgbt .8}
}
light_source {<2,5,1> color rgb 1}
camera {
  orthographic
  location <2,2,-8> look_at <0,.3,0>
  up 10*y right 10*4/3*x
}
background {<1,1,1>}

-- 
Mike Williams
Gentleman of Leisure

Post a reply to this message