Anyone know why I dont get an orange shadow from this scene?


#include "colors.inc"

global_settings {
  assumed_gamma 1
  max_trace_level 8
  photons {
    spacing 1/10
  }
}

// camera

camera {
  location <-10, 16, 30>
  look_at <0, 0, 0>
  angle 40
}

// lights

light_source {
  <50, 100, 0>
  color White
  spotlight
  radius 0
  falloff 90
  tightness 60
}

// floor

plane {
  y, 0
  pigment {
    checker Gray25, Gray75
    scale 4
  }
  finish {
    reflection 1/5
    specular 1
    roughness 1/50
  }
}

// object - glass

#declare GAP = 1e-10;

merge {
  torus {
    3.8, 0.2
    translate <0, 8, 0>
  }
  difference {
    cylinder {
      <0, 0 + GAP, 0>, <0, 8, 0>, 4
    }
    cylinder {
      <0, 0.8, 0>, <0, 9, 0>, 3.6
    }
  }
  pigment {
    color rgb <0.98, 1, 0.98>
    filter 0.98
  }
  finish {
    reflection 1/8
    specular 1
    roughness 1/50
  }
  interior {
    ior 1.5
  }
  photons {
    target
    reflection on
    refraction on
  }
  translate <-2, 0, 5>
}

// object - liquid

cylinder {
  <0, 0.8 + GAP, 0>, <0, 5, 0>, 3.6 - GAP
  pigment {
    color Orange
    filter 1/2
  }
  interior {
    ior 1.33
  }
  finish {
    reflection 1/3
    specular 1
    roughness 1/50
  }
  photons {
    target
    reflection on
    refraction on
  }
  translate <-2, 0, 5>
}

Post a reply to this message

Quietman wrote:
>Anyone know why I dont get an orange shadow from this scene?
>
>

i don't have an orange shadow when i render this (adding } } at the end of
the file)

Post a reply to this message

Quietman wrote:
> 
> Anyone know why I dont get an orange shadow from this scene?

You are getting an orange colored caustic but you are hiding it
under the glass. Try moving the light source.

-- 
Ken Tyler

Post a reply to this message

Since you are using a gap to separate the liquid and the glass, the caustics
are very sensitive to the IOR values.  The light may be "stuck" between the
liquid and the glass, or it may just be refracted sharply downward by the
high IOR of the liquid.  I would reduce the IOR of the liquid to 0, and
reduce the IOR of the glass a bit also.  Then, you will see the caustic
more profoundly.

David Diel

ddi### [at] mitedu

Post a reply to this message