I've created some wings by stretching spheres in a blob. (First Blob!) 
However I need to get the texture right, or at least better than it is.

Right now, the feathers look like some plastic blow-up toy.

There's a post in P.B.I. called 'Flying Shopping Cart' that shows two 
regions: I can probably play around enought to get rid of the sheen 
marked by the red line, but I'd also like to 'feather' or somehow maybe 
fade the area shown by the green line.

Can any of the more experienced POVers in this group help me?

I've posted the full scene (as it stands at the moment) in P.B.I. called 
'Flying Shopping Cart' if you're wondering what I'm up to.

Thanks and Cheers!
Rick Measham

__SCENE__
// This will just render the wings. I've in-lined my wing.inc.
#version 3.5;

#include "colors.inc"
//#include "wing.inc"


global_settings {
   assumed_gamma 1.0
}

// ----------------------------------------
#declare niceCam = camera {
   location  <-20.0, 30, -40>*0.6
   direction 1.5*z
   right     x*image_width/image_height
   look_at   <0.0, 6.5,  -3>
}


sky_sphere {
   pigment {
     gradient y
     color_map {
       [0.0 rgb <0.6,0.7,1.0>]
       [0.7 rgb <0.0,0.1,0.8>]
     }
   }
}

plane {
   y, -1
   pigment { Blue * 2 }
}

light_source {
   <0, 0, 0>            // light's position (translated below)
   color rgb <1, 1, 1>  // light's color
//  area_light <2,0,0>, <0,0,2>, 5,5 // turned off to speed render!
   translate <-30, 30, -30>

}
// ----------------------------------------
// This is wing.inc:
// ----------------------------------------

#macro feather( fAngle, fWidth, fLength )
     sphere {
         <0,fWidth,0>
         fWidth, 1
         scale <0, 1/fWidth * fLength, 0>
         rotate <0,0,90-fAngle>
     }
#end
#declare txtWing=texture{
          pigment{White}
          normal{bumps 0.1 scale 0.5}
          finish{ambient 0.2 diffuse 0.8 specular 1 roughness 0.1}
}

#declare wing=blob{
   threshold 0.1
         #declare d=5;
         #while (d < 45)
                 feather( d, 0.15, 0.2 * (d/5) + 0.4 )
                 #declare d=d+5;
         #end
         sphere {
                 <-0.2,0.1,0>
                 0.2, 1
         }
         texture { txtWing }
         scale <1,1,0.5>
         rotate <-10,0,0>
}

#declare leftWing=object {
         wing
         rotate <-10,0,0>
}
#declare rightWing=object {
         wing
         scale <-1,1,1>
         rotate <-10,0,0>
}

// ----------------------------------------

#declare Index = 3;

merge { //wings
         object{
                 leftWing
                 scale 4
                 rotate <0,20, 0>
                 translate <-2.15, Index + 4.1, 0>
         }
         object{
                 rightWing
                 scale 4
                 rotate <0,-20, 0>
                 translate <2.15, Index + 4.1, 0>
         }
         object{
                 leftWing
                 scale 2
                 rotate <0,10, 30>
                 translate <-2.6, Index + 4.3, 0.15>
         }
         object{
                 rightWing
                 scale 2
                 rotate <0,-10, -30>
                 translate <2.6, Index + 4.3, 0.15>
         }
         translate z*0.75
}

camera { niceCam }

__END__

Post a reply to this message

'media', the scattering kind, could help to soften the feathers.

You would need to make your blob objects completely transparent, hollow, and 
lose the finish statement to prevent the sharp bright edges.

Bob Hughes

Post a reply to this message