kurtz le pirate <kur### [at] gmailcom> wrote:
> Hi,
>
>
> I've tried to reproduce the lighting model used at Wolfram.
> [...]
>
> There are a few explanations here :
>
<http://reference.wolframcloud.com/language/tutorial/TheStructureOfGraphicsAndSound.html#20392>
>
> Maybe some ideas ?
>
> --
> Kurtz le pirate
> Compagnie de la Banquise

Hi Kurtz. I tried to replicate the example on the reference page. (Their
explanation was confusing, but I think I got the gist of it.) Here's my attempt:

// +fn +f +a0.03 +am1 +r3 +w640 +h480

#version 3.7;

global_settings{assumed_gamma 1.0}

background{rgb 1}

camera{
 right x*1.333 up y
 location <5, 7, -9>
 look_at 0
 angle 35
}

#macro Light(Pos, RGB)
 light_source{
  Pos, rgb RGB
  parallel
  point_at 0
  shadowless
 }
#end

union{
 #local Boost = 0.3;
 Light(<0, 1, 0>, x+Boost)
 Light(<1, 1, 0>, y+Boost)
 Light(<1, 0, 0>, z+Boost)
 rotate <0, 10, 10>
}

union{
 sphere{<-1, 0, -1>, 1}
 sphere{<1, 0, -1>, 1}
 sphere{<-1, 0, 1>, 1}
 sphere{<1, 0, 1>, 1}

 pigment{rgb 1}
 finish{brilliance 1.5}
}

#include "shapes.inc"

Wire_Box_Union(<-2, -1, -2>, <2, 1, 2>, .004)

Post a reply to this message

Attachments:
Download 'wolframlightingtest.jpg' (21 KB)

Preview of image 'wolframlightingtest.jpg'