Hey

Here is the noob again asking questions.

Ive got 2 looks_like { CrystalBall } lightsources.
They are area_light <5,0,0> <0,0,5>5,5
When i render and watch the output it seems like that the light is only
emitting from specific points inside the crystal ball.
Im trying to get a constant glow out the ball, which lets of the same amount
of light in every direction. Ive tried without area_light too, but that
doesnt seem to fix it.

any ideas would be appreciated :)

TIA

Christian

Post a reply to this message

"Christian Bryndum" <cbr### [at] deakineduau> wrote in message
news:3f79233b@news.povray.org...

> Ive got 2 looks_like { CrystalBall } lightsources.

looks_like won't do what you want...

> They are area_light <5,0,0> <0,0,5>5,5

Have you used the orient and circular keywords?

Try something like:

light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  area_light <2,0,0>,<0,2,0>,5,5 orient circular
  looks_like{sphere {<1,1,0>, 1} pigment{Red} finish{ambient 1}}
  translate <-3, 3, -3>
}

> any ideas would be appreciated :)

For more realistic results, you will probably need to use radiosity and a sphere
with an emitting media.

Take a look at section 4.1 in the docs (and specifically 4.1.3).

Or try this (rather crappy) scene (note no light source):

#version 3.5;

#include "colors.inc"

global_settings {  ambient_light 0  assumed_gamma 1.0}

global_settings {
  radiosity {
    pretrace_start 0.08
    pretrace_end   0.01
    count 500
    nearest_count 10
    error_bound 0.02
    recursion_limit 3
    low_error_factor 0.2
    gray_threshold 0.5
    minimum_reuse 0.0015
    brightness 10
    adc_bailout 0.01
    media on
  }
}

camera {  location  <0.0, 5, -15.0>  look_at   <0.0, 0.0,  0.0>}
plane {  y, -1  pigment { color rgb <0.7,0.5,0.3> }}

sphere {  0.0, 1  pigment{Green}}

sphere{
  0,1.5
  pigment{rgbf 1}
  hollow
  interior{
    media{
      emission rgb<1,1/4,1/4>*5
      density{wrinkles}
      density{spherical}
    }
  }
  translate<-3,3,-3>
}

Post a reply to this message

Perhaps someone should update the docs to take care of this slight
misconception of area_lights, which pops up every now and then...

Arealights only affect *shadows*, not *where the light is coming from*.

In effect, the lightsource is still a pointlight. Illumination is rendered
like you used a pointlight. Arealights only go off as soon as some shadow
needs to be processed, *then* it checks the area, how much of the points
illuminate the shaded area, and how many really don't.

There are a few option to go round this: like Tom Melly suggested, use
radiosity. Still, Radiosity has a large impact on the lighting of a scene in
its entirety, and takes a lot of tweaking to get it right (you might want to
check my website, http://www.digitaltwilight.de/no_lights, I've made some
experiments on the standard Cornell-Box). What you might want to do is take
several lightsources (this time, don't use area_lights though) and actually
*build* a spherical area_light. To do this, you might want to use my
ESP-Macro (available in my downloads section), which will generate positions
for an even distribution on a sphere for an arbitrary amount of sources.
Note though that lighting calculations and thus rendering time will rise, as
well as parsing time (preparing the light-buffers etc when using lots of
lights and objects, along with the parsing of the macro). Don't forget to
put no_shadow on the sphere you're placing it in then, unless it's
transparent and is supposed to somehow affect the light.

-- 
Tim Nikias v2.0
Homepage: http://www.digitaltwilight.de/no_lights
Email: tim.nikias (@) gmx.de


> Hey
>
> Here is the noob again asking questions.
>
> Ive got 2 looks_like { CrystalBall } lightsources.
> They are area_light <5,0,0> <0,0,5>5,5
> When i render and watch the output it seems like that the light is only
> emitting from specific points inside the crystal ball.
> Im trying to get a constant glow out the ball, which lets of the same
amount
> of light in every direction. Ive tried without area_light too, but that
> doesnt seem to fix it.
>
> any ideas would be appreciated :)
>
> TIA
>
> Christian
>
>


---
Outgoing mail is certified Virus Free.
Checked by AVG anti-virus system (http://www.grisoft.com).
Version: 6.0.521 / Virus Database: 319 - Release Date: 23.09.2003

Post a reply to this message

Oh, just re-read your original post. orient and circular, like Tom
mentioned, might be sufficient.

-- 
Tim Nikias v2.0
Homepage: http://www.digitaltwilight.de/no_lights
Email: tim.nikias (@) gmx.de



---
Outgoing mail is certified Virus Free.
Checked by AVG anti-virus system (http://www.grisoft.com).
Version: 6.0.521 / Virus Database: 319 - Release Date: 23.09.2003

Post a reply to this message