I have a very simple isosurface described by the following POV code:


isosurface {
        function {y - sin(x)}
 threshold 0

 open

 contained_by {sphere {<0, 0, 0>, 4}}

 texture {
  pigment {color rgb < 1, 0.9, 0.65>}
  finish {
   brilliance 1.6
   specular 0.3
  }
}

It is essentially a round disk with sinusoidal waves in it.

However, when viewed from different angles the surface, instead of being s
smooth surface, it often has many black pixels and curved black lines
rendered across the surface.

I have tried rendering with AA on (which reduces their appearance a little)
and by setting much higher accuracies for the isosurface (which also
reduces the effect, but does not remove it).

Can anyone tell me if this is a known issue with isosurfaces? It seems to me
this particular case is a very simple surface and should not present the
renderer with significant problems.

I am using the POV 3.5 final release binaries.

Cheers,

Raymond.

Post a reply to this message

Please post a *complete* (but minimal) scene which *shows the problem*.
It's a lot of trouble if we have to find the camera and light locations
for ourselves.

  Just one question: Does POV-Ray give you any warning when you see the
artifacts?

-- 
plane{-x+y,-1pigment{bozo color_map{[0rgb x][1rgb x+y]}turbulence 1}}
sphere{0,2pigment{rgbt 1}interior{media{emission 1density{spherical
density_map{[0rgb 0][.5rgb<1,.5>][1rgb 1]}turbulence.9}}}scale
<1,1,3>hollow}text{ttf"timrom""Warp".1,0translate<-1,-.1,2>}//  - Warp -

Post a reply to this message

Warp wrote:
>  Please post a *complete* (but minimal) scene which *shows the problem*.
>It's a lot of trouble if we have to find the camera and light locations
>for ourselves.
>
>  Just one question: Does POV-Ray give you any warning when you see the
>artifacts?
>
>plane{-x+y,-1pigment{bozo color_map{[0rgb x][1rgb x+y]}turbulence 1}}
>sphere{0,2pigment{rgbt 1}interior{media{emission 1density{spherical
>density_map{[0rgb 0][.5rgb<1,.5>][1rgb 1]}turbulence.9}}}scale
><1,1,3>hollow}text{ttf"timrom""Warp".1,0translate<-1,-.1,2>}//  - Warp -
>

Sorry! Here's the complete code for an animation that shows the effect quite
graphically, but it's small :-)

// Persistence Of Vision raytracer version 3.5 sample file.

#include "stdinc.inc"
#include "arrays.inc"
#version 3.5;

global_settings {
 assumed_gamma 1
}

sky_sphere {
 pigment {gradient y
  color_map {
   [0 color Blue*0.6]
   [1 color White]
  }
 }
}


//----------------------------------------
#declare CamLoc = < 0, 5, -10>;
camera {
 location CamLoc
 angle 45
 look_at <0, 0, 0>
}

light_source {<-20, 30, -30>*3 color White*1.5}
light_source {CamLoc color rgb 0.3}

#declare Ground =
isosurface {
        function {y - sin(x + clock * 2 * 3.14159265) }
 threshold 0

 open
 all_intersections

 contained_by {sphere {<0, 0, 0>, 4}}

        accuracy 0.000001

 texture {
  pigment {color rgb < 1, 0.9, 0.65>}
  normal {granite 0.2 scale 0.02}
  finish {
   brilliance 1.6
   specular 0.3
  }
 }
}
object {Ground rotate (clock * 360)*y}


And.. ack! Yes POV does throw a warning about the iso-surface, it was buried
in all the other stuff flying past so I didn't notice it:

Warning is:

Warning: The maximum gradient found was 1.163, but max_gradient of the
isosurface was set to 1.100. The isosurface may contain holes!
Adjust max_gradient to get a proper rendering of the isosurface.


I have increased max_gradient appropriately and now it works fine! Might be
nice if POVRay put such warnings a little more 'in your face' :-)

Thanks for the hint!

Cheers,

Raymond.

Post a reply to this message

"Raymond" <ray### [at] trimbleconz> wrote in message
news:web.3e27502953e3fea0802871ed0@news.povray.org...

>
> I have increased max_gradient appropriately and now it works fine! Might be
> nice if POVRay put such warnings a little more 'in your face' :-)
>

Don't worry - you'll get used to it, and in the meantime that's what we're here
for....

Post a reply to this message