I'm having a crash problem with isosurface
using pov-ray 3.6.1 for windows on windows XP:

// PoVRay 3.6 Scene File "isocrash.pov"
//--------------------------------------------------
#include "functions.inc"
//--------------------------------------------------
camera{  angle 10
          location  <20.0 , 20.0 ,-20.0>
          look_at   <0.0 , 0.5 , 0.0>
       }
// -------------------------------------------------
light_source{< -3000, 3000, -3000> color rgb<1,1,1>}
//--------------------------------------------------

isosurface {

   function{
   sqrt(  0.5*x*x + y*y + z*z - 1)
   - f_noise3d( x*12, y*12, z*12 )
   }

   contained_by { box { -2.5, 2.5 } }
   accuracy 0.002
   max_gradient 15

   texture{ pigment{ color rgb<0.45,0.9,0.1>}
                 finish { reflection 0.1}
               }
} // end of isosurface -----------------------------
/*
sphere { <0,0,0>, 0.75

                 pigment{ color rgb< 1, 0.0, 0.0>}

            translate<2.00,0,0>
        }  // end of sphere -------------------------
*/
/*
box { <0, 0,0>,< 1, 1, -1>
       pigment{color rgb<1,1,1>}
       translate<2.5,0,0>
     } // end of box --------------------------------
*/
//------------------------------------- end of scene

Rendering the scene without the sphere and the box
works well.

If we uncomment the sphere POV-Ray crashes, throwing
out an error message (see below!).

If we uncomment only the box no crash!


If we set "reflection 0.0" it does not crash,
also with the sphere.

There is no problem with this scene, if we render it
with POV-Ray version 3.5 !

Error message: //--------------------------------------------
The POV-Ray core rendering code threw an unhandled exception.
The backend thread has been shut down and you will not be
able to perform any further renders.
It is STRONGLY RECOMMENDED that you save your work and exit
POV-Ray now. Note that if internal structures have been
damaged POV-Ray may crash immediately after you click OK).
//-----------------------------------------------------------
system specs:
POV-Ray 3.6.1a.icl8.win32
Windows XP Home Edition (SP2)
Pentium IV 3.20 GHz
2 GB Ram
200 GB hard disk

The above scene crashes also on all my computers at home
and the computers in my school!
//-----------------------------------------------------------

Does anybody know where the problem is?

Greetings to all!



email: Fri### [at] t-onlinede
homepage: http://www.f-lohmueller.de/index.htm

Post a reply to this message

Friedrich Lohmueller wrote:
> I'm having a crash problem with isosurface
> using pov-ray 3.6.1 for windows on windows XP:

Renders without error in all variations using official 3.6.1 here (on Linux)

But note:

>   sqrt(  0.5*x*x + y*y + z*z - 1)

tries to calculate the square root of a negative number for some values 
of x,y and z, the result of this is not defined (and can vary from 
platform to platform - i even get different results with different 
builds here).

You almost certainly want:

sqrt( 0.5*x*x + y*y + z*z ) - 1


Christoph

-- 
POV-Ray tutorials, include files, Landscape of the week:
http://www.tu-bs.de/~y0013390/ (Last updated 24 Jul. 2005)
MegaPOV with mechanics simulation: http://megapov.inetart.net/

Post a reply to this message

Hi Christoph,

> But note:
> 
>>   sqrt(  0.5*x*x + y*y + z*z - 1)
> 
> 
> tries to calculate the square root of a negative number for some values 
> of x,y and z, the result of this is not defined (and can vary from 
> platform to platform - i even get different results with different 
> builds here).
> 
> You almost certainly want:
> 
> sqrt( 0.5*x*x + y*y + z*z ) - 1

Thanks a lot, that solves the problem!


Friedrich

Post a reply to this message