POV-Ray : Newsgroups : povray.binaries.images : Mirascope Server Time
25 May 2024 10:31:19 EDT (-0400)
  Mirascope (Message 1 to 10 of 11)  
Goto Latest 10 Messages Next 1 Messages >>>
From: Samuel B 
Subject: Mirascope
Date: 18 Jan 2024 20:50:00
Message: <web.65a9d4ce78a2f45d16bed5696e741498@news.povray.org>
Hi,

The discussion in p.general got me interested in seeing how a mirascope in
POV-Ray would look. I just eyeballed the shape by looking at images from a
scientific paper on the subject, so it's not accurate or optimal. The focus
object would probably be better lit by using reflective caustics.

Sam

/*

 Mirascope

 2024 stb

 +fn +f +a0.03 +am2 +r3

 Paraboloid object by Cousin Ricky:
 https://news.povray.org/povray.general/thread/%3Cweb.6588c00f78a2f45d1f9dae3025979125%40news.povray.org%3E/

*/

#version 3.7;

#declare RemoveTop = false;

global_settings{
 assumed_gamma 1.0
 #if(true)
  radiosity{
   pretrace_end .0025
   count 64
   error_bound .25
   recursion_limit 1
   nearest_count 10
  }
 #end
}

#default{ finish{ambient 0} }

// y focus of paraboloid
#declare Y = 0.45;

camera{
 right x up y
 location <0, 5, -5>
 look_at 0
 angle 60/3

 aperture .28 focal_point y*Y blur_samples 10 variance 0
}

// sunlight
#if(1)
 light_source{
  <5, 9, -.1>, srgb 3.5*<2, 1.9, 1.8>
  fade_power 2 fade_distance 1

  #if(true)
   #declare ALRes = 2;
   #declare ALSize = 1;
   area_light x*ALSize, z*ALSize, ALRes, ALRes
   jitter
   adaptive 1
  #end
 }

#end

// room
box{
 <-10, -(Y+.001), -10>, <10, 10, 10>
 rotate y*22
 pigment{
  bumps
  scale 9
  turbulence 1 lambda 3
  color_map{[0 rgb .25][1 rgb .75]}
 }
}

// Cousin Ricky's
#macro Concave_Paraboloid (yFocus)
  poly { 2, <-1, 0, 0, 0, 0, 0, yFocus * 4, -1, 0, 0> }
#end

#declare Paraboloid_Clipped =
 object{
  Concave_Paraboloid(.85)
  clipped_by{plane{y, Y}}
  translate -y*Y
 }

#if(1)
 union{
  object{Paraboloid_Clipped}

  #if(!RemoveTop)
   object{
    Paraboloid_Clipped scale <1, -1, 1>
    clipped_by{cylinder{0, y, .35 inverse}}
   }
  #end

  pigment{rgb .1}

  finish{
   brilliance 2
   reflection .9
  }

  // micronormal
  normal{granite .001 scale .001 accuracy .001}
 }
#end

// object of focus
sphere{
 0, .1
 pigment{checker rotate y*33}
 translate -y*(Y-.1)
}


Post a reply to this message


Attachments:
Download 'mirascope.jpg' (43 KB)

Preview of image 'mirascope.jpg'
mirascope.jpg


 

From: Bald Eagle
Subject: Re: Mirascope
Date: 18 Jan 2024 21:50:00
Message: <web.65a9e2accd602f1b1f9dae3025979125@news.povray.org>
"Samuel B." <stb### [at] hotmailcom> wrote:

> The discussion in p.general got me interested in seeing how a mirascope in
> POV-Ray would look. I just eyeballed the shape by looking at images from a
> scientific paper on the subject, so it's not accurate or optimal. The focus
> object would probably be better lit by using reflective caustics.

Just stop.  :P

This is actually the most convincing one yet.  :O

Great job, as always, Sam.

- BW


Post a reply to this message

From: William F Pokorny
Subject: Re: Mirascope
Date: 19 Jan 2024 05:57:03
Message: <65aa557f$1@news.povray.org>
On 1/18/24 20:47, Samuel B. wrote:
> The discussion in p.general got me interested in seeing how a mirascope in
> POV-Ray would look.

Cool!

Bill P.


Post a reply to this message

From: m@b
Subject: Re: Mirascope
Date: 21 Jan 2024 03:03:57
Message: <65accfed@news.povray.org>
On 19/01/2024 9:47 AM, Samuel B. wrote:
> Hi,
> 
> The discussion in p.general got me interested in seeing how a mirascope in
> POV-Ray would look. I just eyeballed the shape by looking at images from a
> scientific paper on the subject, so it's not accurate or optimal. The focus
> object would probably be better lit by using reflective caustics.
> 
> Sam
> 

Nice,

I did a quick animation:


Post a reply to this message


Attachments:
Download 'mirascope 01.mp4.dat' (317 KB)

