|
 |
ALPHA1 <nomail@nomail> wrote:
> been trying to getting onions and radials on a vase, but haven't had any
> luck.
Well, you have to go to a grocery shop and...
But seriously, perhaps you should be more specific about what it is
that you want to do.
Perhaps what you want to do is possible with 'average' or with
user-defined pattern functions?
--
#macro N(D)#if(D>99)cylinder{M()#local D=div(D,104);M().5,2pigment{rgb M()}}
N(D)#end#end#macro M()<mod(D,13)-6mod(div(D,13)8)-3,10>#end blob{
N(11117333955)N(4254934330)N(3900569407)N(7382340)N(3358)N(970)}// - Warp -
Post a reply to this message
|
|
|
|
ALPHA1 wrote:
> been trying to getting onions and radials on a vase, but haven't had any
> luck.
>
AVERAGED:
cylinder { 0*y, 1.1*y .4
pigment {
average
pigment_map {
[1, onion scale .1
pigment_map { [0 rgb 0]
[.5 rgb 1]
[1 rgb 0]
}
]
[1, radial frequency 9
pigment_map { [0 rgb 0]
[.5 rgb 1]
[1 rgb 0]
}
]
}
}
}
NESTED:
cylinder { 0*y, 1.1*y .4
pigment {
onion scale .1
pigment_map {
[0 rgb 0]
[.5 radial frequency 9
pigment_map { [0 rgb 0]
[.5 rgb 1]
[1 rgb 0]
}
]
[1 rgb 0]
}
}
}
COMBINED AS FUNCTIONS (one variant of many):
#declare pO =
function { pigment { onion scale .1
pigment_map { [0 rgb 0]
[.5 rgb 1]
[1 rgb 0]
}
}
}
#declare pR =
function { pigment { radial frequency 9
pigment_map { [0 rgb 0]
[.5 rgb 1]
[1 rgb 0]
}
}
}
cylinder { 0*y, 1.1*y .4
pigment {
function { pR(x,y,z).grey + pO(x,y,z).grey }
}
}
Post a reply to this message
|
|
