|
 |
I created a scene with some glass like superellipsoids. The scene has
radiosity and a high max_trace_level. What I am finding is that it looks
very unrealistic with unsmooth transitions in the reflections in the glass
columns. Even with anti-aliasing on, the transitions aren't smooth at all
and it looks very computer generated and not very real. Can anyone help me
with ideas on how to make this scene look better and more realistic?
Thanks
-------
glasscolumns.pov scene text follows.
-------
#include "colors.inc"
#include "textures.inc"
#include "shapes.inc"
#include "metals.inc"
#include "glass.inc"
#include "woods.inc"
global_settings {
max_trace_level 50
radiosity {
pretrace_start 0.08
pretrace_end 0.02
count 100
nearest_count 5
error_bound 1.8
recursion_limit 3
low_error_factor 0.5
gray_threshold 0.0
minimum_reuse 0.015
brightness 0.25
adc_bailout 0.005
}
}
sky_sphere {
pigment {
color red 0.7 green 0.7 blue 0.7
}
}
camera {
location <400, 200, -1000>
direction <0, 0, 6>
right x*1.33
look_at <0,60,0>
}
light_source {
<300,200,-500>
color red 0.5 green 0.5 blue 0.5
looks_like {sphere {<0,0,0>,5 pigment {color White} finish {ambient 1}}}
}
light_source {
<-50,400,-500>
color red 0.5 green 0.5 blue 0.5
looks_like {sphere {<0,0,0>,5 pigment {color White} finish {ambient 1}}}
}
plane {
<0,1,0>,0
texture {
pigment {color White}
finish {diffuse 1}
}
}
#declare block=difference {
superellipsoid {
<0.1,1>
scale 0.5
translate <0,0.25,0>
}
superellipsoid {
<0.1,1>
scale 0.495
}
translate <0,0.5,0>
}
#declare large_block=union {
object {
block
scale <30,100,30>
interior {ior 1.5}
texture {
pigment {color rgbf <0.90, 0.94, 1.0, 0.9>}
finish {
specular 0.6
roughness 0.002
ambient 0
diffuse 0.1
brilliance 5
reflection {
0, 1.0
fresnel on
}
}
}
}
}
#declare large_block_green=union {
object {
block
scale <30,100,30>
interior {ior 1.5}
texture {
pigment {color rgbf <0.8, 1.0, 0.8, 0.925>}
finish {
specular 0.6
roughness 0.002
ambient 0
diffuse 0.1
brilliance 5
reflection {
0, 1.0
fresnel on
}
}
}
}
}
#declare large_block_clear=union {
object {
block
scale <30,100,30>
interior {ior 1.5}
texture {
pigment {color rgbf <0.99, 0.99, 0.99, 0.9>}
finish {
specular 0.6
roughness 0.002
ambient 0
diffuse 0.1
brilliance 5
reflection {
0, 1.0
fresnel on
}
}
}
}
}
union {
object {large_block translate <0,0,50>}
object {large_block_clear translate <-50,0,50>}
object {large_block_clear translate <50,0,50>}
object {large_block translate <-50,0,0>}
object {large_block_green translate <0,0,0>}
object {large_block translate <50,0,0>}
object {large_block translate <0,0,-50>}
object {large_block_clear translate <-50,0,-50>}
object {large_block_clear translate <50,0,-50>}
}
Post a reply to this message
|
|
|
|
"Bob Hughes" <omniverse@charter%net> wrote in message
news:43eb7f93$1@news.povray.org...
> "Michael Goldshteyn" <mgo### [at] comcast net> wrote in message
> news:43eb5c8b$1@news.povray.org...
> >I created a scene with some glass like superellipsoids.
> > unsmooth transitions in the reflections in the glass columns. Even with
> > anti-aliasing on, the transitions aren't smooth at all and it looks very
> > computer generated and not very real. Can anyone help me with ideas on
how
> > to make this scene look better and more realistic?
>
> Two possible ideas, and both would slow the rendering down. Camera focal
> blur and/or refractive dispersion. However, neither would be direct a
remedy
> for softening reflections.
>
> I'm not certain of what you might be talking about exactly anyhow. Is it
> only the reflectiveness? Or is there something else about it? I tried
> rendering a small section at a large enough size to see the glass columns
> but I'm still not completely sure if it's only reflection causing the
sharp
> and dashed lines I'm seeing. Oh, also might be possible to lower
> max_trace_level without causing blackout areas, since I tried 15 instead
of
> 50 and it looked fairly okay.
>
> As you might already know, the superellipsoid primitive in a CSG
difference
> can be slow to render, so I hope you're ready for slower rendering if you
> take me up on my suggestions. ;)
>
> Have you considered using MegaPOV? It can blur reflections (or at least
did
> in some version). And there's also the regular POV version method of
> blending textures, just search for "blurred reflection" and you should
find
> plenty of past discussion about it.
>
> Bob
>
>
My few suggestions would include using a tight specular highlight with a
softer phong highlight. (borrowed from Lightbeam's glass technique I think.)
Then, maybe use a slight normal scaled large enough so it's not obviously
repeating on the individual objects. Something like
normal {waves 0.2 scale 0.7 }
adds a little character to a unit sphere by just giving the glass a bit of
non-uniformity.
Also, I no longer use colors in pigments for glass. purely rgbt<1, 1, 1, 1>.
Then I do coloring in the interior statement:
interior {
ior 1.5
fade_color <0.3, 1.0, 0.3>
fade_distance 0.15
fade_power 1003
dispersion 1.1
dispersion_samples 7
} // requires tweaking per object
These are things I like to use, they might not always be realistic but I
find them nice.
Post a reply to this message
|
|
