Hi!

I am really clueless now.. I want to create a rotating sphere with the
effect seen here: http://users.pandora.be/eclypse/

I just dont get the emitting beams right. As soon as i add media the whole
scene is lit bright. Is this a CSG or media error?
Rotating is working and I cut the holes using cylinders... i would
appreciate
any hint very much how to do the light emitting from inside the sphere
right.

Thank you

Carsten

Here is what i have so far:


--------------- snip ---------------------
// Persistence of Vision Ray Tracer Scene Description File
// File: gomb.pov
// Vers: 3.5


#version 3.5;

#include "colors.inc"


global_settings {
  assumed_gamma 5.0
}



media {    // atmospheric media
  intervals 10
  scattering { 1, rgb 0.03 }
  samples 1, 10
  confidence 0.9999
  variance 1/1000
  ratio 0.9
}



camera {
  location  <1.5, 0, 0>
  rotate  <90,0, 360*clock>

  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0.0, 0.0,  0.0>
}




light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <10,10,10>  // light's color
  media_attenuation off
//  translate <-30, 30, -30>
}

// ----------------------------------------



difference{

sphere {
  0.0, .5
  color rgb <1, 1, 1>  // light's color
  hollow

texture {

    finish{
      specular 0.6
    }
    }

}


// Capped Cylinder, closed [or open ended]
// cylinder { <END1>, <END2>, RADIUS [open] }
//  END1 = coord of one end of cylinder
//  END2 = coord of other end
// RADIUS = size of cylinder
// open = if present, cylinder is hollow, else capped

#declare Index2 = 1;
#while(Index2 <= 10)

#declare Index = 1;
#while(Index <= 10)


cylinder {
  -1*x,  1*x,  0.03
   open
   hollow
   rotate <1,Index2*18,Index*18>

texture {
    finish{
      specular 0.6
    }
  }
}


  #declare Index = Index + 1;
#end

  #declare Index2 = Index2 + 1;
#end

}

Post a reply to this message

There are several things you might want to change.
1. Place the media inside a hollow container, e.g. a box or such. It can be
very difficult for POV-Ray to properly place the sampling of the intervals
when the rays aren't stopped at an object somewhere.
2. Also note that scattering media also absorbs light, so objects further
away will be less visible. With Point 1 this is the reason why the
background shows white, using a simple box (hollow and with pigment{rgbt 1}
to make the surface invisible) solves that.
3. Why do you set assumed_gamma to 5.0?! A normal screen has 2.2 or so, and
the Docs advise to use 1.0.

That should get you started.

Regards,
Tim

-- 
"Tim Nikias v2.0"
Homepage: <http://www.nolights.de>

Post a reply to this message

What do you think of this?

Regards

----------------------------------------------------------------------------
--------------------------

// Persistence of Vision Ray Tracer Scene Description File
// File: gomb.pov
// Vers: 3.5


#version 3.5;

#include "colors.inc"


global_settings {
  assumed_gamma 1.0
}



camera {
  location  <1.5, 0, 0>
  rotate  <90,0, 360*clock>

  direction 1.0*z  // So we can see the whole sphere.
  right     x*image_width/image_height
  look_at   <0.0, 0.0,  0.0>
}




light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <10,10,10>  // light's color
  media_attenuation off
//  translate <-30, 30, -30>
}

// ----------------------------------------



difference{

  sphere {
    0.0, .5
    hollow
  }


  // Capped Cylinder, closed [or open ended]
  // cylinder { <END1>, <END2>, RADIUS [open] }
  //  END1 = coord of one end of cylinder
  //  END2 = coord of other end
  // RADIUS = size of cylinder
  // open = if present, cylinder is hollow, else capped

  #declare Index2 = 1;
  #while(Index2 <= 10)

    #declare Index = 1;
    #while(Index <= 10)


      cylinder {
        -1*x,  1*x,  0.015 // So not only the beams are thinner but they
spread less.
         //open  // There's no point in removing a cylinder's caps
                      // if you're subtracting it from another shape!
         hollow
         rotate <1,Index2*18,Index*18>
      }

      #declare Index = Index + 1;
    #end

    #declare Index2 = Index2 + 1;
  #end

  texture {  // When all the objects inside a CSG block have the same
texture, attaching it
               // to the whole CSG is faster and simpler.
    pigment{rgb 0} // Does nothing, but avoids a warning.
    finish{
      specular 0.6
    }
  }

}

sphere {  // We constrain the media within a concentric sphere.
  0, .65
  hollow
  pigment {rgbt 1}
  interior {
    media {
      intervals 10
      scattering { 1, rgb 1 }
      samples 1, 10
      confidence 0.9999
      variance 1/1000
      ratio 0.9
      density { onion frequency -1 scale 0.65 }  // To get a smooth
transition into darkness
                                                   // at the end of each
light beam.
    }
  }
}

Post a reply to this message

Great!

Thank you very much for the help to both of you!

Carsten

"Frango com Nata" <odo### [at] yahoocombr> schrieb im Newsbeitrag
news:417126e4@news.povray.org...
> What do you think of this?
>
> Regards
>
> --------------------------------------------------------------------------
--
> --------------------------
>
> // Persistence of Vision Ray Tracer Scene Description File
> // File: gomb.pov
> // Vers: 3.5
>
>
> #version 3.5;
>
> #include "colors.inc"
>
>
> global_settings {
>   assumed_gamma 1.0
> }
>
>
>
> camera {
>   location  <1.5, 0, 0>
>   rotate  <90,0, 360*clock>
>
>   direction 1.0*z  // So we can see the whole sphere.
>   right     x*image_width/image_height
>   look_at   <0.0, 0.0,  0.0>
> }
>
>
>
>
> light_source {
>   <0, 0, 0>            // light's position (translated below)
>   color rgb <10,10,10>  // light's color
>   media_attenuation off
> //  translate <-30, 30, -30>
> }
>
> // ----------------------------------------
>
>
>
> difference{
>
>   sphere {
>     0.0, .5
>     hollow
>   }
>
>
>   // Capped Cylinder, closed [or open ended]
>   // cylinder { <END1>, <END2>, RADIUS [open] }
>   //  END1 = coord of one end of cylinder
>   //  END2 = coord of other end
>   // RADIUS = size of cylinder
>   // open = if present, cylinder is hollow, else capped
>
>   #declare Index2 = 1;
>   #while(Index2 <= 10)
>
>     #declare Index = 1;
>     #while(Index <= 10)
>
>
>       cylinder {
>         -1*x,  1*x,  0.015 // So not only the beams are thinner but they
> spread less.
>          //open  // There's no point in removing a cylinder's caps
>                       // if you're subtracting it from another shape!
>          hollow
>          rotate <1,Index2*18,Index*18>
>       }
>
>       #declare Index = Index + 1;
>     #end
>
>     #declare Index2 = Index2 + 1;
>   #end
>
>   texture {  // When all the objects inside a CSG block have the same
> texture, attaching it
>                // to the whole CSG is faster and simpler.
>     pigment{rgb 0} // Does nothing, but avoids a warning.
>     finish{
>       specular 0.6
>     }
>   }
>
> }
>
> sphere {  // We constrain the media within a concentric sphere.
>   0, .65
>   hollow
>   pigment {rgbt 1}
>   interior {
>     media {
>       intervals 10
>       scattering { 1, rgb 1 }
>       samples 1, 10
>       confidence 0.9999
>       variance 1/1000
>       ratio 0.9
>       density { onion frequency -1 scale 0.65 }  // To get a smooth
> transition into darkness
>                                                    // at the end of each
> light beam.
>     }
>   }
> }
>
>

Post a reply to this message