How do I get a pigment to work on an isosurface, the normal syntax will not
work, I mean c'mon. I gant even get a simple color on it, b/s using ambient,
which does no more justice to the curves and angles than does black.  I know
that this has probly been addressed b4, but I can't find it.
Thanx for your time.

""If you leave few things to chance, you will do few things poorly, but you
will do very few things."

Post a reply to this message

"TAlphaBravo" <TAl### [at] yahoocom> wrote in message
news:3c58be72$1@news.povray.org...
> How do I get a pigment to work on an isosurface, the normal syntax will
not
> work, I mean c'mon. I gant even get a simple color on it, b/s using
ambient,
> which does no more justice to the curves and angles than does black.  I
know
> that this has probly been addressed b4, but I can't find it.
> Thanx for your time.
>

It's easier to diagnose and solve a problem it there is code posted
The code below works (pov 3.5)

#include "functions.inc"

camera { location <0,4,-10> look_at <0,0,0>}

light_source {<-5,5,-20>  rgb 1}

light_source {<5,5,10> rgb 1}

isosurface {
 function {y-f_noise3d(x*3,0,z*3)}
 max_gradient 5
 contained_by {box {<-5,-1,-5>,<5,5,5>}}
 pigment {
  bozo
  scale 0.5
  color_map {
   [0.0 rgb <1,0,0>]
   [1.0 rgb <0,0,1>]
  }
 }
}

Gail
--
#macro G(H,S)disc{0z.4pigment{onion color_map{[0rgb<sin(H/pi)cos(S/pi)*(H<6)
cos(S/pi)*(H>6)>*18][.4rgb 0]}}translate<H-5S-3,9>}#end G(3,5)G(2,5.5)G(1,5)
G(.6,4)G(.5,3)G(.6,2)G(1,1)G(2,.5)G(3,.7)G(3.2,1.6)G(3.1,2.5)G(2.2,2.5)G(9,5
)G(8,5.5)G(7,5)G(7,4)G(7.7,3.3)G(8.3,2.7)G(9,2)G(9,1)G(8,.5)G(7,1)//GS

Post a reply to this message

Here is the problematic source code, I forgot it in my orginal message:

camera{location <10,10,-10> look_at <0,0,0>}
background{rgb 1}

light_source{<0,10,-10>, rgb 1
area_light 4,4,6,6
circular orient jitter}

isosurface {
    function {sqrt((x*y)^2+(y*z)^2+(z*x)^2-3)}
    max_gradient 36
    accuracy 0.01
    contained_by { sphere {<0,0,0>,6} }

     pigment {
  bozo
  scale 0.5
  color_map {
   [0.0 rgb <1,0,0>]
   [1.0 rgb <0,0,1>]
  }
 }
}

Post a reply to this message

This is strange.
While it does not solve your problem, try this slightly varied code:

camera{location <10,10,-10> look_at <0,0,0>}
background{rgb 0}

light_source{<10,10,-10>, rgb 6
}

isosurface {
    function {sqrt((x*y)^2+(y*z)^2+(z*x)^2-3)}
    max_gradient 36
    accuracy 0.00001
    contained_by { sphere {<0,0,0>,6} }
    pigment {
      rgb <1,0,0>
     }
}

double_illuminate fixes is to some avail, but gives strange results anyway.
Perhaps you should report this to p.b-t? Higher max_gradient or lower
accuracy did not help at all.

Marc-Hendrik

Post a reply to this message

In article <3c59b30e$1@news.povray.org>, TAl### [at] yahoocom says...
> function {sqrt((x*y)^2+(y*z)^2+(z*x)^2-3)}

I don't know why this doesn't work, but moving that -3 out of the sqrt 
makes it work, without changing the shape much.

Lutz-Peter

Post a reply to this message

"Lutz-Peter Hooge"  wrote in message .
> In article <3c59b30e$1@news.povray.org>, TAl### [at] yahoocom says...
> > function {sqrt((x*y)^2+(y*z)^2+(z*x)^2-3)}
> 
> I don't know why this doesn't work, 

Because the above function has imaginary values.

>but moving that -3 out of the sqrt 
> makes it work, without changing the shape much.
 
Because this does not have imaginary values.

R. Suzuki

Post a reply to this message

In article <3c59fe90@news.povray.org>, r-s### [at] aistgojp says...

> Because the above function has imaginary values.
Oops. Of course you are right.

Lutz-Peter

Post a reply to this message