Hi,

I'm trying to make the expanding cloud of an explosion by shaping an
isosurface to roughly the shape of the explosion, and then filling it
with scattering media, so it doesn't look so firm.  The problem is,
I get a mostly black object.  The same interior parameters on a sphere
give me a nicely cloudy looking sphere.  Where have I gone wrong?

short sources are below, I've been turning one or the other objects
off by commenting/uncommenting the no_image line.

thanks,

          tom

camera
{
  up <0, 1, 0>
  right <1, 0, 0>
  location <-3,0,-30>
  look_at <0,0,0>
  angle 10
}

#include "colors.inc"
#include "functions.inc"

light_source { <200,180,-300> color rgb <1,1,1> }

sky_sphere { pigment { color rgb <0.8 0.8 1.0> } }

#declare S = function {x*x + y*y + z*z - 2}
//noisy sphere
#declare NS = function {x*x + y*y + z*z - 2 + f_noise3d(x*3,y*3,z*3)*1.2 }

isosurface {
  function { NS(x,y,z)
       - f_noise3d(f_ph(x-2.5,y,z)*40, 0, f_th(x-2.5,y,z)*40)*(x-3)/1.5 }
  max_gradient 15
  contained_by { sphere { <0,0,0>, 6 } }
  pigment { rgbt 1 } hollow
  interior { media { scattering { 1, 0.05 extinction 0.0 } } }
  //no_image no_shadow no_reflection
}

sphere { 0,2
  pigment { rgbt 1 } hollow
  interior { media { scattering { 1, 0.05 extinction 0.0 } } }
  no_image no_shadow no_reflection
}

Post a reply to this message

"Thomas A. Fine" <fin### [at] head-cfaharvardedu> wrote in message 
news:43a9e885$1@news.povray.org...
>
> I'm trying to make the expanding cloud of an explosion by shaping an
> isosurface to roughly the shape of the explosion, and then filling it
> with scattering media
> I get a mostly black object.

Apparently a max_trace_level related problem, as well as too low a 
max_gradient in the isosurface itself. POV suggests a max_gradient of around 
35 or 36, but I also found that global_settings {max_trace_level 30} helps 
clean it up.

Messing around with your media I tried this, too:

   media {
    method 2
    samples 3
    scattering { 1, <0.3,0.2,0.01> extinction 0.8 }
    emission <0.4,0.2,0.1>
    absorption <0.1,0.3,0.9>
    density {
     crackle
     density_map {
      [0 rgb 0] [1 rgb 5]
     }
     scale 0.2
    }
   }

So it would look more like a fiery cloud, even if it might not be what 
you're wanting exactly. Never-ending tweaking, this kind of stuff is, as you 
probably know. Just my feeble attempt there.

Bob

Post a reply to this message