From: Christopher James Huff <cja### [at] earthlinknet>
Date: Tue, 22 Jun 2004 14:17:09 -0500

This one seems pretty simple, and may be the cause of the problems
some people have with radiosity + media: radiosity does not seem to
see media from volumes containing the point radiosity is being
computed from. If you have a container of media, the media will only
illuminate surfaces outside the container. It looks like the radiosity
samples start from a void, whether they are really in a container or
not.

There appear to be other artifacts caused by the container object as 
well, but that may be a more difficult problem to solve.

#default {texture {finish {ambient 0 diffuse 1}}}

#version 3.6;

global_settings {
    assumed_gamma 1
    max_trace_level 12
    radiosity {
        count 300
        nearest_count 7
        error_bound 0.3
        minimum_reuse 0.017
        media on
    }
}

camera {
    location <0, 3.5,-8>
    up y*image_height right x*image_width
    angle 45
    look_at < 0, 0, 0>
}

union {
    box {<-100, 0,-100>, < 100, 0, 100>}
    box {< 0, 0, 0>, < 10, 10, 10>}
    texture {
        pigment {color rgb 0.98}
    }
}

#declare StandinSphere = false;

sphere {< 0, 0, 0>, 2 hollow
    texture {
        pigment {color rgbf 1}
    }
    #if(!StandinSphere)
    interior {
        media {
            emission < 0.9, 1, 0.35>*15
            method 3
            intervals 1 samples 3
            density {function {pow(max(0, 1 - f_r(x, y, z)), 3)}}
        }
    }
    #end
    translate y*1   
}

#if(StandinSphere)
sphere {< 0, 1, 0>, 0.5
    texture {
        pigment {color rgb 1}
        finish {ambient 10}
    }
}
#end

-- 
Christopher James Huff <cja### [at] earthlinknet>
http://home.earthlink.net/~cjameshuff/
POV-Ray TAG: <chr### [at] tagpovrayorg>
http://tag.povray.org/

Post a reply to this message