Hi all

Will photons be shot this? 

If so, what possible reasons can there be for no photons mentioned in
statistics on a scene with a mesh2 photon target, photons defined in the
global settings, and a light source that illuminates the target object that
is defined as being a photon source?

I'm pulling my hair out - I've tried everything - more photons, lower
spacings, lower spacings on the target object, but absolutely zero photons
get generated. My only conclusion is that mesh2 objects cannot participate
in photons? I've searched the docs but I can't find any mention of this,
nor can I figure out why Povray refuses to generate a photon map...

Can anybody help?
-- 
Stefan

Post a reply to this message

Stefan Viljoen nous apporta ses lumieres en ce 05-01-2007 03:26:
> Hi all

> Will photons be shot this? 

> If so, what possible reasons can there be for no photons mentioned in
> statistics on a scene with a mesh2 photon target, photons defined in the
> global settings, and a light source that illuminates the target object that
> is defined as being a photon source?

> I'm pulling my hair out - I've tried everything - more photons, lower
> spacings, lower spacings on the target object, but absolutely zero photons
> get generated. My only conclusion is that mesh2 objects cannot participate
> in photons? I've searched the docs but I can't find any mention of this,
> nor can I figure out why Povray refuses to generate a photon map...

> Can anybody help?
Is the mesh2 object reflective?
Is it transparent, at least partialy?
It is deffined as target, is it also deffined with reflection on? refraction on?

-- 
Alain
-------------------------------------------------
Monday is an awful way to spend 1/7 of your week.

Post a reply to this message

Alain wrote:

>> Can anybody help?
> Is the mesh2 object reflective?
> Is it transparent, at least partialy?
> It is deffined as target, is it also deffined with reflection on?
> refraction on?
 
I've tried all the above - making it reflective, transparent, filtering, IOR
and no IOR - no results. Zero photons are generated no matter what I try...
-- 
Stefan

Post a reply to this message

> Can anybody help?

Without seeing your code it's dificult, because it should
work fine. Here is a sample that works fine with mesh2.

#version 3.6;

#declare Photons=on;

global_settings {
  assumed_gamma 1.0
  max_trace_level 20
  #if (Photons)
    photons { // global photon block
      spacing 0.02
    }
  #end
}
// ----------------------------------------
camera {
  right x*image_width/image_height
  location  <0,1.6,-5>
  look_at   <0,0.75,0>
}
light_source {
  <500,500,150>
  color rgb 1.3
  photons { // photon block for a light
    refraction on
    reflection on
  }
}
sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}
// ----------------------------------------
#declare M_Glass=    // Glass material
material {
  texture {
    pigment {rgbt 1}
    finish {
      ambient 0.0
      diffuse 0.05
      specular 0.6
      roughness 0.005
      reflection {
        0.1, 1.0
        fresnel on
      }
      conserve_energy
    }
  }
  interior {
    ior 1.5
    fade_power 1001
    fade_distance 0.9
    fade_color <0.5,0.8,0.6>
  }
};
#declare tetra = mesh2{
vertex_vectors{
4,
<0,2,0>,
<1.632994,-0.666666,-0.94281>,
<0,-0.66666,1.885618>,
<-1.632994,-0.666666,-0.94281>
}
normal_vectors{
4,
<0,1,-9.392993E-7>,
<0.8164975,-0.3333328,-0.4714033>,
<0,-0.3333322,0.9428094>,
<-0.8164975,-0.3333328,-0.4714033>
}
face_indices{
4,
<0,1,2>,
<0,3,1>,
<2,3,0>,
<1,3,2>
}
normal_indices{
4,
<0,1,2>,
<0,3,1>,
<2,3,0>,
<1,3,2>
}
};
// ----------------------------------------
plane {
  y, 0
  texture {
    pigment { color rgb <1.0, 0.8, 0.6> }
  }
}
object {
   tetra
   rotate <0,180,0>
   translate <1,1,0>
   material { M_Glass }
   photons {  // photon block for an object
    target 1.0
    refraction on
    reflection on
  }
}

Post a reply to this message

Tim Attwood wrote:

>> Can anybody help?
> 
> Without seeing your code it's dificult, because it should
> work fine. Here is a sample that works fine with mesh2.

Hi Tim

Thanks for replying - I checked the code you provided and I cannot see the
difference between yours and mine:

global_settings {
  adc_bailout 0.003922
  ambient_light <1.0,1.0,1.0>
  assumed_gamma 1.9
  hf_gray_16 off
  irid_wavelength <0.247059,0.176471,0.137255>
  max_intersections 64
  max_trace_level 10
  number_of_waves 10
  noise_generator 2
  charset ascii
  photons
  {
        count 20000
        jitter .4
        radius ,1.5
  }
}

