I am trying to make a bend in a pipe using a torus then cutting off
three quarters with two boxes.  But when I try to rotate the object I
get what looks like a very thin disk.  It only shows up with a rotate
and not a translate.

Where is it coming from and how do I get rid of it?

#include "colors.inc"

global_settings {
  assumed_gamma 1.0
}

camera {
  location  <0, 20, -30>
  //direction 1.5*z
  right     x*image_width/image_height
  look_at   <0, 0,  0>
}

light_source {
  <0, 0, 0>           
  color rgb <1, 1, 1>
  translate <0, 0, -30>
  shadowless
}

background { rgb 0.75}

#declare torusMajorRadius = 7;
#declare pipeRadius = 1;

#declare bend =
  difference {
    torus { torusMajorRadius, pipeRadius }
    #declare len = torusMajorRadius + pipeRadius + 1;
    box { <0, -2*pipeRadius, -1*len>, <-len, 2*pipeRadius, len> }
    box { <0, -2*pipeRadius, 0>, <len, 2*pipeRadius, len> }
    translate <0,0,torusMajorRadius>
  }

object {
	bend
	pigment { color Red }
	rotate <0,90,0>
}

DeLeon Thomas

Post a reply to this message

DeLeon Thomas <gad### [at] deleonthomascom> wrote:
> I am trying to make a bend in a pipe using a torus then cutting off
> three quarters with two boxes.  But when I try to rotate the object I
> get what looks like a very thin disk.  It only shows up with a rotate
> and not a translate.
>
> Where is it coming from and how do I get rid of it?

Coincident surface problem between your two subtracting boxes (they are
coincident on the x=0 plane)

try:

#declare bend =
  difference {
    torus { torusMajorRadius, pipeRadius }
    #declare len = torusMajorRadius + pipeRadius + 1;
    box { <0, -2*pipeRadius, -1*len>, <-len, 2*pipeRadius, len> }
    box { <-1, -2*pipeRadius, 0>, <len, 2*pipeRadius, len> }
    translate <0,0,torusMajorRadius>
  }


-tgq

Post a reply to this message

Thank you Trevor!  That fixed everything.



On Mon, 17 Apr 2006 15:34:30 EDT, "Trevor G Quayle"
<Tin### [at] hotmailcom> wrote:

>DeLeon Thomas <gad### [at] deleonthomascom> wrote:
>> I am trying to make a bend in a pipe using a torus then cutting off
>> three quarters with two boxes.  But when I try to rotate the object I
>> get what looks like a very thin disk.  It only shows up with a rotate
>> and not a translate.
>>
>> Where is it coming from and how do I get rid of it?
>
>Coincident surface problem between your two subtracting boxes (they are
>coincident on the x=0 plane)
>
>try:
>
>#declare bend =
>  difference {
>    torus { torusMajorRadius, pipeRadius }
>    #declare len = torusMajorRadius + pipeRadius + 1;
>    box { <0, -2*pipeRadius, -1*len>, <-len, 2*pipeRadius, len> }
>    box { <-1, -2*pipeRadius, 0>, <len, 2*pipeRadius, len> }
>    translate <0,0,torusMajorRadius>
>  }
>
>
>-tgq
>
>

Post a reply to this message