// read in .general

camera {
  location <0,8,-9> look_at -y*6 angle 70
}
box { -10,+10 inverse pigment { checker rgb .85 rgb 1 } finish { diffuse .97 } }
plane { y,-9.99 pigment { rgb 1 } finish { diffuse .96 } }

global_settings {
 radiosity { media on }
 photons { 
   count 100*1000    
   media 100
 }
}

// == LEFT - simple
#local Tr=-x*6;
#local P=<0,  2,0>+Tr;
#local T=<0,-10,0>+Tr;
sphere { P .2 finish { ambient 1 } pigment{rgb 1} no_shadow }
sphere { T .2                      pigment{rgb y}  }
light_source { 
  P rgb 1
  spotlight point_at T  radius 10 falloff 10+5
} 
box { -.4,+.4 pigment { rgb x } translate <0,-2,0> translate Tr }


// ==  glass +normal + PHOTONS
#local Tr=+x*0;
#local P=<0,  2,0>+Tr;
#local T=<0,-10,0>+Tr;
sphere { P .2 finish { ambient 1 } pigment{rgb 1} no_shadow }
sphere { T .2                      pigment{rgb y}  }
light_source { 
  P rgb 1
  spotlight point_at T  radius 10 falloff 10+5
  media_interaction
  media_attenuation
  photons { reflection on  refraction on }
} 
box { -.7,+.7 scale <1,.2,1>
  pigment { rgbf .99 }
  finish { reflection .2 specular .9 roughness 0.02 }
  interior { ior 1.3 }
  normal { bozo scale .4 }
  translate <0,-1,0> translate Tr
  photons { refraction on  target on }
}

// ==  glass +normal + PHOTONS + dispersion
#local Tr=+x*6;
#local P=<0,  2,0>+Tr;
#local T=<0,-10,0>+Tr;
sphere { P .2 finish { ambient 1 } pigment{rgb 1} no_shadow }
sphere { T .2                      pigment{rgb y}  }
light_source { 
  P rgb 1
  spotlight point_at T  radius 10 falloff 10+5
} 
box { -.7,+.7 scale <1,.2,1>
  pigment { rgbf .99 }
  finish { reflection .2 specular .9 roughness 0.02 }
  interior { 
    ior 1.3        
    dispersion 1.04 dispersion_samples 20 
  }
  normal { bozo scale .4 }
  translate <0,-1,0> translate Tr
  photons { refraction on  target on }
}

// --- media ---
media {
  scattering { 1 rgb .3 extinction .1 }
  samples 1000  
}

Post a reply to this message