I am doing an animation translating a scattering media
(bozo'd) 'through' a solid.  At frame 1, only one of the
objects is affected.  Subsequent frames show all the
solid, filled objects affected.  The effect looks like
some kind of scan line error.  A much older post that
seemed to indicate a similar error referred to a 'lathe bug'.
What I'm seeing may help to finally nail that one down
if it's the same or a related problem.

A ZIP file containing the POV,INI,necessary INC and GIF
files to re-render the scene and several frames from 
the animation showing the problem are on my webserver:
http://www.untiedmusic.com/media_error.zip
(It's about a 500K file)

PovWin 3.5
Pent 4 1.2GHz, 256MB RAM
Win Nt 4 SP 6

If anyone can confirm this on another platform and/or suggest a
work-around, it would be greatly appreciated!

Just FYI, this is an animatic for a 2+ minute animation I hope
to get on TechTV's EyeDrops show.  I have 1:45 of the video rendered
at 720x540@15fps - now up to about 10 CPU DAYS of rendering time...

Emory Stagmer
  Executive Producer, UnTied Music
  Bass/12string/windsynth for Ezekiel's Wheel
    http://www.untiedmusic.com

Post a reply to this message

In article <3D7DE417.8DE00E20@comcast.net> , Gwen & Emory Stagmer 
<emo### [at] comcastnet>  wrote:

> A ZIP file containing the POV,INI,necessary INC and GIF
> files to re-render the scene and several frames from
> the animation showing the problem are on my webserver:
> http://www.untiedmusic.com/media_error.zip
> (It's about a 500K file)

Well, producing scenes in a readable indentation usually helps you to find
your mistakes ;-)

So after adding at least some basic indentation you will find that your
problem, as indicated by the parser warning, is that you assigning the
interior only to some parts of the intersection object.  Pair this with a
few coincident-surface-like problems (which still exists to some extend in
the scene below) and you get funny artifacts.  So properly placing the
interior block and removing unnecessary "object" blocks from your scene, you
get the follow, which works just fine as expected:

#include "consts.inc"
#include "colors.inc"
#include "landscap.inc"
#include "stones1.inc"

#if(clock=0)
 #declare HERMITE_FRAME = 1;
#else
 #declare HERMITE_FRAME = clock-1;
#end

#declare vpt=<-210,10,6>;
#declare lookat=<160,0,100>;

#declare show_clouds = false;
#declare show_mist_boxes = false;
#declare hi_res_clouds = false;

global_settings{ max_trace_level 25 }


camera
{
 location vpt
 direction <0,0,1>
 sky <0,0,1>
 look_at lookat
}

intersection
{
 box {0 1}
 height_field
 {
  gif "edhead.gif"  smooth water_level 0.05
 }
 no_shadow
 hollow
 texture{ pigment{ color Clear } }
 interior
 {
  media
  {
   //emission 0.5
   scattering {3, rgb 0.5}
   //absorption rgb<1,0,1>
   samples 1,10
   density
   {
    //boxed
    bozo
    color_map
    {
     [0.0 rgb 0.1]
     [0.4 rgb 0]
     [0.5 rgb 0.3]
     [0.6 rgb 0.1]
     [0.8 rgb 0.4]
     [1.0 rgb 0.1]
    }
    scale 1
    turbulence 1
    translate x*clock/20
   }
   method 3
  }
 }
 rotate <90,0,0>
 scale <150,250,50>
 translate <-75,125,0> /* centered over origin */
 rotate <-90,0,90+(5-clock/10)>
 translate <160,0,120>
 finish{ambient 0.6}
}

intersection
{
 box {0 1}
 height_field
 {
  gif "allenhead.gif"  smooth water_level 0.05
 }
 no_shadow
 hollow
 texture{ pigment{ color Clear } }
 interior
 {
  media
  {
   //emission 0.5
   scattering {3, rgb 0.5}
   //absorption rgb<1,0,1>
   samples 1,10
   density
   {
    //boxed
    bozo
    color_map
    {
     [0.0 rgb 0.1]
     [0.4 rgb 0]
     [0.5 rgb 0.3]
     [0.6 rgb 0.1]
     [0.8 rgb 0.4]
     [1.0 rgb 0.1]
    }
    scale 1/2
    turbulence 1
    translate x*clock/20
   }
   method 3
  }
 }
 rotate <90,0,0>
 scale <150,250,50>
 translate <-75,125,0> /* centered over origin */
 rotate <-90,0,90+(5-clock/10)>
 translate <160,150,120>
 finish{ambient 0.6}
}


intersection
{
 box {0 1}
 height_field
 {
  gif "emoryhead.gif"  smooth water_level 0.05
 }
 no_shadow
 hollow
 texture{ pigment{ color Clear } }
 interior
 {
  media
  {
   //emission 0.5
   scattering {3, rgb 0.5}
   //absorption rgb<1,0,1>
   samples 4,10
   density
   {
    //boxed
    bozo
    color_map
    {
     [0.0 rgb 0.1]
     [0.4 rgb 0]
     [0.5 rgb 0.3]
     [0.6 rgb 0.1]
     [0.8 rgb 0.4]
     [1.0 rgb 0.1]
    }
    scale 1/2
    turbulence 1
    translate x*clock/20
   }
   method 3
  }
 }
 rotate <90,0,0>
 scale <150,250,50>
 translate <-75,125,0> /* centered over origin */
 rotate <-90,0,90+(5-clock/10)>
 translate <160,-150,120>
 finish{ambient 0.6}
}

light_source
{
 <-800,0,800>
 rgb 1
}

#if(show_clouds)
box
{
 -1 1
 hollow
 texture
 {
  pigment { color Clear }
 }
 interior
 {
  media
  {
   scattering { 1, rgb<.1,.1,.1> }
   #if (hi_res_clouds)
   intervals 50
   samples 1,4
   #else
   intervals 15
   samples 1,2
   #end
   density
   {
    //boxed
    marble
    color_map
    {
     [0.0 Black]
     [0.4  White/4]
     [0.5  Black]
     [0.7  White/3]
     [0.8  Black]
     [1.0  White/2]
    }
   }
   scale 1
   turbulence .5+(sin(clock/80)/5)
   octaves 10
   omega .2
  }
 }
 scale <1000,1000,8>
 translate z*12
 finish{ ambient 1 }
}
#end


#if (show_mist_boxes)
box
{
 <-100000,-100000,10>, <100000,100000,14>
 
 texture{ Mist scale (190+(clock/10/50)) }
 rotate <0,3,0>
 finish{ambient 0.4}
}

box
{
 <-100000,-100000,100>, <100000,100000,200>
 
 texture{ Mist scale (190+(clock/10/50)) }
 rotate <0,10,0>
 finish{ambient 0.4}
}
#end

height_field
{
 gif "mandcros.gif"
 rotate <90,0,0>
 texture{ pigment{Landscape} scale 1.1 }
 scale <400,400,5>
 translate <-200,200,0>
 rotate <0,0,0>
 finish{ambient 0.5}
}

light_source
{
 <-5000,-2000,5000>
 color rgb < 0.8, 0.7, 1.0>
 rotate <0,0,-clock/10>
}



____________________________________________________
Thorsten Froehlich, Duisburg, Germany
e-mail: tho### [at] trfde

Visit POV-Ray on the web: http://mac.povray.org

Post a reply to this message

In article <3D7DE417.8DE00E20@comcast.net> , Gwen & Emory Stagmer 
<emo### [at] comcastnet>  wrote:

> I am doing an animation translating a scattering media
> (bozo'd) 'through' a solid.  At frame 1, only one of the
> objects is affected.  Subsequent frames show all the
> solid, filled objects affected.  The effect looks like
> some kind of scan line error.  A much older post that
> seemed to indicate a similar error referred to a 'lathe bug'.
> What I'm seeing may help to finally nail that one down
> if it's the same or a related problem.

POV-Ray is a ray tracer, not a scanline renderer.  So there cannot be "some
kind of scan line error" anywhere under any condition simply because there
is no scanline for an object.  And what you posted also has absolutely
nothing to do with the lathe object.  As you know, your scene uses the
heightfield object.  As you did not say which particular lathe object
problem you are referring to, I assume you are talking about people
forgetting to use the "sturm" keyword which turns on a more precise root
finding algorithm and usually eliminated artifacts.  This again would be a
user error, just like in your scene.

    Thorsten

____________________________________________________
Thorsten Froehlich, Duisburg, Germany
e-mail: tho### [at] trfde

Visit POV-Ray on the web: http://mac.povray.org

Post a reply to this message

Gwen & Emory Stagmer wrote:
> 

> 
> If anyone can confirm this on another platform and/or suggest a
> work-around, it would be greatly appreciated!
> 
> Just FYI, this is an animatic for a 2+ minute animation I hope
> to get on TechTV's EyeDrops show.  I have 1:45 of the video rendered
> at 720x540@15fps - now up to about 10 CPU DAYS of rendering time...

Sorry, no help for your problem (I'm just starting to get a working
knowledge of media - I still don't understand most of the keywords for
them), but I did have some questions on your project.

Is that a typical size for a TV animation?  What format do they want it
(avi? MPG?)  What do you use to put the frames together?  

I saw Shrek on the big screen last weekend, and watched the background -
the blades of grass were done individually, the leaves were great, the
pine trees looked great (all things I've played with recently).  Does
anyone know what kind of resolution a feature film takes?  

Thanks.

> Emory Stagmer

-- 
Tom A.
When scientist say they're making a "quantum leap" it 
means they are going out to catch some rays.  - Dr. Science
Deja mail is gone.  Look for me at raugost at yahoo . com

Post a reply to this message

Thorsten,
   Thank you very much.  I'm usually a serious stickler for 
indentation, but I was just trying, as I said, to produce
a test render and hacked some stuff together.
  I've been using POV since version 2, so I'm QUITE aware that
it's not a scanline renderer - I was referring to the way
the artifacts appeared in the test renders that showed the
error.

Emory
 
Thorsten Froehlich wrote:
> 
> In article <3D7DE417.8DE00E20@comcast.net> , Gwen & Emory Stagmer
> <emo### [at] comcastnet>  wrote:
> 
> > I am doing an animation translating a scattering media
> > (bozo'd) 'through' a solid.  At frame 1, only one of the
> > objects is affected.  Subsequent frames show all the
> > solid, filled objects affected.  The effect looks like
> > some kind of scan line error.  A much older post that
> > seemed to indicate a similar error referred to a 'lathe bug'.
> > What I'm seeing may help to finally nail that one down
> > if it's the same or a related problem.
> 
> POV-Ray is a ray tracer, not a scanline renderer.  So there cannot be "some
> kind of scan line error" anywhere under any condition simply because there
> is no scanline for an object.  And what you posted also has absolutely
> nothing to do with the lathe object.  As you know, your scene uses the
> heightfield object.  As you did not say which particular lathe object
> problem you are referring to, I assume you are talking about people
> forgetting to use the "sturm" keyword which turns on a more precise root
> finding algorithm and usually eliminated artifacts.  This again would be a
> user error, just like in your scene.
> 
>     Thorsten
> 
> ____________________________________________________
> Thorsten Froehlich, Duisburg, Germany
> e-mail: tho### [at] trfde
> 
> Visit POV-Ray on the web: http://mac.povray.org

Post a reply to this message

Tom,
   Here's the URL for their submission guidelines:
http://www.techtv.com/eyedrops/story/0,24330,3373159,00.html
I just picked the highest numbers...They don't give
(in my opinion) enough info - no fps numbers for instance.
I picked 15, though 30 is surely smoother.  They say
the want MPEG or Quicktime, but there are about a million
parameters for both of them and no guidelines as to any
specifics.  I posted a question to TechTV 2 weeks ago,
but don't really expect an answer.  Probably what I'll
get is a "hey that's cool, but we can't show it because
you didn't do <THIS>" response when I send the stuff in...
:^\
BTW: NONE of the movies you see in the theatre are ray-traced.
They use very different techniques, although I think I
remember reading that they are using some ray-tracing
techniques in small areas.  The usenet group
comp.graphics.rendering.raytracing gets read by a few
guys at Pixar and they contribute regularlly!

The video is called "Ezekiel's Wheel".  It's actually
a music video for my band (same name).  I've been 
playing with the concept for 3 YEARS, but never got
motivated to finish it, because I never had a forum
to get it out to the public.  I was watching EyeDrops
about 6 weeks ago and had one of those head-smacking
moments! DUH! Put the video on EyeDrops!  ;)
You can download the soundtrack from:
  http://www.untiedmusic.com/ezekiel/ezekiel.html
Click on the ear to listen...

Emory
  Bass/12string/windsynth for Ezekiel's Wheel
   http://www.untiedmusic.com/ezekiel

"Tom A." wrote:
> 
> Gwen & Emory Stagmer wrote:
> >
> 
> >
> > If anyone can confirm this on another platform and/or suggest a
> > work-around, it would be greatly appreciated!
> >
> > Just FYI, this is an animatic for a 2+ minute animation I hope
> > to get on TechTV's EyeDrops show.  I have 1:45 of the video rendered
> > at 720x540@15fps - now up to about 10 CPU DAYS of rendering time...
> 
> Sorry, no help for your problem (I'm just starting to get a working
> knowledge of media - I still don't understand most of the keywords for
> them), but I did have some questions on your project.
> 
> Is that a typical size for a TV animation?  What format do they want it
> (avi? MPG?)  What do you use to put the frames together?
> 
> I saw Shrek on the big screen last weekend, and watched the background -
> the blades of grass were done individually, the leaves were great, the
> pine trees looked great (all things I've played with recently).  Does
> anyone know what kind of resolution a feature film takes?
> 
> Thanks.
> 
> > Emory Stagmer
> 
> --
> Tom A.
> When scientist say they're making a "quantum leap" it
> means they are going out to catch some rays.  - Dr. Science
> Deja mail is gone.  Look for me at raugost at yahoo . com

Post a reply to this message

Thorsten Froehlich wrote:
> Gwen & Emory Stagmer wrote:
>> The effect looks like some kind of scan line error.
> POV-Ray is a ray tracer, not a scanline renderer.  [snip]

The lad said 'looks like', not 'is'.

-- 
Tim Cook
http://empyrean.scifi-fantasy.com
mirror: http://personal.lig.bellsouth.net/lig/z/9/z993126

-----BEGIN GEEK CODE BLOCK-----
Version: 3.12
GFA dpu- s: a?-- C++(++++) U P? L E--- W++(+++)>$
N++ o? K- w(+) O? M-(--) V? PS+(+++) PE(--) Y(--)
PGP-(--) t* 5++>+++++ X+ R* tv+ b++(+++) DI
D++(---) G(++) e*>++ h+ !r--- !y--
------END GEEK CODE BLOCK------

Post a reply to this message

In article <3d7e1eaa@news.povray.org> , "Timothy R. Cook" 
<tim### [at] scifi-fantasycom> wrote:
> Thorsten Froehlich wrote:
>> Gwen & Emory Stagmer wrote:
>>> The effect looks like some kind of scan line error.
>> POV-Ray is a ray tracer, not a scanline renderer.  [snip]
>
> The lad said 'looks like', not 'is'.

I suppose that depends on how you interpret the whole sentence, not just two
words of it ... you can either interpret as "looks like some kind of scan
line" or "looks like some kind of scan line error".  I used the second, you
the first interpretation...

    Thorsten

____________________________________________________
Thorsten Froehlich, Duisburg, Germany
e-mail: tho### [at] trfde

Visit POV-Ray on the web: http://mac.povray.org

Post a reply to this message

Thorsten Froehlich wrote:
> In article <3d7e1eaa@news.povray.org> , "Timothy R. Cook" 
> <tim### [at] scifi-fantasycom> wrote:
> 
>>Thorsten Froehlich wrote:
>>
>>>Gwen & Emory Stagmer wrote:
>>>
>>>>The effect looks like some kind of scan line error.
>>>
>>>POV-Ray is a ray tracer, not a scanline renderer.  [snip]
>>
>>The lad said 'looks like', not 'is'.
> 
> 
> I suppose that depends on how you interpret the whole sentence, not just two
> words of it ... you can either interpret as "looks like some kind of scan
> line" or "looks like some kind of scan line error".  I used the second, you
> the first interpretation...

Eh...wtf

I interpret it to be 'looks like some kind of error of the type a scan
line render would produce', which seems to be what he meant.  You are
seeming to interpret it to be 'looks like an error that only scan line
renderers produce'.

-- 
Tim Cook
http://empyrean.scifi-fantasy.com
mirror: http://personal.lig.bellsouth.net/lig/z/9/z993126

-----BEGIN GEEK CODE BLOCK-----
Version: 3.12
GFA dpu- s: a?-- C++(++++) U P? L E--- W++(+++)>$
N++ o? K- w(+) O? M-(--) V? PS+(+++) PE(--) Y(--)
PGP-(--) t* 5++>+++++ X+ R* tv+ b++(+++) DI
D++(---) G(++) e*>++ h+ !r--- !y--
------END GEEK CODE BLOCK------

Post a reply to this message

In article <3d7e2d08$1@news.povray.org> , "Timothy R. Cook" 
<tim### [at] scifi-fantasycom> wrote:

>>>>>The effect looks like some kind of scan line error.
>>>>
>>>>POV-Ray is a ray tracer, not a scanline renderer.  [snip]
>>>
>>>The lad said 'looks like', not 'is'.
>>
>> I suppose that depends on how you interpret the whole sentence, not just two
>> words of it ... you can either interpret as "looks like some kind of scan
>> line" or "looks like some kind of scan line error".  I used the second, you
>> the first interpretation...
>
> Eh...wtf
>
> I interpret it to be 'looks like some kind of error of the type a scan
> line render would produce', which seems to be what he meant.  You are
> seeming to interpret it to be 'looks like an error that only scan line
> renderers produce'.

Well, given that POV-Ray has to do absolutely nothing with a scanline
renderer, there was nothing wrong with pointing this out then.

Anyway, the world will not end because of this, so... :-)

    Thorsten

____________________________________________________
Thorsten Froehlich, Duisburg, Germany
e-mail: tho### [at] trfde

Visit POV-Ray on the web: http://mac.povray.org

Post a reply to this message