POV-Ray : Newsgroups : povray.bugreports : artifacts on lathe object Server Time
28 Mar 2024 11:45:53 EDT (-0400)
  artifacts on lathe object (Message 1 to 10 of 15)  
Goto Latest 10 Messages Next 5 Messages >>>
From: David Mandelberg
Subject: artifacts on lathe object
Date: 9 Oct 2017 17:20:01
Message: <web.59dbe72e2e96ce0e146834bc0@news.povray.org>
When I render the below scene, there are some spurious black artifacts near the
center of the red vuvuzela. Without the translation and rotation, the artifacts
go away. I'm using POV-Ray 3.7.0 on Ubuntu 16.04.

camera {
  right x
  location <0, 0, -10>
  look_at <0, 0, 0>
  angle 25
}

light_source { <-5, 20, -10>, color rgb 1 }
light_source { <5, 20, -10>, color rgb 1 }

// Vuvuzela, with mouthpiece around <2, 0, 0>, flare around <-2, 0, 0>, and max
// diameter around 1.
#declare Vuvuzela = lathe {
  bezier_spline
  24,
  // mouthpiece
  <0.001, 0.2>, <0.001, 0.2>, <0.06, 0.11>, <0.06, 0.1>,
  <0.06, 0.1>, <0.06, 0.09>, <0.07, 0.09>, <0.07, 0.1>,
  <0.07, 0.1>, <0.07, 0.15>, <0.05, 0.19>, <0.04, 0.2>,
  // rest of the vuvuzela
  <0.04, 0.2>, <0.04125, 0.6>, <0.1, 3.5>, <0.5, 3.9>,
  <0.5, 3.9>, <0.51, 3.91>, <0.51, 3.92>, <0.5, 3.92>,
  <0.5, 3.92>, <0.49, 3.92>, <0.1, 3.8>, <0.001, 3.8>
  sturm

  translate -2*y
  scale 0.9
  rotate 90*z
};

object { Vuvuzela pigment { color rgb <1, 0, 0> } }


Post a reply to this message

From: Bald Eagle
Subject: Re: artifacts on lathe object
Date: 10 Oct 2017 07:50:00
Message: <web.59dcb3b9d40b44f2c437ac910@news.povray.org>
"David Mandelberg" <dav### [at] mandelbergorg> wrote:
> When I render the below scene, there are some spurious black artifacts near the
> center of the red vuvuzela. Without the translation and rotation, the artifacts
> go away. I'm using POV-Ray 3.7.0 on Ubuntu 16.04.
>

I think there may have been some issues with the bezier spline, that have been
addressed post-v-3.7
I didn't have a chance to render this in 3.7.1-beta.8, but I'd guess it might
look better.
I'd say either install the beta and try it, or use a different spline type.

> #declare Vuvuzela = lathe {
>   bezier_spline
>   24,

> object { Vuvuzela pigment { color rgb <1, 0, 0> } }

I must confess, I had to look up "vuvuzela" and was apprehensive about the
search results, as it sounded like it might be something NSFW.   :D


Post a reply to this message

From: clipka
Subject: Re: artifacts on lathe object
Date: 10 Oct 2017 08:56:15
Message: <59dcc36f$1@news.povray.org>
Am 10.10.2017 um 13:49 schrieb Bald Eagle:

> I must confess, I had to look up "vuvuzela" and was apprehensive about the
> search results, as it sounded like it might be something NSFW.   :D

Yes, that's _exactly_ how vuvuzelas sound: Not suitable for work (nor
recreational use, for that matter)... except where ear protection must
be worn anyway ;)


Post a reply to this message

From: David Mandelberg
Subject: Re: artifacts on lathe object
Date: 10 Oct 2017 14:20:00
Message: <web.59dd0eb8d40b44f2146834bc0@news.povray.org>
"Bald Eagle" <cre### [at] netscapenet> wrote:
> "David Mandelberg" <dav### [at] mandelbergorg> wrote:
> > When I render the below scene, there are some spurious black artifacts near the
> > center of the red vuvuzela. Without the translation and rotation, the artifacts
> > go away. I'm using POV-Ray 3.7.0 on Ubuntu 16.04.
> >
>
> I think there may have been some issues with the bezier spline, that have been
> addressed post-v-3.7
> I didn't have a chance to render this in 3.7.1-beta.8, but I'd guess it might
> look better.
> I'd say either install the beta and try it, or use a different spline type.

There's still an issue in 3.7.1-beta.9. I'll try 3.8.0-alpha.9322209 next, but
it'll take me a bit of time to get to that.


Post a reply to this message