.
.
.
#declare Light001 = light_source {
  <0.0, 0.0, 0.0>
  color rgb <1.000, 1.000, 1.000>*1.4500
  photons {
  }
  translate  <0.984692, -14.212549, 19.073553>
  
  photons
  {
        refraction on
        reflection on
  }
}
.
.
.
#declare myobject=mesh2{
vertex_vectors{
144,
<-5.510035,-2E-6,14.84191>,
<-5.986242,-2E-6,14.94362>,
<-6.483728,-2E-6,14.82747>,
.
.
.
}

object
{
 myobject
  
 material
   {   

      texture

      {      

         pigment

         {

            color rgbft <0.27451, 0.741176, 0.156863, 0.45, 0.75>

         }      

         finish

         {

            ambient 0.2

            specular 0.4

            roughness 0.01

            conserve_energy

            reflection

            {

               0.15 , 0.25

               fresnel  off

               falloff  1.0

               exponent 1.0

               metallic 0.0

            }

         }

      }   

      interior

      {

         ior 1.35

         caustics 1.25

         dispersion 1.25

         dispersion_samples  10

      }

   }            
        
 
 photons
 {
        target
        refraction on
        reflection on
        collect off
 } 
}
.
.
.

The above gives me 0 photons emitted - I cannot spot a functional difference
with your code? Except that you specify a photon density and I used a
count - I tried using density as well (just like you did) with no results -
0 photons are still emitted...

Thanks for the reply!
-- 
Stefan

Post a reply to this message

Stefan Viljoen nous apporta ses lumieres en ce 07-01-2007 02:13:
> Tim Attwood wrote:

>>> Can anybody help?
>> Without seeing your code it's dificult, because it should
>> work fine. Here is a sample that works fine with mesh2.

> Hi Tim

> Thanks for replying - I checked the code you provided and I cannot see the
> difference between yours and mine:
> .
> .
> .
> #declare Light001 = light_source {
>   <0.0, 0.0, 0.0>
>   color rgb <1.000, 1.000, 1.000>*1.4500
>   photons {
>   }
>   translate  <0.984692, -14.212549, 19.073553>

>   photons
>   {
>         refraction on
>         reflection on
>   }
> }
> .

>       interior

>       {

>          ior 1.35

>          caustics 1.25

>          dispersion 1.25

>          dispersion_samples  10


> The above gives me 0 photons emitted - I cannot spot a functional difference
> with your code? Except that you specify a photon density and I used a
> count - I tried using density as well (just like you did) with no results -
> 0 photons are still emitted...

> Thanks for the reply!
when you use photons, you don't use caustics. caustics is a fast simulation that 
don't take the distance into consideration AND don't show outside the shadowed area.
Also, you don't need the empty photons{} block in your light_source. Maybe it's 
what's turning your photons OFF... It's all ON by default. You need it if you 
DON'T want that light_source to emit photons: photons{refraction off reflection off}

-- 
Alain
-------------------------------------------------
Fundamentalism: If shit happens to a televangelist, it's okay.

Post a reply to this message

> when you use photons, you don't use caustics. caustics is a fast
> simulation that don't take the distance into consideration AND don't show
> outside the shadowed area. Also, you don't need the empty photons{} block
> in your light_source. Maybe it's what's turning your photons OFF... It's
> all ON by default. You need it if you DON'T want that light_source to emit
> photons: photons{refraction off reflection off}
> 

Ok I'll give that a try. Thanks for the hint!

-- 
Stefan

Post a reply to this message

Stefan Viljoen wrote:

> 
>> when you use photons, you don't use caustics. caustics is a fast
>> simulation that don't take the distance into consideration AND don't show
>> outside the shadowed area. Also, you don't need the empty photons{} block
>> in your light_source. Maybe it's what's turning your photons OFF... It's
>> all ON by default. You need it if you DON'T want that light_source to
>> emit photons: photons{refraction off reflection off}
>> 
> 
> Ok I'll give that a try. Thanks for the hint!

Yargh... ok that wasn't it. I just re-exported everything from Moray with
some of the moray photon stuff turned on and I started getting photons.
Guess it's one of -those- days for me... 

-- 
Stefan

Post a reply to this message

> Yargh... ok that wasn't it. I just re-exported everything from Moray with
> some of the moray photon stuff turned on and I started getting photons.
> Guess it's one of -those- days for me...

Oh, good it's working! =)
I bet Moray was re-doing your settings in an include file.

Post a reply to this message

Tim Attwood wrote:

>> Yargh... ok that wasn't it. I just re-exported everything from Moray with
>> some of the moray photon stuff turned on and I started getting photons.
>> Guess it's one of -those- days for me...
> 
> Oh, good it's working! =)
> I bet Moray was re-doing your settings in an include file.

I thought so too and exported the files, then edited them in the Pov editor.
My bad...

-- 
Stefan

Post a reply to this message