I'm just starting to experiment with isosurfaces.

I have played around with some CSG shapes and partially transparent
isosurfaces. Despite the documentation's warning that max_trace needs to be
set for use with CSG, they seem to work just fine with max_trace set at the
default of 1.

Can someone please post an example where it is necessary to increase the
max_trace of an isosurface?

Thanks

Post a reply to this message

"Mike" <nomail@nomail> wrote in message
news:web.3d6180f36bb2fa2e8b0b6f760@news.povray.org...

<snip>

Here ya go....

#include "colors.inc"
light_source {
  0*x
  color rgb <1,1,1>
  translate <-20, 40, -20>
}

camera {
  location  <1, 1, -4.0>
  look_at   <0.0, 0.0,  0.0>
}

#declare fn_X = function(x,y,z) { x*x + y*y +z*z - 1 }
#declare iso_sphere =
isosurface {
  function { fn_X(x, y, z) }
  contained_by { box { -1.2, 1.2 } }
  accuracy 0.001
  max_gradient 4

  // uncomment either of the following 2 lines to repair the CSG
  //max_trace 2
  //all_intersections
}

difference{
  object{iso_sphere}
  object{iso_sphere translate<0.75,0.75,-0.75>}
  pigment{Green}
}

Post a reply to this message

Thanks. I understand now. :)

Post a reply to this message