// Persistence of Vision Ray Tracer Scene Description File
// File: speaker.pov
// Vers: 3.1
// Desc: Speaker
// Date: 10/6/1999
// Auth: Bryan Valencia bry### [at] 209softwarecom

#include "colors.inc"
#include "textures.inc"

camera{location <0,4,-130> look_at<0,0,0>}
light_source{<100,100,-100> color White}

box{<-100,-50,-100><100,200,100> pigment{color White} hollow scale 100}

#declare Metal_Texture=Polished_Brass
#declare Rubber=texture{
  pigment{checker color Black color White* .1 scale .1}
  normal {bumps .4 scale .1}
  finish{phong .5}
}


#declare Speaker = union{
  cylinder{<-5,0,0>,<0,0,0>,10
    texture{Metal_Texture}
  }

  cylinder{<-4,0,0>,<-1,0,0>,11
    texture{Rubber}
  }

  difference{
    cone{<0,0,0>,10,<10,0,0>,20}
    union{
      cone{<0,0,0>,9.9,<10.1,0,0>,19.9}
      #declare A=0;
      #while (A<360)
        cylinder{<21,15,0><-1,15,0>,4 rotate x*A}
        #declare A=A+45;
      #end
    }
    texture{Metal_Texture}
  }

  torus{ 20, 1
    texture{Metal_Texture}
    rotate z*90
    translate x*10
  }

  torus{ 18.75, .5
    texture{Rubber}
    rotate z*90
    translate x*10
  }

  sphere{<0,0,0>,5 scale<.1,1,1> translate <5,0,0>
    texture{Rubber}
  }

  cone{<5,0,0>,5,<10,0,0>,18.75 open texture{Rubber} }
}


object{Speaker}
object{Speaker rotate y*90 translate x*50}
object{Speaker rotate y*-90 translate x*-50}



--
Bryan Valencia
Software Services
mailto:bry### [at] 209softwarecom
http://www.209software.com/
http://www.209software.com/books/p4dp/p4dp.html
http://www.209software.com/books/wpid/

Post a reply to this message