From: omniverse
Subject: Re: artifacts on lathe object
Date: 10 Oct 2017 16:10:00
Message: <web.59dd28f7d40b44f29c5d6c810@news.povray.org>
"David Mandelberg" <dav### [at] mandelbergorg> wrote:
> "Bald Eagle" <cre### [at] netscapenet> wrote:
> > "David Mandelberg" <dav### [at] mandelbergorg> wrote:
> > > When I render the below scene, there are some spurious black artifacts near the
> > > center of the red vuvuzela. Without the translation and rotation, the artifacts
> > > go away. I'm using POV-Ray 3.7.0 on Ubuntu 16.04.
> > >
> >
> > I think there may have been some issues with the bezier spline, that have been
> > addressed post-v-3.7
> > I didn't have a chance to render this in 3.7.1-beta.8, but I'd guess it might
> > look better.
> > I'd say either install the beta and try it, or use a different spline type.
>
> There's still an issue in 3.7.1-beta.9. I'll try 3.8.0-alpha.9322209 next, but
> it'll take me a bit of time to get to that.

Think you'll find it's the same... except be aware v3.8 has changed default
ambient so if you render with directive #version 3.7; it will look different
from using 3.8 in its place.

At first I thought the lathe object was thinner but its just the missing ambient
in shadow.

Nothing new about lathe problems, there was something about negative control
points for bezier_spline which I'm guessing doesn't actually relate to this
trouble.


Post a reply to this message

From: David Mandelberg
Subject: Re: artifacts on lathe object
Date: 10 Oct 2017 16:20:00
Message: <web.59dd2b10d40b44f2146834bc0@news.povray.org>
"omniverse" <omn### [at] charternet> wrote:
> "David Mandelberg" <dav### [at] mandelbergorg> wrote:
> > "Bald Eagle" <cre### [at] netscapenet> wrote:
> > > "David Mandelberg" <dav### [at] mandelbergorg> wrote:
> > > > When I render the below scene, there are some spurious black artifacts near
the
> > > > center of the red vuvuzela. Without the translation and rotation, the
artifacts
> > > > go away. I'm using POV-Ray 3.7.0 on Ubuntu 16.04.
> > > >
> > >
> > > I think there may have been some issues with the bezier spline, that have been
> > > addressed post-v-3.7
> > > I didn't have a chance to render this in 3.7.1-beta.8, but I'd guess it might
> > > look better.
> > > I'd say either install the beta and try it, or use a different spline type.
> >
> > There's still an issue in 3.7.1-beta.9. I'll try 3.8.0-alpha.9322209 next, but
> > it'll take me a bit of time to get to that.
>
> Think you'll find it's the same... except be aware v3.8 has changed default
> ambient so if you render with directive #version 3.7; it will look different
> from using 3.8 in its place.

You're right. 3.8.0-alpha.9322209 has the same issue.

>
> At first I thought the lathe object was thinner but its just the missing ambient
> in shadow.
>
> Nothing new about lathe problems, there was something about negative control
> points for bezier_spline which I'm guessing doesn't actually relate to this
> trouble.


Post a reply to this message

From: Bald Eagle
Subject: Re: artifacts on lathe object
Date: 10 Oct 2017 19:50:00
Message: <web.59dd5b8cd40b44f25cafe28e0@news.povray.org>
"David Mandelberg" <dav### [at] mandelbergorg> wrote:
> When I render the below scene, there are some spurious black artifacts near the
> center of the red vuvuzela. Without the translation and rotation, the artifacts
> go away.

I'm not sure how you got them to go away - they certainly don't for me.

I've tried removing the translation and rotation, and moving the camera, the
light sources, etc.  Gave the finish a little specular reflection - still there.
I used a cubic_spline instead - still there.

I suppose I ought to mention that when i was deveoping a recent scene with a
bell - I used a SOR, and I saw the same sort of artefact.

<snippet>
#declare bellSpline = array [12] {
     < 3.4688, 0.0001>,
     < 3.4688, 0.0002>,
     < 3.0938, 0.4375>,
     < 2.9375, 0.6250>,
     < 2.4844, 1.3438>,
     < 2.1719, 2.6094>,
     < 2.0469, 4.4688>,
     < 1.9063, 4.6875>,
     < 1.7500, 4.8750>,
     < 1.0313, 5.0938>,
     < 0.0001, 5.1563>,
     < 0.0001, 5.1564>
}

.....


#declare Bell1 =
union {

