POV-Ray : Newsgroups : povray.binaries.scene-files : Playing with media clouds Server Time
28 Mar 2024 09:56:25 EDT (-0400)
  Playing with media clouds (Message 1 to 3 of 3)  
From: Thomas de Groot
Subject: Playing with media clouds
Date: 11 May 2018 07:06:24
Message: <5af57930@news.povray.org>
Here is the scene and df3 files talked about in p.b.images.

-- 
Thomas


Post a reply to this message


Attachments:
Download 'media cloud.zip' (4004 KB)

From: Thomas de Groot
Subject: Re: Playing with media clouds - update
Date: 12 May 2018 03:36:33
Message: <5af69981$1@news.povray.org>
Absorption an emission media should also be compensated for media 
scaling. Here is an update for both cloud and atmosphere, to be replaced 
with originals.

//start code
//========================================================================
//Cloud layer:

#declare C_Cloud = <252, 252, 253>/255;
#declare C_Sky3  = <225, 225, 226>/255;

#declare C_Scattering = C_Cloud*10;
#declare C_Absorption = (1-C_Cloud)*800;
#declare C_Emission   = C_Cloud*0.1;//C_Sky3*0.01;

#declare C_Scale    = 200;
#declare Turbulence = 0.15; //0.15; // cloud turbulence
#declare Lambda     = 3; // cloud lambda
#declare Omega      = 0.6; // cloud omega

#declare Cloud1 =
box {
   <-0.5, 0, -0.5>, <0.5, 1.0, 0.5>
   texture {pigment {rgbt 1} finish {diffuse 0}}
   //texture {pigment {rgbt <1,0,0,0.9>} finish {diffuse 1}}
   hollow
   interior {
     media {
       scattering {1, rgb C_Scattering/C_Scale /*extinction 0.15*/}
       absorption rgb C_Absorption/C_Scale
       emission rgb C_Emission/C_Scale
       intervals 1
       samples 100
       density {
         density_file df3 "Scattered_03.df3"
         turbulence Turbulence
         lambda Lambda
         omega Omega
         interpolate 1
         translate <-0.5, 0.0, -0.5>
       }
     }
   }
   scale C_Scale
   scale <10, 0.5, 10>
   rotate y*0
   translate <0, 101, C_Scale*5>
}

Cloud1

//========================================================================
//Atmospheric haze under the cloud layer:

#declare C_Fog          = <250, 250, 250>/255;
#declare Fog_Scattering = C_Fog*0.1;
#declare Fog_absorption = (1-C_Fog)*2;
#declare Fog_Scale      = 200;

#declare Fog =
box {
   <-0.5, -1.0, -0.5>, <0.5, 0.0, 0.5>
   texture {pigment {rgbt 1} finish {diffuse 0}}
   hollow
   interior {
     media {
       scattering {1, rgb Fog_Scattering/Fog_Scale /*extinction 0.15*/}
       absorption rgb Fog_absorption/Fog_Scale
       intervals 1
       samples 100
     }
   }
   scale Fog_Scale
   scale <10, 1, 10>
   translate <0, 100, C_Scale*5>
}

Fog

//end code


-- 
Thomas


Post a reply to this message

From: And
Subject: Re: Playing with media clouds
Date: 25 Jun 2018 06:20:01
Message: <web.5b30c163beb905282d85b1510@news.povray.org>
Thomas de Groot <tho### [at] degrootorg> wrote:
> Here is the scene and df3 files talked about in p.b.images.
>
> --
> Thomas

Good shape;


Post a reply to this message

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.