From: Samuel B 
Subject: Re: Mirascope
Date: 21 Jan 2024 20:35:00
Message: <web.65adc577cd602f1b16bed5696e741498@news.povray.org>
"Bald Eagle" <cre### [at] netscapenet> wrote:
> "Samuel B." <stb### [at] hotmailcom> wrote:
>
> > The discussion in p.general got me interested in seeing how a mirascope in
> > POV-Ray would look. I just eyeballed the shape by looking at images from a
> > scientific paper on the subject, so it's not accurate or optimal. The focus
> > object would probably be better lit by using reflective caustics.
>
> Just stop.  :P

Nevarr!

> This is actually the most convincing one yet.  :O
>
> Great job, as always, Sam.
>
> - BW

Thanks, Bald Eagle. It helps to have a background to reflect the metallic
texture.

Sam


Post a reply to this message

From: Samuel B 
Subject: Re: Mirascope
Date: 21 Jan 2024 20:35:00
Message: <web.65adc585cd602f1b16bed5696e741498@news.povray.org>
William F Pokorny <ano### [at] anonymousorg> wrote:
> On 1/18/24 20:47, Samuel B. wrote:
> > The discussion in p.general got me interested in seeing how a mirascope in
> > POV-Ray would look.
>
> Cool!
>
> Bill P.

Thanks Bill.


Post a reply to this message

From: Samuel B 
Subject: Re: Mirascope
Date: 21 Jan 2024 20:40:00
Message: <web.65adc6e6cd602f1b16bed5696e741498@news.povray.org>
"m@b" <sai### [at] googlemailcom> wrote:
> On 19/01/2024 9:47 AM, Samuel B. wrote:
> > Hi,
> >
> > The discussion in p.general got me interested in seeing how a mirascope in
> > POV-Ray would look. I just eyeballed the shape by looking at images from a
> > scientific paper on the subject, so it's not accurate or optimal. The focus
> > object would probably be better lit by using reflective caustics.
> >
> > Sam
> >
>
> Nice,
>
> I did a quick animation:

Ah, cool m@b. It looks good. I was wondering how it would animate. It's
interesting how things appear and disappear. Did it take a long time? (Btw, it
seems there's some horizontal stretching... I forgot to mention that the scene
uses equal width and height.)

Sam


Post a reply to this message

From: m@b
Subject: Re: Mirascope
Date: 22 Jan 2024 19:46:16
Message: <65af0c58$1@news.povray.org>
On 22/01/2024 9:37 AM, Samuel B. wrote:
> "m@b" <sai### [at] googlemailcom> wrote:
>> On 19/01/2024 9:47 AM, Samuel B. wrote:
>>> Hi,
>>>
>>> The discussion in p.general got me interested in seeing how a mirascope in
>>> POV-Ray would look. I just eyeballed the shape by looking at images from a
>>> scientific paper on the subject, so it's not accurate or optimal. The focus
>>> object would probably be better lit by using reflective caustics.
>>>
>>> Sam
>>>
>>
>> Nice,
>>
>> I did a quick animation:
> 
> Ah, cool m@b. It looks good. I was wondering how it would animate. It's
> interesting how things appear and disappear. Did it take a long time? 

About 4 hours to render 150 frames

> (Btw, it
> seems there's some horizontal stretching... I forgot to mention that the scene
> uses equal width and height.)

Ah, OK, will bear it in mind next time :-)

> 
> Sam
> 
m@


Post a reply to this message

From: Paolo Gibellini
Subject: Re: Mirascope
Date: 28 Jan 2024 06:45:03
Message: <65b63e3f$1@news.povray.org>
Il 19/01/2024 02:47, Samuel B. ha scritto:
> Hi,
> 
> The discussion in p.general got me interested in seeing how a mirascope in
> POV-Ray would look. I just eyeballed the shape by looking at images from a
> scientific paper on the subject, so it's not accurate or optimal. The focus
> object would probably be better lit by using reflective caustics.
> 
> Sam
> 

Very interesting, Sam! And also very interesting the animation of m@b, 
well done!

Paolo


Post a reply to this message

From: Samuel B 
Subject: Re: Mirascope
Date: 1 Feb 2024 19:50:00
Message: <web.65bc3bb3cd602f1b16bed5696e741498@news.povray.org>
"m@b" <sai### [at] googlemailcom> wrote:
> On 22/01/2024 9:37 AM, Samuel B. wrote:
> > "m@b" <sai### [at] googlemailcom> wrote:
> >> On 19/01/2024 9:47 AM, Samuel B. wrote:
> >>> [...] mirascope [...]
> >>
> >> Nice,
> >>
> >> I did a quick animation:
> >
> > Ah, cool m@b. It looks good. I was wondering how it would animate. It's
> > interesting how things appear and disappear. Did it take a long time?
>
> About 4 hours to render 150 frames

That's not too bad!

Sam


Post a reply to this message

Goto Latest 10 Messages Next 1 Messages >>>

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.