 cylinder {<0, 0, 0>, <0, (5.0938/2)+1, 0> 0.125}
 sphere {0, 0.25}
 torus {0.125, 0.125/4 rotate x*90 translate -y*0.25}
 object {Handle translate -y*1}
 sor {
     arraySize+1,
  #for (B, 0, arraySize)
  #local NewSpline = bellSpline [B]/2;
  //#debug concat ("B = ", str (B, 3, 1), "| Point = ", vstr (2, bellSpline [B],
",", 5, 1), "\n")
  #declare Xmax = max (Xmax, NewSpline.x);
  #declare Ymax = max (Ymax, NewSpline.y);
  NewSpline,
  #end
     open
 }
 //texture { T_Gold_1B }
 texture { mtex }
 //pigment {rgb <1, 1, 0>}
}

</snippet>

So there's something going on - just in general.


Post a reply to this message

From: omniverse
Subject: Re: artifacts on lathe object
Date: 10 Oct 2017 22:45:00
Message: <web.59dd84e0d40b44f29c5d6c810@news.povray.org>
"Bald Eagle" <cre### [at] netscapenet> wrote:
> "David Mandelberg" <dav### [at] mandelbergorg> wrote:
> > When I render the below scene, there are some spurious black artifacts near the
> > center of the red vuvuzela. Without the translation and rotation, the artifacts
> > go away.
>
> I'm not sure how you got them to go away - they certainly don't for me.
>
> I've tried removing the translation and rotation, and moving the camera, the
> light sources, etc.  Gave the finish a little specular reflection - still there.
> I used a cubic_spline instead - still there.
>
> I suppose I ought to mention that when i was deveoping a recent scene with a
> bell - I used a SOR, and I saw the same sort of artefact.

It's when the camera is perpendicular to sides (within vertical extent, ignoring
actual surface curvature) facing camera, so if it gets tilted away enough for
either the base or cap imaginary infinite reach outward to miss the camera it
doesn't show.

I was checking doing that; it can make a line of surface color outward into
space away from the surface, along with the colorless mess. The extent seems to
get confined to the maximum x point, so I don't know if that's a result of
bounding or what but I didn't see it go beyond sides of a box with same
dimensions. Or more precisely, kept within a cylinder of maximum x dimension.

Your bell again below, able to be added directly into lathe scene file and
rendered to show its trouble with this.


#declare bellSpline = array [12] {
     < 3.4688, 0.0001>,
     < 3.4688, 0.0002>,
     < 3.0938, 0.4375>,
     < 2.9375, 0.6250>,
     < 2.4844, 1.3438>,
     < 2.1719, 2.6094>,
     < 2.0469, 4.4688>,
     < 1.9063, 4.6875>,
     < 1.7500, 4.8750>,
     < 1.0313, 5.0938>,
     < 0.0001, 5.1563>,
     < 0.0001, 5.1564>
}

#declare arraySize=11;
#declare Xmax=3.4688;
#declare Ymax=5.1564;

//#declare Bell1 =
union {
 cylinder {<0, 0, 0>, <0, (5.0938/2)+1, 0> 0.125}
 sphere {0, 0.25}
 torus {0.125, 0.125/4 rotate x*90 translate -y*0.25}
// object {Handle translate -y*1}
 sor {
     arraySize+1,
  #for (B, 0, arraySize)
  #local NewSpline = bellSpline [B]/2;
  #declare Xmax = max (Xmax, NewSpline.x);
  #declare Ymax = max (Ymax, NewSpline.y);
  NewSpline,
  #end
     open
 }
 //texture { T_Gold_1B }
// texture { mtex }
 pigment {rgb <1, 1, 0>}
 rotate <-2,0,0>
}


Post a reply to this message

From: omniverse
Subject: Re: artifacts on lathe object
Date: 10 Oct 2017 23:05:00
Message: <web.59dd8954d40b44f29c5d6c810@news.povray.org>
"omniverse" <omn### [at] charternet> wrote:
Of course I notice after posting my last reply that simply adding keyword sturm
to the sor bell fixes it completely, at least from what I can see from the
example.

Unfortunate that the same can't be said for lathe, which doesn't seem affected
by sturm at all.


Post a reply to this message

From: clipka
Subject: Re: artifacts on lathe object
Date: 11 Oct 2017 04:45:54
Message: <59ddda42@news.povray.org>
Am 11.10.2017 um 04:41 schrieb omniverse:

> I was checking doing that; it can make a line of surface color outward into
> space away from the surface, along with the colorless mess. The extent seems to
> get confined to the maximum x point, so I don't know if that's a result of
> bounding or what but I didn't see it go beyond sides of a box with same
> dimensions. Or more precisely, kept within a cylinder of maximum x dimension.

The confinement you're seeing there is the lathe's internal bounding
mechanism kicking in, which does indeed use cylinders (instead of boxes)
to bound each individual segment.


Post a reply to this message

Goto Latest 10 Messages Next 5 Messages >>>

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.