 |
|
|
|
|
|
| |
| |
|
|
From: ninjafoo Ng
Subject: Render Panoramic photo for use in a sky box?
Date: 20 Sep 2006 07:43:47
Message: <45112973@news.povray.org>
|
|
|
| |
| |
|
|
I have found a few panoramic photos on the web
http://www.philohome.com/panogallery/holidays.htm
How could I use POV to render 6 square tiles that I could then use to map
this image onto the insides of a cube and not loose the effect -
essentially I want to end up with a skybox
Rick
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Wasn't it ninjafoo Ng who wrote:
>I have found a few panoramic photos on the web
>
>http://www.philohome.com/panogallery/holidays.htm
>
>How could I use POV to render 6 square tiles that I could then use to map
>this image onto the insides of a cube and not loose the effect -
>essentially I want to end up with a skybox
Since those photos already are cylindrical, it makes more sense to use a
cylindrical sky rather than a box:
cylinder {-y,y,1
pigment {
image_map {
jpeg "mariegalante.jpg"
interpolate 2
map_type 2
}
translate -y/2
scale <1,pi,1>
}
finish {ambient 1}
scale 1000
}
The "map_type 2" makes the image_map cylindrical
The "translate -y/2" makes the image run from -y/2 to +y/2 instead of
from 0 to y.
The scale <1,pi,1> scales the image so that the height matches the
width.
The "finish {ambient 1}" prevents shadows being cast onto the sky
backdrop.
--
Mike Williams
Gentleman of Leisure
Post a reply to this message
|
|
| |
| |
|
|
From: ninjafoo Ng
Subject: Re: Render Panoramic photo for use in a sky box?
Date: 20 Sep 2006 08:54:47
Message: <45113a17@news.povray.org>
|
|
|
| |
| |
|
|
Mike Williams wrote:
> Wasn't it ninjafoo Ng who wrote:
>>I have found a few panoramic photos on the web
>>
>>http://www.philohome.com/panogallery/holidays.htm
>>
>>How could I use POV to render 6 square tiles that I could then use to map
>>this image onto the insides of a cube and not loose the effect -
>>essentially I want to end up with a skybox
>
> Since those photos already are cylindrical, it makes more sense to use a
> cylindrical sky rather than a box:
The final images are not for use in povray, will be used to texture the
inside of a cube in an opengl app
Rick
Post a reply to this message
|
|
| |
| |
|
|
From: Jaime Vives Piqueres
Subject: Re: Render Panoramic photo for use in a sky box?
Date: 20 Sep 2006 09:22:43
Message: <451140a3@news.povray.org>
|
|
|
| |
| |
|
|
ninjafoo Ng wrote:
> The final images are not for use in povray, will be used to texture the
> inside of a cube in an opengl app
Look at Paul Bourke site: I seem to remember it had an include file
for this...
http://local.wasp.uwa.edu.au/~pbourke/projection/
--
Jaime
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
> How could I use POV to render 6 square tiles that I could then use to map
> this image onto the insides of a cube and not loose the effect -
> essentially I want to end up with a skybox
Here's what I use for that:
#declare camloc = <0,0,0>;
camera {
location camloc
right x
up y
direction z
angle 90
#if (frame_number = 0)
look_at camloc + x
#else #if (frame_number = 1)
look_at camloc + -x
#else #if (frame_number = 2)
look_at camloc + y
#else #if (frame_number = 3)
look_at camloc + -y
#else #if (frame_number = 4)
look_at camloc + z
#else #if (frame_number = 5)
look_at camloc + -z
#end #end #end #end #end #end
}
With command line arguments +kfi0 +kff5 .
- Slime
[ http://www.slimeland.com/ ]
Post a reply to this message
|
|
| |
| |
|
|
From: Marc
Subject: Re: Render Panoramic photo for use in a sky box?
Date: 21 Sep 2006 02:04:52
Message: <45122b84@news.povray.org>
|
|
|
| |
| |
|
|
451222ba$1@news.povray.org...
why not?
#switch(frame_number)
#case (0)
look_at camloc + x
#case(1)
look_at camloc + -x
#case(2)
look_at camloc + y
#case(3)
look_at camloc + -y
#case(4)
look_at camloc + z
#case(5)
look_at camloc + -z
#end
Marc
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
> why not?
No reason. Never got in the habit of using #switches in povray.
- Slime
[ http://www.slimeland.com/ ]
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
