Does anybody know how to make bricks using isosurfaces.  I have a scene with 
wood and bricks in it, originally just made from boxes, and when I used the 
iso-wood inc to change the wood, the bricks look cheezy.  And I don't have a 
clue as to how to make isosurface bricks.

Thanx in advance,

Eric

Post a reply to this message

Wasn't it Eric Freeman who wrote:
>Does anybody know how to make bricks using isosurfaces.  I have a scene with 
>wood and bricks in it, originally just made from boxes, and when I used the 
>iso-wood inc to change the wood, the bricks look cheezy.  And I don't have a 
>clue as to how to make isosurface bricks.

You can't just use f_brick, because it has infinite gradients where the
colours change. You have to generate something where the value changes
continuously instead of having sudden changes. One way to do it is by
blending two gradient pigments like this:

#declare Px= pigment {
    gradient x
    colour_map {[0 rgb 0][0.05 rgb 1][0.95 rgb 1][1 rgb 0]}
}

#declare Py= pigment {
    gradient y
    colour_map {[0 rgb 0][0.1 rgb 1][0.9 rgb 1][1 rgb 0]}
    scale 0.5
}

#declare F=function{pigment {
  average pigment_map {[1 Px][1 Py]}    
  warp {repeat y*0.5 offset <0.5,0,0>}
}}

isosurface {
  function { -z - F(x,y,z).red*0.05 }
        max_gradient 10
        contained_by{box{<-2,-2,-1><2,2,1>}}
        pigment { ... }
}


-- 
Mike Williams
Gentleman of Leisure

Post a reply to this message

I made the floor on my irtc entry
http://www.irtc.org/ftp/pub/stills/2005-06-30/untitled.jpg using isosurfaces

#macro adoquin (rs_brick)
#local rnd_ad= seed(rs_brick) ;
     isosurface {
            function{f_rounded_box(x,y,z,0.15,1.75*gr,1.75,1.75)-

(f_bozo(x*1.85*gr+rs_brick,y*1.85+rs_brick,z*1.85-rs_brick)*0.3)
                     }
            threshold 0
            contained_by {box {<-2*gr,-2,-2>,<2*gr,2,2>}}
             max_gradient 1.358
            scale .5
            }
#end
 perhaps you could find it useful
--
light_source{0,1}#macro C(r,p)cylinder{x*-2,x*2,.9 pigment { rgb
p} /* B Gimeno estoeslarealidad */ rotate p*90 } #end difference
{box {-1,1} C(z /* http://usuarios.lycos.es/game2413 */,x)C(x,y)
C(z,z) pigment{rgb 2} rotate 45 translate z*4} // www.povray.org

Post a reply to this message

"B. Gimeno" <NO_### [at] lycoses> wrote in message 
news:43bbc6ba@news.povray.org...
>I made the floor on my irtc entry
> http://www.irtc.org/ftp/pub/stills/2005-06-30/untitled.jpg using 
> isosurfaces
>
> #macro adoquin (rs_brick)
> #local rnd_ad= seed(rs_brick) ;
>     isosurface {
>            function{f_rounded_box(x,y,z,0.15,1.75*gr,1.75,1.75)-
>
> (f_bozo(x*1.85*gr+rs_brick,y*1.85+rs_brick,z*1.85-rs_brick)*0.3)
>                     }
>            threshold 0
>            contained_by {box {<-2*gr,-2,-2>,<2*gr,2,2>}}
>             max_gradient 1.358
>            scale .5
>            }
> #end
> perhaps you could find it useful
> --
> light_source{0,1}#macro C(r,p)cylinder{x*-2,x*2,.9 pigment { rgb
> p} /* B Gimeno estoeslarealidad */ rotate p*90 } #end difference
> {box {-1,1} C(z /* http://usuarios.lycos.es/game2413 */,x)C(x,y)
> C(z,z) pigment{rgb 2} rotate 45 translate z*4} // www.povray.org
>
>

Thanx to both of you for responding.  Cool picture,too.

Eric

Post a reply to this message