|
 |
Here is the source code for the "Void Eggs" image- all textures and pigments
included:
// File: VoidEggs.pov
// Vers: 3.5
// Desc: Abstract image file
// Date: 25-Mar-2002
// Auth: Charles W. Shults III
//
#version 3.5;
#include "colors.inc"
global_settings {
assumed_gamma 1.0
max_trace_level 5.0 // to get the floor layers to appear
}
// ----------------------------------------
camera {
location <0.0, 1,0>
direction 1.5*z
right x*image_width/image_height
look_at <0.0, 1.0, 1.0>
}
sky_sphere { // this is the rippled blue effect
pigment {
radial frequency 2000
turbulence .75
translate 10*x
color_map {
[0.00 Black]
[0.45 Gray20]
[0.50 Blue]
[0.55 Gray20]
[1.00 Black]
}
}
}
light_source {
<-30, 30, -30>
color rgb 1
}
// ----------------------------------------
fog { // a yellow, sulphurous fog
fog_type 2
distance 20
color rgb <.3,.3,.1>
fog_offset 0.1
fog_alt 0.2
turbulence 0.9
}
#declare PL = pigment {leopard // rippled orangey layers for the floor
frequency 20
color_map {
[0.00 Clear]
[0.80 Clear]
[0.83 Orange]
[0.97 Red]
[1.00 Black]
}
};
#macro Zip(a,b,c) // the "egg" with the circuitry pattern
sphere {
0.0, 1
texture {
pigment {
crackle scale .33
rotate <a,b,c>
frequency 16
color_map {
[0.00 rgb <.1,.4,.1> ]
[0.50 rgb <.1,.4,.1> ]
[0.50 Copper ]
[1.00 Silver ]
}
}
finish{
specular 0.6 metallic 1 reflection .2 brilliance 3 ambient -.1 roughness
.2
}
}
scale <1.2,1,1>
}
#end
// now drop all items into the scene
// create the layered floor effect
cylinder {<0,-1.00,0><0,-1.03,0> 500 pigment {PL } }
cylinder {<0,-1.06,0><0,-1.09,0> 500 pigment {PL } }
cylinder {<0,-1.12,0><0,-1.15,0> 500 pigment {PL } }
cylinder {<0,-1.18,0><0,-1.21,0> 500 pigment {PL } }
cylinder {<0,-1.24,0><0,-1.27,0> 500 pigment {PL } }
// create the "eggs"
object {Zip( 23, 45, 19) translate <-2, 0,10>}
object {Zip( 0, 0, 0) translate < 0, 0, 5>}
object {Zip( 12,-38, 27) translate < 3, 0, 9>}
object {Zip(180, 0,-34) translate < 2, 0, 3>}
// end of POV code
Cheers!
Chip Shults
My robotics, space and CGI web page - http://home.cfl.rr.com/aichip
light_source{0#macro k(_)sphere{13*z+i*_.5pigment{agate}finish{phong.3}}#end
1}#macro _(s,i,g)#if(s)k(1)k(-1)_(s-1i+g,g)#end#end _(3x+3*y<2,-2>)_(2x,y)_(
2x-y,x)_(4x*3,-y)_(4<3,1>x)_(2x*6,-y)
Post a reply to this message
|
|
rr