POV-Ray : Newsgroups : povray.general : cyclone fence : Re: cyclone fence Server Time
29 Nov 2022 04:24:48 EST (-0500)
  Re: cyclone fence  
From: Bald Eagle
Date: 13 Aug 2022 21:55:00
Message: <web.62f85581c97524821f9dae3025979125@news.povray.org>
"David Kraics" <bar### [at] aolcom> wrote:
> I did a render of my high school but didn't add the cyclone fencing because the
> thought of that many calculations frightens me. Is there a way to cheat a
> cyclone fence since the school is seen from a distance?

Quick and dirty, but accurate and to scale.

Should give a solid start.   :)




#version 3.8;
global_settings {assumed_gamma 1.0}

#include "shapes3.inc"

camera {
    location  <0, 48, -96>
    right x*image_width/image_height
    look_at   <0, 24, 0>
}

light_source {<-140, 200, -300> rgb 1 shadowless}


#declare RH =
union {
 object {Segment_of_Torus (
    0.15, // radius major,
    0.15/2, // radius minor,
    -90  // segment angle (in degrees)
    )
 rotate  y*45
 rotate -x*45
 translate -x*0.15
 }
 //cylinder {<0, 0, 0.15>, <-2, 0, 0.15> 0.15/2}

 cylinder {<0, 0, 0.15>, <-2, 0, 0.15> 0.15/2 rotate -z*45}
}


#declare LH =
union {
 object {Segment_of_Torus (
    0.15, // radius major,
    0.15/2, // radius minor,
    -90  // segment angle (in degrees)
    )
  rotate -y*90
  rotate -y*45
  rotate  x*45
  translate x*0.15
 }
 cylinder {<0, 0, 0.15>, <2, 0, 0.15> 0.15/2 rotate z*45 translate -z*0.15*3/2}

 //scale <1, 1, -1>
}

#declare Coil1 =
union {
 #for (n, 1, 17)
  object {RH translate y*n*1.4*2}
  object {LH translate y*(1.4 + n*1.4*2) translate -x*1.4}
 #end
 pigment {rgb <1, 0.7, 0>}
}

#declare Coil2 = object {Coil1 scale <-1, 1, 1>}

#declare Pair =
union {
 object {Coil1}
 object {Coil2 translate -x*0.15}
}

#for (N, -20, 20)
 object {Pair translate x*(1.4-0.15)*N*2}
#end


Post a reply to this message

Copyright 2003-2021 Persistence of Vision Raytracer Pty. Ltd.